[开_137]寻找五连号

hifeng · 发表于 2012-9-27 10:31

=IF(MAX(--TRIM(MID(SUBSTITUTE(A1,",",REPT(" ",50)),50*COLUMN(A:E)-49,50)))-MIN(--TRIM(MID(SUBSTITUTE(A1,",",REPT(" ",50)),50*COLUMN(A:E)-49,50)))=4,1,0)可能不符合要求了

chrisfang · 发表于 2012-9-27 10:44

本帖最后由 chrisfang 于 2012-9-27 11:35 编辑

39字符：=1*(DEVSQ(-MID(A1,{1,4,7,10,13},2))=10)
38字符：=1*(VAR(-MID(A1,{1,4,7,10,13},2))=2.5)
37字符：=1*(VARP(-MID(A1,{1,4,7,10,13},2))=2)

titi012 · 发表于 2012-9-27 10:47

=((MAX(--MID(A2,ROW($1:$5)*3-2,2))-MIN(--MID(A2,ROW($1:$5)*3-2,2)))=4)*1
71个字符,还差的很远啊....

titi012 · 发表于 2012-9-27 10:58

=(AVEDEV(--MID(A1,ROW($1:$5)*3-2,2))=1.2)*1
这个42个,不算数组的大括号,勉强合格了.

I000000I · 发表于 2012-9-27 11:06

本帖最后由 I000000I 于 2012-9-27 12:11 编辑

=N(STDEV(-MID(A1,{1,4,7,10,13},2))<1.6)
=N(VAR(-MID(A1,{1,4,7,10,13},2))<3)

chenzicheng · 发表于 2012-9-27 11:13

40

=--(AVEDEV(-MID(A1,{1;4;7;10;13},2))=1.2)

复制代码

Q小然Q · 发表于 2012-9-27 11:17

=IF(MAX(LEFT(A1,2),MID(SUBSTITUTE(A1,",","a",1),FIND("a",SUBSTITUTE(A1,",","a",1))+1,2),MID(SUBSTITUTE(A1,",","a",2),FIND("a",SUBSTITUTE(A1,",","a",2))+1,2),MID(SUBSTITUTE(A1,",","a",3),FIND("a",SUBSTITUTE(A1,",","a",3))+1,2),RIGHT(A1,2))-MIN(LEFT(A1,2),MID(SUBSTITUTE(A1,",","a",1),FIND("a",SUBSTITUTE(A1,",","a",1))+1,2),MID(SUBSTITUTE(A1,",","a",2),FIND("a",SUBSTITUTE(A1,",","a",2))+1,2),MID(SUBSTITUTE(A1,",","a",3),FIND("a",SUBSTITUTE(A1,",","a",3))+1,2),RIGHT(A1,2))=4,1,0)
{:soso_e109:}肯定超过45个字符了

陶宝 · 发表于 2012-9-27 13:39

请楼主赐教

titi012 · 发表于 2012-9-27 13:47

改成这样:
=(VAR(--MID(A1,ROW($1:$5)*3-2,2))<3)*1
38个,比前面少五个. 再想想, 看能不能再短

yql4688 · 发表于 2012-9-27 14:17

呵呵呵，就是用来玩的

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [开_137]寻找五连号

评分

点评

评分

评分

点评

评分

点评

评分

点评

评分

评分

点评

评分