ppt学习资料

weiyingde

AfterEffect属性
应用于EffectInformation对象的 AfterEffect属性。
返回一个MsoAnimAfterEffect 常数，它表示动画播放后效果是变暗、隐藏，还是不改变。只读。
MsoAnimAfterEffect 可以是下列 MsoAnimAfterEffect 类型常数之一。
msoAnimAfterEffectDim
msoAnimAfterEffectHide
msoAnimAfterEffectHideOnNextClick
msoAnimAfterEffectMixed
msoAnimAfterEffectNone
expression.AfterEffect
expression  必选。该表达式返回一个EffectInformation对象。
应用于 AnimationSettings对象的 AfterEffect属性。
返回或设置一个PpAfterEffect 常数，它表示在创建指定的形状之后该形状是变暗、隐藏，还是不改变。可读写。
PpAfterEffect 可以是下列 PpAfterEffect 类型常数之一。
ppAfterEffectDim
ppAfterEffectHide
ppAfterEffectHideOnClick
ppAfterEffectMixed
ppAfterEffectNothing
expression.AfterEffect
expression  必选。该表达式返回一个AnimationSettings对象。
说明
除非带有动画播放后效果的形状播放动画，且幻灯片上至少有另一个形状在其播放后播放动画；否则无法看到为该形状设置的动画播放后效果。对于要动画显示的形状，该形状的 AnimationSettings对象的TextLevelEffect属性必须设为除 ppAnimateLevelNone 以外的值，或者EntryEffect属性必须设为 ppEffectNone 以外的常数。且Animate属性必须设为 True。若要更改一张幻灯片中形状的创建顺序，请使用AnimationOrder属性。
VBA示例
本示例指定当前演示文稿中第一张幻灯片的标题在创建后变暗。但是，如果它是第一张幻灯片中最后的或唯一的形状，文本将不会变暗。
With ActivePresentation.Slides(1).Shapes.Title.AnimationSettings
    .Animate = True
    .TextLevelEffect = ppAnimateByAllLevels
    .AfterEffect = ppAfterEffectDim
End With
Alignment属性
应用于 TextEffectFormat对象的 Alignment属性。
为指定的艺术字返回或设置对齐方式。可读写。MsoTextEffectAlignment 类型。
MsoTextEffectAlignment 可以是下列 MsoTextEffectAlignment 类型常数之一。
msoTextEffectAlignmentCentered
msoTextEffectAlignmentLeft
msoTextEffectAlignmentMixed
msoTextEffectAlignmentRight
msoTextEffectAlignmentStretchJustify
msoTextEffectAlignmentWordJustify
msoTextEffectAlignmentLetterJustify
expression.Alignment
expression  必选。该表达式返回一个 TextEffectFormat对象。
应用于 ParagraphFormat对象的 Alignment属性。
以指定的段落格式为每个段落返回或设置对齐方式。可读写。PpParagraphAlignment 类型。
PpParagraphAlignment 可以是下列 PpParagraphAlignment 类型常数之一。
ppAlignCenter
ppAlignDistribute
ppAlignJustify
ppAlignJustifyLow
ppAlignLeft
ppAlignmentMixed
ppAlignRight
ppAlignThaiDistribute
expression.Alignment
expression  必选。表达式返回一个 ParagraphFormat对象。
VBA示例
应用于 TextEffectFormat对象。
本示例在当前演示文稿的第一张幻灯片中添加艺术字对象并将它右对齐。
Set mySh = Application.ActivePresentation.Slides(1).Shapes
Set myTE = mySh.AddTextEffect(PresetTextEffect:=msoTextEffect1, _
    Text:="Test Text", FontName:="Palatino", FontSize:=54, _
    FontBold:=True, FontItalic:=False, Left:=100, Top:=50)
myTE.TextEffect.Alignment = msoTextEffectAlignmentRight
应用于 ParagraphFormat对象。
本示例将当前演示文稿第一张幻灯片第二个形状中的段落左对齐。
Application.ActivePresentation.Slides(1).Shapes(2) _
    .TextFrame.TextRange.ParagraphFormat.Alignment = ppAlignLeft

weiyingde

