ppt学习资料

weiyingde

Slides集合对象
Presentation
Slides (Slide)
  Multiple objects
在指定演示文稿中所有Slide对象的集合。
使用 Slides集合
本节叙述如何：
创建一个幻灯片并添加到集合
返回一个指定名称、幻灯片索引号、或幻灯片 ID 号的幻灯片
返回演示文稿中幻灯片的子集
同时将一种属性或方法应用到演示文稿中的所有幻灯片
创建一个幻灯片并添加到集合
使用Slides属性返回 Slides集合。使用Add方法创建新幻灯片并添加到集合。以下示例将新幻灯片添加到当前演示文稿中。
ActivePresentation.Slides.Add 2, ppLayoutBlank
返回指定名称、幻灯片索引号或幻灯片 ID 号的幻灯片
使用 Slides(index)（其中 index 为幻灯片名称或索引号）或 Slides.FindBySlideID(index)（其中 index 为幻灯片 ID 号）返回一个 Slide对象。以下示例设置当前演示文稿第一张幻灯片的版式。
ActivePresentation.Slides(1).Layout = ppLayoutTitle
以下示例设置当前演示文稿中名为“Big Chart”的幻灯片的版式。请注意，幻灯片创建时被自动赋予一个形如 Sliden（其中 n 为一整数）的名称。若要给幻灯片赋予一个更有意义的名称，请使用Name属性。
ActivePresentation.Slides("Big Chart").Layout = ppLayoutTitle
返回演示文稿中幻灯片的子集
使用 Slides.Range(index)返回代表 Slides集合的一个子集的SlideRange对象，其中 index 为幻灯片索引号或名称，或者幻灯片索引号或名称的数组。以下示例设置当前演示文稿第一张和第三张幻灯片的背景填充。
With ActivePresentation.Slides.Range(Array(1, 3))
    .FollowMasterBackground = False
    .Background.Fill.PresetGradient msoGradientHorizontal, _
        1, msoGradientLateSunset
End With
同时将一种属性或方法应用于演示文稿
如果要同时对演示文稿中所有幻灯片进行某种操作（例如全部删除或设置它们的某些属性），可不带参数使用 Slides.Range 创建一个包含 Slides集合中所有幻灯片的 SlideRange集合，然后将适当的属性或方法应用于 SlideRange集合。本示例设置当前演示文稿所有幻灯片的背景填充。
With ActivePresentation.Slides.Range
    .FollowMasterBackground = False
    .Background.Fill.PresetGradient msoGradientHorizontal, _
        1, msoGradientLateSunset
End With
SlideShowSettings对象
Presentation
SlideShowSettings
  多个对象
代表演示文稿的幻灯片放映设置。
使用 SlideShowSettings对象
使用SlideShowSettings属性返回 SlideShowSettings对象。以下示例的第一部分设置当前演示文稿中的所有幻灯片在五秒后自动切换。第二部分设置幻灯片放映从第二张开始到第四张结束，使用在第一部分中设置的计时切换幻灯片，并连续循环放映幻灯片，直到用户按 Esc。最后，本示例运行幻灯片放映。
For Each s In ActivePresentation.Slides
    With s.SlideShowTransition
        .AdvanceOnTime = True
        .AdvanceTime = 5
    End With
Next
With ActivePresentation.SlideShowSettings
    .RangeType = ppShowSlideRange
    .StartingSlide = 2
    .EndingSlide = 4
    .AdvanceMode = ppSlideShowUseSlideTimings
    .LoopUntilStopped = True
    .Run
End With

weiyingde

SlideShowTransition对象
多个对象
SlideShowTransition
  SoundEffect
包含幻灯片放映过程中指定幻灯片切换方式的信息。
使用 SlideShowTransition对象
使用SlideShowTransition属性返回 SlideShowTransition对象。以下示例为当前演示文稿第一张幻灯片指定快速阶梯状向左下展开切换方式，并伴随有 Bass.wav 声音，而且指定幻灯片在前一个动画或幻灯片切换结束五秒后自动换片。
With ActivePresentation.Slides(1).SlideShowTransition
    .Speed = ppTransitionSpeedFast
    .EntryEffect = ppEffectStripsDownLeft
    .SoundEffect.ImportFromFile "c:\sndsys\bass.wav"
    .AdvanceOnTime = True
    .AdvanceTime = 5
