[开_137]寻找五连号

戆小琳 · 发表于 2012-10-5 15:15

本帖最后由戆小琳于 2012-10-5 17:58 编辑

=--(SUM(--MID($A1,ROW($1:$5)*3-2,2))=SMALL(--MID($A1,ROW($1:$5)*3-2,2),1)*5+10)

数组公式用的不好，先想到这个思路，不过超过字符限制了

=--(MAX(--MID($A1,ROW($1:$5)*3-2,2))=MIN(--MID($A1,ROW($1:$5)*3-2,2))+4)
短了一点，还是超

=--(VAR(--MID(A1,ROW($1:$5)*3-2,2))=2.5)
求方差，40字符

shaowu459 · 发表于 2012-10-5 20:03

以前楼层的row改成常量数组，多试几个函数。
=N(AVEDEV((-MID(A1,{1,4,7,10,13},2)))=1.2)
=N(DEVSQ((-MID(A1,{1,4,7,10,13},2)))=10)
=N(VAR((-MID(A1,{1,4,7,10,13},2)))=2.5)
=N(VARP((-MID(A1,{1,4,7,10,13},2)))=2)
看见这种数字规律的，且限制字符的，很大可能是用各种统计函数或者是数学函数。
原始数据好像是无重复的吧，楼主好像没有特别说明

wangyuhu · 发表于 2012-10-9 13:04

shaowu459 发表于 2012-10-5 20:03
以前楼层的row改成常量数组，多试几个函数。
=N(AVEDEV((-MID(A1,{1,4,7,10,13},2)))=1.2)
=N(DEVSQ((-MI ...

是无特别说明：原数据无重复！

xj4071 · 发表于 2012-10-19 16:07

VRA是什么意思？

xj4071 · 发表于 2012-10-19 16:09

错了是VAR?本人水平有限，目前就只能做出这样=
IF(MIN(-MID(A1,{1,4,7,10,13},2))+4=MAX(-MID(A1,{1,4,7,10,13},2)),1,0)

他、 · 发表于 2012-11-1 16:51

qigengzier 发表于 2012-10-5 13:31
首先感谢杨小军老师的开导，让我在这个讨论题里写下这个规律

其主要运用了DEVSQ的特性，来判断一 ...

Q大。求新群号
我是但丁

npixxf · 发表于 2013-1-22 09:24

真是好东西呀

@刘卓 · 发表于 2020-1-22 23:15

=N(SUM(AGGREGATE({14,15},6,-MID(A1,{1;4;7;10;13},2),1)*{1,-1})=4)参与一下

alan57 · 发表于 2023-4-22 19:47

=MAP(A1:A40,LAMBDA(x,LET(_a,--SORT(TEXTSPLIT(x,,",")),_b,SEQUENCE(ROWS(_a)),_c,_a-_b,IF(ROWS(UNIQUE(_c))=1,1,0))))

复制代码

chenlishan2000 · 发表于 2023-6-28 10:05

kkitt 发表于 2012-9-27 09:43
=N(DEVSQ(--MID(A1,{1,4,7,10,13},2))=10)

再给个短点的

不用N不行么，会有什么问题
=VAR(-MID(A40,{1,4,7,10,13},2))

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [开_137]寻找五连号

评分

点评

点评