AllowPNG属性
决定当以 Web 页保存或发布一篇完整的或部分演示文稿时，是否允许将 PNG (Portable Network Graphics) 作为输出格式。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 默认值。以 Web 页保存或发布一篇完整的或部分演示文稿时，不允许将 PNG 作为输出格式。
msoTriStateMixed
msoTriStateToggle
msoTrue 以 Web 页保存或发布一篇完整的或部分演示文稿时，允许将 PNG 作为图像格式。
expression.AllowPNG
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
如果将图像保存为 PNG 格式而非其他文件格式，则可以提高图像的质量或减小图像文件的大小，因而也就可以减少下载所需的时间，前提是所使用的 Web 浏览器支持 PNG 格式。
VBA示例
本示例允许将 PNG 格式作为当前演示文稿的输出格式。
ActivePresentation.WebOptions.AllowPNG = msoTrue
另外，也可将 PNG 作为新建演示文稿中应用程序的全局默认设置。
Application.DefaultWebOptions.AllowPNG = msoTrue
AlternativeText属性
在 Web 演示文稿中返回或设置与某形状相关的可选文字。可读写。String 类型。
VBA示例
以下示例设置活动窗口中选定形状的可选文字。选定的形状为一幅野鸭的图片。
ActiveWindow.Selection.ShapeRange _
    .AlternativeText = "This is a mallard duck."
AlwaysSaveInDefaultEncoding属性
决定保存 Web 页或纯文本文档时是否使用默认编码，以及文件的原始编码打开时是否独立。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 默认值。保存 Web 页或纯文本文档时使用文件的原始编码，并且文件的原始编码打开时独立。
msoTriStateMixed
msoTriStateToggle
msoTrue 保存 Web 页或纯文本文档时使用默认编码，并且文件的原始编码打开时独立。
expression.AlwaysSaveInDefaultEncoding
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
Encoding属性可用于设置默认编码。
VBA示例
本示例将编码设置为默认编码。当用户将文档保存为 Web 页时使用该编码。
Application.DefaultWebOptions.AlwaysSaveInDefaultEncoding = msoTrue
Amount属性
返回或设置 Single 变量，它代表具有动画效果的形状绕 Z 轴旋转的度数。正值表示顺时针旋转；负值表示逆时针旋转。可读写。
expression.Amount
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例添加了一个形状，并且给该形状添加了一个旋转 90 度的动画。
Sub SetAnimEffect()
    Dim effSpin As Effect
    Dim shpCube As Shape
    Set shpCube = ActivePresentation.Slides(1).Shapes.AddShape _
        (Type:=msoShapeCube, Left:=100, Top:=100, _
        Width:=50, Height:=50)
    Set effSpin = ActivePresentation.Slides(1).TimeLine _
        .MainSequence.AddEffect(Shape:=shpCube, _
        effectId:=msoAnimEffectSpin)
    effSpin.Timing.Duration = 3
    effSpin.EffectParameters.Amount = -90
End Sub

weiyingde

Angle属性
返回或设置标注线的角度。如果标注线包含多条线段，则该属性返回或设置距标注文本框最远的线段的角度。可读写。MsoCalloutAngleType 类型。
MsoCalloutAngleType 可以是下列 MsoCalloutAngleType 类型常数之一。
msoCalloutAngle30
msoCalloutAngle45
msoCalloutAngle60
msoCalloutAngle90
msoCalloutAngleAutomatic 拖动标注时标注线保持一个固定的角度。
msoCalloutAngleMixed
expression.Angle
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例为myDocument 上称为“co1”的标注设置 90 度的标注角度。
Set myDocument = ActivePresentation.Slides(1)
myDocument.Shapes("co1").Callout.Angle = msoCalloutAngle90
决定幻灯片放映期间指定的形状是否为动画。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 幻灯片放映期间指定的形状为动画。
expression.Animate
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
要使形状以动画方式播放，针对图形的 AnimationSettings对象的TextLevelEffect属性必须设置为除 ppAnimateLevelNone 以外的值，并且 Animate属性必须设置为 True, 或者EntryEffect属性必须设置为除 ppEffectNone 外的常数。
VBA示例
本示例指定当前演示文稿第二张幻灯片的标题在创建后变暗。如果该标题是第二张幻灯片中的最后一个或唯一创建的形状，则该文本不变暗。
With ActivePresentation.Slides(2).Shapes.Title.AnimationSettings
    .TextLevelEffect = ppAnimateByAllLevels
    .AfterEffect = ppAfterEffectDim
    .Animate = msoTrue