End With
ActivePresentation.SlideShowSettings.AdvanceMode = _
    ppSlideShowUseSlideTimings
SlideShowView对象
SlideShowWindows (SlideShowWindow)
SlideShowView
  ColorFormat
  Slide
代表幻灯片放映窗口中的视图。
使用 SlideShowView对象
使用 SlideShowWindow对象的View属性可返回 SlideShowView对象。以下示例对第一个幻灯片放映窗口进行设置，以便显示演示文稿中的第一张幻灯片。
SlideShowWindows(1).View.First
使用 SlideShowSettings对象的Run方法可创建一个 SlideShowWindow对象，然后使用 View属性可返回该窗口（前面返回的那个对象）所包含的 SlideShowView对象。以下示例将运行当前演示文稿的幻灯片放映，并将指针更改为笔形，然后将幻灯片放映中此笔形的颜色设置为红色。
With ActivePresentation.SlideShowSettings.Run.View
    .PointerColor.RGB = RGB(255, 0, 0)
    .PointerType = ppSlideShowPointerPen
End With
SlideShowWindow对象
多个对象
SlideShowWindow
  多个对象
代表运行幻灯片放映的窗口。
使用 SlideShowWindow对象
使用 SlideShowWindows(index) 返回单个 SlideShowWindow对象，其中 index 表示幻灯片放映窗口的索引号。以下示例将激活第二个幻灯片放映窗口。
SlideShowWindows(2).Activate
使用Run方法新建一个幻灯片放映窗口并返回对该幻灯片放映窗口的引用。以下示例将运行当前演示文稿的一个幻灯片放映，并缩小幻灯片放映窗口的高度以便可看到任务栏（对于分辨率为 800 x 600 的屏幕）。
With ActivePresentation.SlideShowSettings
    .ShowType = ppShowTypeSpeaker
    With .Run
        .Height = 300
        .Width = 400
    End With
End With
使用View属性返回指定幻灯片放映窗口中的视图。以下示例设置第一个幻灯片放映窗口中的视图，以显示演示文稿中的第三张幻灯片。
SlideShowWindows(1).View.GotoSlide 3
使用Presentation属性返回当前在指定幻灯片放映窗口中运行的演示文稿。以下示例显示当前在第一个幻灯片放映窗口中运行的演示文稿的名称。
MsgBox SlideShowWindows(1).Presentation.Name

weiyingde

SlideShowWindows集合对象
Application
SlideShowWindows (SlideShowWindow)
  Presentation
  SlideShowView
代表 PowerPoint 中打开的幻灯片放映的所有SlideShowWindow对象的集合。
使用 SlideShowWindows集合
使用SlideShowWindows属性返回 SlideShowWindows集合。使用 SlideShowWindows(index)返回单个 SlideShowWindow对象，其中 index 为窗口索引号。以下示例降低第一个幻灯片放映窗口的高度（假设它是全屏的）。
With SlideShowWindows(1)
    If .IsFullScreen Then
        .Height = .Height - 20
    End If
End With
使用Run方法创建新幻灯片窗口并添加到 SlideShowWindows集合。以下示例运行当前演示文稿的一个幻灯片放映。
ActivePresentation.SlideShowSettings.Run
SoundEffect对象
多个对象
SoundEffect
代表在幻灯片放映过程中伴随动画或幻灯片切换的声音效果。
使用 SoundEffect对象
使用 AnimationSettings对象的SoundEffect属性返回 SoundEffect对象，该对象代表伴随动画的声音效果。以下示例指定当前演示文稿第一张幻灯片的标题动画伴随有文件“Bass.wav”的声音。
With ActivePresentation.Slides(1).Shapes(1).AnimationSettings
    .TextLevelEffect = ppAnimateByAllLevels
    .SoundEffect.ImportFromFile "c:\sndsys\bass.wav"