End With
AnimateAction属性
MsoTrue 如果指定鼠标动作发生时该指定形状的颜色立即反转，则使用该属性值。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue
expression.AnimateAction
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例设置在幻灯片放映过程中，单击当前演示文稿第一张幻灯片的第三个形状时播放掌声，并立即反转该形状的颜色。
With ActivePresentation.Slides(1) _
    .Shapes(3).ActionSettings(ppMouseClick)
        .SoundEffect.Name = "applause"
        .AnimateAction = msoTrue
End With

weiyingde

AnimateBackground属性
应用于 AnimationSettings对象的 AnimateBackground属性。
如果指定对象是自选图形，则形状与其所含的文本分别动画时该属性值为 msoTrue；如果指定形状是图表对象，则指定图表对象的背景（坐标轴和网格线）动画显示时该属性值为 msoTrue。仅应用于包含可多步创建的文本的自选图形或者图表对象。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue
expression.AnimateBackground
expression  必选。该表达式返回一个AnimationSettings对象。
应用于 EffectInformation对象的 AnimateBackground属性。
如果指定的效果是背景动画，则返回 MsoTrue。只读。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue
expression.AnimateBackground
expression  必选。该表达式返回上述对象之一。
说明
使用TextLevelEffect 和TextUnitEffect属性控制放入指定形状中的文本的动画效果。
如果设置该属性为 MsoTrue 并设置 TextLevelEffect属性为 ppAnimateByAllLevels，形状及其文本将被同时赋予动画效果。如果设置该属性为 MsoTrue 并设置 TextLevelEffect属性为非 ppAnimateByAllLevels 的值，则形状将在文本之前直接被赋予动画效果。
如果不给指定形状赋予动画效果，则看不到设置该属性的效果。对于要赋予动画效果的形状，必须将该形状的 TextLevelEffect属性设置为非 ppAnimateLevelNone 的值，并且必须将Animate属性设置为 MsoTrue，或者必须将EntryEffect属性设置为一个非 ppEffectNone 的常数。
VBA示例
应用于 AnimationSettings对象。
本示例创建一个包含文本的矩形框。本示例还指定该形状应该从右下角飞入，文本应该从第一级段落创建，且该形状应该与其所包含的文本分别动画显示。在本示例中，EntryEffect属性用于打开动画显示。
Sub AnimateTextBox()
    With ActivePresentation.Slides(1).Shapes.AddShape _
            (Type:=msoShapeRectangle, Left:=50, Top:=200, _
            Width:=200, Height:=200)
        .TextFrame.TextRange = "Reason 1" & Chr(13) & _
        "Reason 2" & Chr(13) & "Reason 3"
        With .AnimationSettings
            .EntryEffect = ppEffectFlyFromBottomRight
            .TextLevelEffect = ppAnimateByFirstLevel
            .TextUnitEffect = ppAnimateByParagraph
            .AnimateBackground = msoTrue
        End With
    End With
End Sub
应用于 EffectInformation对象。
本示例中，如果背景当前具有动画效果，则更改该动画的方向。
Sub ChangeAnimationDirection()
    With ActivePresentation.Slides(1).TimeLine.MainSequence(1)
        If .EffectInformation.AnimateBackground = msoTrue Then
            .EffectParameters.Direction = msoAnimDirectionTopLeft
        End If
    End With
End Sub

weiyingde