End With
使用 SlideShowTransition对象的 SoundEffect属性返回 SoundEffect对象，该对象代表伴随幻灯片切换的声音效果。
以下示例指定切换到当前演示文稿第一张幻灯片时伴随文件“Bass.wav”的声音。
ActivePresentation.Slides(1).SlideShowTransition.SoundEffect _
    .ImportFromFile "c:\sndsys\bass.wav"
Table对象
Shapes (Shape)
Table
  Columns (Column)
  Rows (Row)
代表幻灯片上的表格形状。Table对象是 Shapes集合的成员。Table对象包含Columns集合和Rows集合。
使用 Table对象
使用 Shapes(index) 可返回一个包含表格的形状，其中 index 为一个数字。使用HasTable属性可查看形状是否包含表格。本示例将遍历第一张幻灯片上的形状，以查看是否每个形状都含有表格，然后为每个表格形状设置鼠标单击动作以前进到下一张幻灯片。
With ActivePresentation.Slides(2).Shapes
    For i = 1 To .Count
        If .Item(i).HasTable Then
            .Item(i).ActionSettings(ppMouseClick) _
                .Action = ppActionNextSlide
        End If
    Next
End With
使用 Table对象的Cell方法可访问每个单元格的内容。本示例将文本“Cell 1”插入第三张幻灯片上第五个形状中表格的第一个单元格中。
ActivePresentation.Slides(3).Shapes(5).Table _
    .Cell(1, 1).Shape.TextFrame.TextRange _
    .Text = "Cell 1"
使用AddTable方法可将表格添加到幻灯片。本示例在活动演示文稿第二张幻灯片上添加一个 3x3 的表格。
ActivePresentation.Slides(2).Shapes.AddTable(3, 3)

weiyingde

TabStop对象
Ruler
TabStops (TabStop)
代表单个制表位。TabStop对象是TabStops集合的成员。TabStops集合代表标尺上的所有制表位。
使用 Tabstop对象
使用 TabStops(index) 返回单个 TabStop对象，其中 index 为制表位的索引号。以下示例清除当前演示文稿第一张幻灯片第二个形状文本的第一个制表位。
ActivePresentation.Slides(1).Shapes(2).TextFrame _
    .Ruler.TabStops(1).Clear
TabStops集合对象
Ruler
TabStops (TabStop)
标尺上所有TabStop对象的集合。
使用 TabStops集合
使用TabStops属性返回 TabStops集合。以下示例清除当前演示文稿第一张幻灯片第二个形状中文本的所有制表位。
With ActivePresentation.Slides(1).Shapes(2) _
        .TextFrame.Ruler.TabStops
    For t = .Count To 1 Step -1
        .Item(t).Clear
    Next
End With
使用Add方法创建制表位并添加到 TabStops集合。以下示例将制表位添加到当前演示文稿幻灯片母版的正文文本样式中。新制表位在距标尺左边缘 2 英寸（144 磅）处，且为左对齐。
ActivePresentation.SlideMaster _
    .TextStyles(ppBodyStyle).Ruler.TabStops.Add ppTabStopLeft, 144
Tags对象
多个对象
Tags
代表可为形状、幻灯片或演示文稿创建的标记或自定义属性。每个 Tags对象包含一个自定义属性名称和该属性的值。
如果要对集合的指定成员进行选择性操作，请基于非内置的属性创建标记。例如，如果要根据所应用的国家/地区中来分类演示文稿中的幻灯片，可以创建地区标记并为每个幻灯片的地区标记赋值。然后，可以根据地区标记值对某些幻灯片进行选择性操作，例如将地区标记值为“East”的所有幻灯片隐藏。
使用 Tags对象
使用Add方法将标记添加到对象。以下示例在当前演示文稿第一张幻灯片中添加名为“Region”的标记，其值为“East”。
ActivePresentation.Slides(1).Tags.Add "Region", "East"
使用 Tags(index) 返回标记名称，其中 index 是标记名称。以下示例检查当前演示文稿中所有幻灯片的地区标记值，并隐藏所有不属于“东海岸”（由“East”值表示）的幻灯片。
For Each s In ActivePresentation.Slides
    If s.Tags("region") <> "east" Then
        s.SlideShowTransition.Hidden = True
    End If
Next

weiyingde