AnimateTextInReverse属性
决定指定形状是否按相反顺序构造。仅应用于具有多个创建步骤的形状（例如，包含列表的形状）。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 指定形状按相反顺序构造。
expression.AnimateTextInReverse
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
指定形状必须被赋予动画效果，才能看到设置该属性的效果。要为某个形状赋予动画效果，必须将 AnimationSettings对象的 TextLevelEffect属性设为除 ppAnimateLevelNone 以外的值，并且Animate属性必须设为 True。
VBA示例
本示例在当前演示文稿的第一张幻灯片后添加一张幻灯片，然后设置标题文本，并为文本占位符添加三个项的列表，并设置该列表按相反顺序构造。
With ActivePresentation.Slides.Add(2, ppLayoutText).Shapes
    .Item(1).TextFrame.TextRange.Text = "Top Three Reasons"
    With .Item(2)
        .TextFrame.TextRange = "Reason 1" & Chr(13) _
            & "Reason 2" & Chr(13) & "Reason 3"
        With .AnimationSettings
            .Animate = msoTrue
            .TextLevelEffect = ppAnimateByFirstLevel
            .AnimateTextInReverse = msoTrue
        End With
    End With
End With

weiyingde

AnimationOrder属性
返回或设置一个整数，该整数代表指定形状在设为动画的形状集合中的位置。可读写。Long 类型。
说明
指定形状必须被赋予动画效果，才能看到设置该属性的效果。要给一个形状赋予动画效果，必须将 AnimationSettings对象的 TextLevelEffect属性设为非 ppAnimateLevelNone 的值，并且Animate属性必须设为 True。
注意  如果设置 AnimationOrder属性值为一个小于现存的AnimationOrder 最大属性值，就可以改变动画顺序。
VBA示例
本示例指定活动演示文稿中第二张幻灯片第二个形状的动画显示次序为二。
ActivePresentation.Slides(2).Shapes(2) _
    .AnimationSettings.AnimationOrder = 2
AnimationSettings属性
返回一个AnimationSettings对象，该对象代表可应用于指定形状的所有特殊效果。
expression.AnimationSettings
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例设置在创建幻灯片时，当前演示文稿第二张幻灯片的第一个形状从左侧飞入。
With ActivePresentation.Slides(2).Shapes(1).AnimationSettings
    .EntryEffect = ppEffectFlyFromLeft
    .TextLevelEffect = ppAnimateByAllLevels
End With
AnswerWizard属性
返回 AnswerWizard对象，该对象中包含联机“帮助”搜索引擎所使用的文件。只读。
Application属性
返回一个Application对象，该对象代表指定对象的创建者。
expression.Application
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例中，一个Presentation对象被传送至某过程。此过程在演示文稿中添加一张幻灯片，然后将其保存在 Microsoft PowerPoint 运行的文件夹中。
Sub AddAndSave(pptPres As Presentation)
    pptPres.Slides.Add 1, 1
    pptPres.SaveAs pptPres.Application.Path & "\Added Slide"
End Sub
本示例显示在当前演示文稿的第一张幻灯片上创建每个链接的 OLE对象的应用程序的名称。
For Each shpOle In ActivePresentation.Slides(1).Shapes
    If shpOle.Type = msoLinkedOLEObject Then
        MsgBox shpOle.OLEFormat.Application.Name
    End If
Next

weiyingde

Assistant属性
本主题中的有些内容可能不适用于某些语言。
返回一个 Assistant对象，该对象代表“Office 助手”。只读。
VBA示例
本示例显示“Office 助手”。
Application.Assistant.Visible = True
本示例将“Office 助手”移到屏幕的左上角。
Application.Assistant.Move xLeft:=100, yTop:=100
Author属性
返回 String 的值，该值代表指定Comment对象的作者。只读。
expression.Author
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
此属性只返回作者姓名。若要返回作者姓和名的首字母，请使用AuthorInitials属性。在向演示文稿中添加新的批注时指定批注的作者。
VBA示例
以下示例向当前演示文稿的第一张幻灯片中添加批注，然后以消息的形式显示作者的姓名以及姓和名的首字母。
Sub GetAuthorName()
    With ActivePresentation.Slides(1)
        .Comments.Add Left:=100, Top:=100, Author:="Jeff Smith", _
            AuthorInitials:="JS", _
            Text:="This is a new comment added to the first slide."
        MsgBox "This comment was created by " & _
            .Comments(1).Author & " (" & .Comments(1).AuthorInitials & ")."
    End With