TextEffectFormat对象
Shapes (Shape)
TextEffectFormat
包含应用于艺术字对象的属性和方法。
使用 TextEffectFormat对象
使用 TextEffect属性返回 TextEffectFormat对象。以下示例为myDocument 上的第一个形状设置字体名称及格式。要运行本示例，第一个形状必须是艺术字对象。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(1).TextEffect
    .FontName = "Courier New"
    .FontBold = True
    .FontItalic = True
End With
TextFrame对象
多个对象
TextFrame
  Ruler
  TextRange
代表 Shape对象中的文字框。包含文本框中的文本，还包含控制文本框对齐方式和缩进方式的属性和方法。
使用 TextFrame对象
使用 TextFrame属性返回 TextFrame对象。以下示例向myDocument 中添加一个矩形，向矩形中添加文本，然后设置文本框的边距。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes _
        .AddShape(msoShapeRectangle, 0, 0, 250, 140).TextFrame
    .TextRange.Text = "Here is some test text"
    .MarginBottom = 10
    .MarginLeft = 10
    .MarginRight = 10
    .MarginTop = 10
End With
使用HasTextFrame属性决定形状是否含有文本框，使用HasText属性决定文本框是否含有文本，如以下示例所示。
Set myDocument = ActivePresentation.Slides(1)
For Each s In myDocument.Shapes
    If s.HasTextFrame Then
        With s.TextFrame
            If .HasText Then MsgBox .TextRange.Text
        End With
    End If
Next

weiyingde

TextStyleLevel对象
TextStyles (TextStyle)
TextStyleLevels (TextStyleLevel)
  Font
  ParagraphFormat
包含大纲级别的字符和段落格式信息。TextStyleLevel对象是TextStyleLevels集合的成员。TextStyleLevels集合包含所有五个大纲级别的 TextStyleLevel对象。
使用 TextStyleLevel对象
使用 Levels(index) 返回单个 TextStyleLevel对象，其中 index 为 1 到 5 的数字，对应于五个大纲级别。以下示例为当前演示文稿的所有幻灯片设置字体名称和大小、段前空间、第一级正文文本的段落对齐。
With ActivePresentation.SlideMaster _
        .TextStyles(ppBodyStyle).Levels(1)
    With .Font
        .Name = "Arial"
        .Size = 36
    End With
    With .ParagraphFormat
        .LineRuleBefore = False
        .SpaceBefore = 14
        .Alignment = ppAlignJustify
    End With
End With
TextStyleLevels集合对象
TextStyles (TextStyle)
TextStyleLevels (TextStyleLevel)
  Font
  ParagraphFormat
所有大纲文本级别的集合。该集合总是包含五个成员，每个成员由一个TextStyleLevel对象代表。
使用 TextStyleLevels集合
使用 Levels(index) 返回单个 TextStyleLevel对象，其中 index 为 1 到 5 的数字，对应于五个大纲级别。以下示例为当前演示文稿的所有幻灯片设置第一级正文文本的字体名称和大小。
With ActivePresentation.SlideMaster _
        .TextStyles(ppBodyStyle).Levels(1)
    With .Font
        .Name = "Arial"
        .Size = 36
End With
End With
以下示例为当前演示文稿的所有备注页的备注正文区域的每个大纲级别文本设置字体大小。
With ActivePresentation.NotesMaster.TextStyles(ppBodyStyle).Levels
    .Item(1).Font.Size = 34
    .Item(2).Font.Size = 30
    .Item(3).Font.Size = 25
    .Item(4).Font.Size = 20
    .Item(5).Font.Size = 15
End With

weiyingde

TextStyles集合对象
Master
TextStyles (TextStyle)
  Ruler
  TextFrame
  TextStyleLevels (TextStyleLevel)