End Sub
AuthorIndex属性
返回 Long 的值，该值代表给定作者的批注的索引号。给定作者第一个批注的索引号为 1，第二个批注的索引号为 2，以此类推。只读。
expression.AuthorIndex
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例提供了给定幻灯片中作者及其批注索引的信息。
Sub GetCommentAuthorInfo()
    Dim cmtComment As Comment
    Dim strAuthorInfo As String
    With ActivePresentation.Slides(1)
        If .Comments.Count > 0 Then
            For Each cmtComment In .Comments
                strAuthorInfo = strAuthorInfo & "Comment Number:  " & _
                    cmtComment.AuthorIndex & vbLf & _
                    "Made by:  " & cmtComment.Author & vbLf & _
                    "Says:  " & cmtComment.Text & vbLf & vbLf
            Next cmtComment
        End If
    End With
    MsgBox "The comments for this slide are as follows: " & _
        vbLf & vbLf & strAuthorInfo
End Sub

weiyingde

AuthorInitials属性
以只读 String 的形式返回指定Comment对象的作者姓和名的首字母。只读。
expression.AuthorInitials
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
此属性只返回作者姓和名的首字母。若要返回作者的姓名，请使用Author属性。在向演示文稿中添加新的批注时指定作者姓和名的首字母。
VBA示例
以下示例返回指定批注的作者姓和名的首字母。
Sub GetAuthorName()
    With ActivePresentation.Slides(1)
        .Comments.Add Left:=100, Top:=100, Author:="Jeff Smith", _
            AuthorInitials:="JS", _
            Text:="This is a new comment added to the first slide."
        MsgBox .Comments(1).Author & .Comments(1).AuthorInitials
    End With
End Sub
AutoAttach属性
根据标注线的原始位置（标注指向的位置）是在标注文本框的左边还是右边，决定标注线附加到标注文本框的位置。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 标注线附加到标注文本框的位置，取决于标注线原始位置（标注指向的位置）是在标注文本框的左边还是右边。
说明
当该属性值为 msoTrue 时，如果文本框位于原始位置右侧，则下移值（从标注文本框的边界到标注线附加位置的垂直距离）从文本框顶部开始测量；如果文本框位于原始位置左侧，则下移值从文本框底部开始测量。当该属性值为 msoFalse 时，下移值总是从文本框顶部开始测量，而不管文本框与原始位置的相对位置。使用CustomDrop方法设置下移值，并使用Drop属性返回下移值。
仅当明确设置下移值（即DropType属性值为 msoCalloutDropCustom）后，设置该属性才会影响标注。默认情况下，创建标注时已经明确设置了下移值。
VBA示例
本示例为第一张幻灯片添加两个标注，其中一个是自动附加的，另一个则不是。如果将自动附加标注的标注行的原始位置改到附加的文本框的右侧，该文本框的位置就会发生变化。而对于非自动附加的标注则不会存在此现象。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes
    With .AddCallout(msoCalloutTwo, 420, 170, 200, 50)
        .TextFrame.TextRange.Text = "auto-attached"
        .Callout.AutoAttach = msoTrue
    End With
    With .AddCallout(msoCalloutTwo, 420, 350, 200, 50)
        .TextFrame.TextRange.Text = "not auto-attached"
        .Callout.AutoAttach = msoFalse
    End With
End With

weiyingde

AutoCorrect属性
返回AutoCorrect对象，该对象代表 Microsoft PowerPoint 中的“自动更正”功能。
expression.AutoCorrect
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例禁止显示“自动更正选项”和“自动版式选项”按钮。
Sub HideAutoCorrectOpButton()
    With Application.AutoCorrect
        .DisplayAutoCorrectOptions = msoFalse
        .DisplayAutoLayoutOptions = msoFalse
    End With
End Sub
AutoFormat属性
设置或返回 MsoTriState 类型常数，该常数代图示的自动套用格式状态。可读写。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue 不应用于此属性。
msoFalse 不启用自动套用格式。
msoTriStateMixed 不应用于此属性。
msoTriStateToggle 不应用于此属性。
msoTrue 启用自动套用格式。
expression.AutoFormat
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例创建一个图表并启用自动套用格式。
Sub ConvertPyramidDiagram()
    Dim dgnNode As DiagramNode
    Dim shpDiagram As Shape
    Dim intNodes As Integer
    'Adds pyramid diagram and first child node
    Set shpDiagram = ActivePresentation.Slides(1).Shapes _
        .AddDiagram(Type:=msoDiagramPyramid, Left:=10, _
        Top:=15, Width:=400, Height:=475)
    Set dgnNode = shpDiagram.DiagramNode.Children.AddNode
    'Adds three additional nodes
    For intNodes = 1 To 3
        dgnNode.AddNode
    Next intNodes
    'Automatically formats the diagram nodes and
    'converts pyramid diagram to radial diagram
    With dgnNode.Diagram
        .AutoFormat = msoTrue
        .Convert Type:=msoDiagramRadial
    End With
End Sub

weiyingde

AutoLength属性
在移动标注时，可决定标注的第一段是保持Length属性指定的固定长度，还是被自动缩放。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。仅应用于由多条线段组成线条的标注（类型 msoCalloutThree 和 msoCalloutFour）。
msoCTrue
msoFalse 无论何时移动标注，标注线的第一段都保持 Length属性指定的固定长度。
msoTriStateMixed
msoTriStateToggle
msoTrue 无论何时移动标注，标注线的第一段（附加到文本标注框的段）都自动缩放。
说明
该属性是只读的。使用AutomaticLength方法设置该属性为 msoTrue，并且使用CustomLength方法设置该属性为 msoFalse。
VBA示例
本示例使myDocument 第一个形状的标注线在对第一段自动缩放和对第一段使用固定长度之间进行切换。要使本示例执行，第一个形状必须是标注。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(1).Callout
    If .AutoLength Then
        .CustomLength 50
    Else
        .AutomaticLength
    End If
End With
AutoLoad属性
决定指定的加载宏在每次启动 PowerPoint 时是否自动加载。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 每次启动 PowerPoint 时，自动加载指定的加载宏。
说明
设置该属性为 msoTrue 的同时会自动设置Registered属性为 msoTrue。
VBA示例
本示例显示每次启动 PowerPoint 时自动加载的每个加载项的名称。
For Each myAddIn In AddIns
    If myAddIn.AutoLoad Then
        MsgBox myAddIn.Name
        afound = True
    End If
Next myAddIn
If afound <> True Then
    MsgBox "No add-ins were loaded automatically."
End If
本示例指定名为“MyTools”的加载项在每次启动 PowerPoint 时自动加载。
Application.AddIns("mytools").AutoLoad = msoTrue
AutomationSecurity属性
返回或设置MsoAutomationSecurity 常数，该常数代表用编程方式打开文件时 Microsoft PowerPoint 使用的安全模式。启动应用程序时，此属性自动设置为msoAutomationSecurityLow 值。因此，为了避免破坏基于默认设置的解决方案，在用编程方式打开文件后要注意将此属性重新设置为 msoAutomationSecurityLow。同样，在用编程方式打开文件之前或之后都应立即设置此属性以避免遭受蓄意破坏。可读写。
MsoAutomationSecurity 可以是下列 MsoAutomationSecurity 类型常数之一。
msoAutomationSecurityByUI 使用在“安全性”对话框中指定的安全设置。
msoAutomationSecurityForceDisable 禁用所有以编程方式打开的文件中的所有宏而不显示任何安全警告。
msoAutomationSecurityLow 启用所有的宏。启动应用程序时此参数为默认值。
expression.AutomationSecurity
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
DisplayAlerts属性的值将不会应用于安全警告。例如，如果用户将 DisplayAlerts属性设置为 False 并将 AutomationSecurity属性设置为 msoAutomationSecurityByUI，而用户又处于中等安全级别，则在运行宏时将出现安全警告。此属性将允许宏捕获打开文件时产生的错误，这样即使文件成功打开，仍将显示安全警告。
VBA示例
本示例捕获当前的自动安全设置，将该设置更改为禁用宏，显示“打开”对话框，并在打开选定的演示文稿之后将自动安全性恢复为其原始设置。
Sub Security()
    Dim secAutomation As MsoAutomationSecurity
    secAutomation = Application.AutomationSecurity
    Application.AutomationSecurity = msoAutomationSecurityForceDisable
    Application.FileDialog(msoFileDialogOpen).Show
    Application.AutomationSecurity = secAutomation
End Sub