标题文本、正文文本和默认文本 三个文本样式 的集合，其中每个文本样式由一个TextStyle对象表示。每个文本样式包含一个描述文本在文本边框中的放置方式的TextFrame对象、一个包含制表位和大纲缩进格式信息的Ruler对象、一个包含大纲文本格式化信息的TextStyleLevels集合。
使用 TextStyles集合
使用 TextStyles(index) 返回单个 TextStyle对象，其中 index 为 ppBodyStyle、ppDefaultStyle 或 ppTitleStyle。本示例设置当前演示文稿所有备注页上备注正文区域的边距。
With ActivePresentation.NotesMaster _
        .TextStyles(ppBodyStyle).TextFrame
    .MarginBottom = 50
    .MarginLeft = 50
    .MarginRight = 50
    .MarginTop = 50
End With
ThreeDFormat对象
Shapes (Shape)
ThreeDFormat
  ColorFormat
代表形状的三维格式。
使用 ThreeDFormat对象
使用 ThreeD属性可返回一个 ThreeDFormat对象。以下示例向myDocument 中添加一个椭圆，然后指定该椭圆被挤压 50 磅的深度且延伸为紫色。
Set myDocument = ActivePresentation.Slides(1)
Set myShape = myDocument.Shapes _
    .AddShape(msoShapeOval, 90, 90, 90, 40)
With myShape.ThreeD
    .Visible = True
    .Depth = 50
    'RGB value for purple
    .ExtrusionColor.RGB = RGB(255, 100, 255)
End With
说明
不能对某些形状应用三维格式，例如斜截形状或多处间断的路径。对这些形状，ThreeDFormat对象的大多数属性和方法将失败。
TimeLine对象
多个对象
TimeLine
  多个对象
存储 Master、Slide 或 SlideRange对象的动画信息。
使用 TimeLine对象
使用Master、Slide 或SlideRange对象的TimeLine属性返回 TimeLine对象。
TimeLine对象的MainSequence属性可获得访问主动画序列的权限，而InteractiveSequences属性可获得访问单张幻灯片或幻灯片范围的交互式动画序列集合的权限。若要引用日程表对象，请使用与这些编码示例类似的语法：
ActivePresentation.Slides(1).TimeLine.MainSequence
ActivePresentation.SlideMaster.TimeLine.InteractiveSequences
ActiveWindow.Selection.SlideRange.TimeLine.InteractiveSequences

weiyingde

Timing对象
多个对象
Timing
  Shape
代表动画效果的计时属性。
使用 Timing对象
若要返回 Timing对象，请使用AnimationBehavior 或Effect对象的Timing属性。以下示例设置主动画的计时持续时间的信息。
ActiveWindow.Selection.SlideRange(1).TimeLine _
   .MainSequence(1).Timing.Duration = 5
使用 Timing对象的可读写属性处理动画计时效果。
使用此...        若要更改此...
Accelerate
加速过程持续时间的百分比
AutoReverse
是否应该正向播放效果后再反向播放效果，这样会使持续时间加倍
Decelerate
减速过程持续时间的百分比
Duration
动画长度（以秒为单位）
RepeatCount
重复动画的次数
RepeatDuration
重复动作持续的时间（以秒为单位）
Restart
重新启动动画节点的动作
RewindAtEnd
效果结束后对象是否返回其开始位置
SmoothStart
效果启动时是否加速
SmoothEnd
效果结束时是否减速
TriggerDelayTime
启用触发产生的延迟时间（以秒为单位）
TriggerShape
与计时效果有关的形状
TriggerType
触发计时效果的方法
View对象
DocumentWindow
View
  多个对象
代表指定文档窗口中当前编辑的视图。
使用 View对象
使用DocumentWindow对象的View属性返回 View对象。以下示例设置第一个窗口的大小，并将缩放比例设为适应新窗口大小。
With Windows(1)
    .Height = 200
    .Width = 250
    .View.ZoomToFit = True
End With
注意  View对象可以代表任何文档窗口视图：普通视图、幻灯片视图、大纲视图、幻灯片浏览视图、备注页视图、幻灯片母版视图、讲义母版视图或备注母版视图。View对象的某些属性和方法仅在特定视图中使用。如果试图使用不适合 View对象的属性或方法，将产生错误。
WebOptions对象
Presentation
WebOptions
包含演示文稿级的属性，当将整个或部分演示文稿作为 Web 页发布和保存或在打开 Web 页时，Microsoft PowerPoint 会使用这些属性。用户可以在应用程序（全局）级或演示文稿级返回或设置属性。（请注意，不同演示文稿的属性值可能不同，取决于在保存演示文稿时的属性值。）演示文稿级的属性设置会覆盖应用程序级的属性设置。应用程序级的属性包含在DefaultWebOptions对象中。
使用 WebOptions对象
使用WebOptions属性可返回 WebOptions对象。以下示例将检查在第一篇演示文稿中是否可以将可移植网络图形 (PNG) 作为图像格式使用。如果允许使用 PNG，则以下示例会将大纲窗格中的文字颜色设置为白色，将大纲和幻灯片窗格中的背景色设置为黑色。
Set objAppWebOptions = Presentations(1).WebOptions
With objAppWebOptions
    If .AllowPNG = True Then
        .FrameColors = ppFrameColorsWhiteTextOnBlack
    End If
End With

weiyingde

Accelerate属性
返回或设置 Single 变量，它代表加速过程持续时间的百分比。例如，数值 0.9 意味着动画将在前 90% 的时间内逐渐加速到默认速度，并在最后 10% 的时间内保持默认速度。可读写。
expression.Accelerate
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
若要在动画结束时减速，请使用Decelerate属性。
VBA示例
本示例添加了一个形状并添加一个动画，慢速启动并在动画序列进行到 30% 时达到默认速度。
Sub AddShapeSetTiming()
    Dim effDiamond As Effect
    Dim shpRectangle As Shape
    'Adds rectangle and specifies effect to use for rectangle
    Set shpRectangle = ActivePresentation.Slides(1) _
        .Shapes.AddShape(Type:=msoShapeRectangle, _
        Left:=100, Top:=100, Width:=50, Height:=50)
    Set effDiamond = ActivePresentation.Slides(1) _
        .TimeLine.MainSequence.AddEffect(Shape:=shpRectangle, _
        effectId:=msoAnimEffectPathDiamond)
    'Specifies the acceleration for the effect
    With effDiamond.Timing
        .Accelerate = 0.3
    End With
End Sub
AcceleratorsEnabled属性
决定幻灯片放映期间快捷键是否可用。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。（如果幻灯片放映期间快捷键被禁用，则可以在幻灯片放映中使用键进行导航或按 F1 得到快捷键列表。还可以使用 ESC 退出幻灯片放映。）
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 默认值。幻灯片放映期间启用快捷键。
expression.Paste
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例运行当前演示文稿的一个幻灯片放映并禁用快捷键。
ActivePresentation.SlideShowSettings.Run _
    .View.AcceleratorsEnabled = False
Accent属性
决定垂直强调线是否分隔标注文本与标注线。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 垂直强调线分隔标注文本与标注线。
expression.Accent
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例在myDocument 中添加一个椭圆和指向该椭圆的标注。标注文本没有边界，但包含将文本与标注线分隔开的垂直强调线。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes
    .AddShape msoShapeOval, 180, 200, 280, 130
    With .AddCallout(msoCalloutTwo, 420, 170, 170, 40)
        .TextFrame.TextRange.Text = "My oval"
        With .Callout
            .Accent = msoTrue
            .Border = msoFalse
        End With
    End With
End With

weiyingde

Accumulate属性
设置或返回MsoAnimAccumulate 类型常数，它代表是否累加动画动作。可读写。
MsoAnimAccumulate 可以是下列 MsoAnimAccumulate 类型常数之一。
msoAnimAccumulateAlways 使用当前值重复启动。
msoAnimAccumulateNone 默认值。
expression.Accumulate
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
将此属性和Additive属性联合使用以合并动画效果。
VBA示例
以下示例允许指定的动画动作与其他动画动作进行累加。
Sub SetAccumulate()
    Dim animBehavior As AnimationBehavior
    Set animBehavior = ActiveWindow.Selection.SlideRange(1).TimeLine. _
        MainSequence(1).Behaviors(1)
    animBehavior.Accumulate = msoAnimAccumulateAlways
End Sub
Action属性
返回或设置在幻灯片放映期间，单击指定形状或将鼠标指针定位到形状上时会产生的动作的类型。 可以是下列PpActionType 类型常数之一。可读写。Long 类型。
ppActionEndShow
ppActionFirstSlide
ppActionHyperlink
ppActionLastSlide
ppActionLastSlideViewed
ppActionMixed
ppActionNamedSlideShow
ppActionNextSlide
ppActionNone
ppActionOLEVerb
ppActionPlay
ppActionPreviousSlide
ppActionRunMacro
ppActionRunProgram
可将 Action属性与 ActionSetting对象的其他属性一起使用，如下表所示：
如果您设置
Action属性的值为        使用此属性        可实现
ppActionHyperlink        Hyperlink
设置超链接的属性，遵照该属性可响应幻灯片放映过程中对形状的鼠标操作。
ppActionRunProgram        Run
返回或设置程序名以响应幻灯片放映过程中对形状的鼠标操作。
ppActionRunMacro        Run
返回或设置宏名以响应幻灯片放映过程中对形状的鼠标操作。
ppActionOLEVerb        ActionVerb
设置 OLE 动词，调用该动词可响应幻灯片放映过程中对形状的鼠标操作。
ppActionNamedSlideShow        SlideShowName
设置自定义放映名称以响应幻灯片放映过程中对形状的鼠标操作。
VBA示例
本示例设置当前演示文稿第一张幻灯片的第三个形状（OLE对象），使其在幻灯片放映过程中当鼠标移过它时播放。
With ActivePresentation.Slides(1) _
    .Shapes(3).ActionSettings(ppMouseOver)
        .ActionVerb = "Play"
        .Action = ppActionOLEVerb
End With
ActionSettings属性
返回一个ActionSettings对象，该对象包含幻灯片放映时，用户在指定形状或文本区中移动或单击鼠标所产生的动作的信息。只读。
VBA示例
本示例设置在活动演示文稿的第二张幻灯片的第一个形状中移动或单击鼠标时产生的动作。
Set myShape = ActivePresentation.Slides(2).Shapes(1)
myShape.ActionSettings(ppMouseClick).Action = ppActionLastSlide
myShape.ActionSettings(ppMouseOver).SoundEffect.Name = "applause"
ActionVerb属性
应用于 PlaySettings对象的 ActionVerb属性。
返回或设置包含 OLE 动词的字符串，该字符串在幻灯片放映期间当指定的 OLE对象被激活时运行。默认动词指定 OLE对象在上一个动画或幻灯片切换之后运行的操作（例如，播放一波形文件或显示数据使得用户可以进行修改）。可读写。String 类型。
应用于 ActionSetting对象的 ActionVerb属性。
返回或设置包含 OLE 动词的字符串，该 OLE 动词在幻灯片放映期间当用户单击指定的形状或将鼠标指针移过它时运行。要使Action属性影响幻灯片操作，该属性必须首先设置为 ppActionOLEVerb。可读写。String 类型。
VBA示例
应用于 PlaySettings 对象。
本示例指定当前演示文稿第一张幻灯片的第三个形状被激活时将自动打开并进行编辑。但第三个形状必须是包含声音或视频对象并支持“Edit”动词的 OLE对象。
Set OLEobj = ActivePresentation.Slides(1).Shapes(3)
With OLEobj.AnimationSettings.PlaySettings
    .PlayOnEntry = True
    .ActionVerb = "Edit"
End With
应用于 ActionSetting对象。
本示例将第一张幻灯片的第三个形状设置为：只要鼠标指针在幻灯片放映时移过该形状就会被播放。但第三个形状必须是支持“Play”动词的 OLE对象。
With ActivePresentation.Slides(1).Shapes(3) _
        .ActionSettings(ppMouseOver)
    .ActionVerb = "Play"
    .Action = ppActionOLEVerb
End With
Active属性
返回指定的窗格或窗口是否处于激活的状态。只读。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 指定的窗格或窗口处于激活状态。
expression.Active
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例检查演示文稿文件“test.ppt”是否位于当前窗口。如果不是，则将当前处于激活状态的演示文稿的名称保存在变量oldWin 中，并激活“test.ppt”演示文稿。
With Application.Presentations("test.ppt").Windows(1)
    If Not .Active Then
        Set oldWin = Application.ActiveWindow
        .Activate
    End If
End With