ppt学习资料

weiyingde

ZOrder方法
将集合中指定的形状移动到其他形状前面或后面（也就是说，改变形状在 Z 顺序中的位置）。
expression.ZOrder(ZOrderCmd)
expression  必选。该表达式返回一个 Shape对象。
ZOrderCmd  必选。MsoZOrderCmd 类型。指定所指定形状相对于其他形状移动的位置。
MsoZOrderCmd 可以是下列 MsoZOrderCmd 类型常数之一。
msoBringForward
msoBringInFrontOfText 仅用于 Microsoft Word。
msoBringToFront
msoSendBackward
msoSendBehindText 仅用于 Microsoft Word。
msoSendToBack
说明
使用ZOrderPosition属性判断一个形状在 Z 顺序中的当前位置。
VBA示例
本示例向myDocument 中添加椭圆，如果幻灯片中有至少一个其他形状，则将该椭圆放置在 Z 顺序中倒数第二的位置上。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.AddShape(msoShapeOval, 100, 100, 100, 300)
    While .ZOrderPosition > 2
        .ZOrder msoSendBackward
    Wend
End With

weiyingde

ActionSetting对象
多个对象
ActionSettings (ActionSetting)
Hyperlink
SoundEffect
包含指定形状或文本范围在幻灯片放映中对鼠标动作的反应的信息。ActionSetting对象是ActionSettings集合的成员。ActionSettings集合包含一个 ActionSetting对象（该对象代表幻灯片放映中用户单击指定对象时的反应）和一个 ActionSetting对象（该对象代表幻灯片放映中用户将鼠标移过指定对象时的反应）。
使用 ActionSetting对象
使用 ActionSettings(index) 返回单个 ActionSetting对象，其中 index 是 ppMouseClick 或 ppMouseOver。以下示例设定单击当前演示文稿第一张幻灯片第三个形状中的文本时，连接到 Internet 上。
With ActivePresentation.Slides(1).Shapes(3) _
        .TextFrame.TextRange.ActionSettings(ppMouseClick)
    .Action = ppActionHyperlink
    .Hyperlink.Address = "http://www.microsoft.com"
End With
说明
如果设置了 ActionSetting对象的属性但没有效果，请确认将Action属性设为相应的值。
ActionSettings集合对象
多个对象
ActionSettings (ActionSetting)
Hyperlink
SoundEffect
包含两个ActionSetting对象的集合，这些对象用于形状或文本范围。其中一个 ActionSetting对象代表幻灯片放映中用户单击指定对象时的反应；另一个 ActionSetting对象代表幻灯片放映中用户将鼠标移过指定对象时的反应。
使用 ActionSettings集合
使用ActionSettings属性返回 ActionSettings集合。使用 ActionSettings(index) 返回单个 ActionSetting对象，其中 index 是 ppMouseClick 或 ppMouseOver。以下示例指定幻灯片放映中鼠标移过某形状时执行宏“CalculateTotal”。
With ActivePresentation.Slides(1).Shapes(3) _
        .ActionSettings(ppMouseOver)
    .Action = ppActionRunMacro
    .Run = "CalculateTotal"
    .AnimateAction = True
End With
AddIn对象
Application
AddIns (AddIn)
加载或未加载的对象都代表单个加载宏。AddIn对象是AddIns集合的成员之一。无论是否加载 PowerPoint 指定的加载宏，AddIns集合都包含所有可用的加载宏。该集合不包含组件对象模型 (COM) 加载宏。
使用 AddIn对象
使用 AddIns(index) 返回单个 AddIn对象，其中 index 是加载宏的标题或索引编号。以下示例加载 My Ppt Tools 加载宏。
AddIns("my ppt tools").Loaded = True
不要将显示在上方的加载宏标题与加载宏名称相混淆，该名称是加载宏的文件名。在 Add-Ins对话框中键入该标题时必须正确拼写，但是不一定要大写匹配。
索引编号代表了加载宏在 Add-Ins对话框的可用 Add-Ins 列表中的位置。以下示例显示了当前 PowerPoint 中加载的所有加载宏的名称。
For i = 1 To AddIns.Count
    If AddIns(i).Loaded Then MsgBox AddIns(i).Name
Next
说明
可以使用Add方法向可用加载宏列表中添加与 PowerPoint 相关的加载宏。注意，使用该方法并不会加载加载宏。如果要加载加载宏，请在使用 Add方法后将加载宏的Loaded属性设为 True。可以单步执行这些动作，如以下示例所示（注意，Add方法使用加载宏名称而不使用标题）。
AddIns.Add("generic.ppa").Loaded = True
使用 AddIns(index) 可返回一个对已加载的加载宏的引用，其中 index 表示加载宏的标题。以下示例将变量presAddin 设置成标题为“my ppt tools”的加载宏，并将变量myName 设置成该加载宏的名称。
Set presAddin = AddIns("my ppt tools")
With presAddin
    myName = .Name
End With

weiyingde

AddIns集合对象
Application
AddIns (AddIn)
无论是否加载 Microsoft PowerPoint 指定的对 PowerPoint 可用的加载宏，AddIn对象集合都包含所有加载宏。这里不包含组件对象模型 (COM) 加载宏。
使用 AddIns集合
使用 AddIns方法返回 AddIns集合。以下示例显示 PowerPoint 中当前加载的所有加载宏的名称。
For Each ad In AddIns
    If ad.Loaded Then MsgBox ad.Name
Next
可以使用Add方法向可用加载宏列表中添加与 PowerPoint 相关的加载宏。Add方法将加载宏添加到列表中但不加载它。要加载它，请在使用 Add方法后将将加载宏的Loaded属性设为 True。可以单步执行这些动作，如以下示例所示（注意，Add方法使用加载宏名称而不使用标题）。
AddIns.Add("graphdrs.ppa").Loaded = True
使用 AddIns(index) 可返回单个 AddIn对象，其中 index 表示加载宏的标题或索引编号。以下示例加载假定标题为“My Ppt Tools”的加载宏。
AddIns("my ppt tools").Loaded = True
不要把加载宏标题与加载宏名称相混淆，该标题是加载宏的文件名。在 Add-Ins对话框中键入该标题时必须正确拼写，但是不一定要大写匹配。
Adjustments对象
Shapes (Shape)
Adjustments
它包含指定的自选图形、艺术字对象或连接符的调整值的集合。每个调整值代表了调整句柄可以调整的方向。因为某些调整句柄有两个调整方向（例如，某些调整句柄可以在水平和垂直两个方向调整），所以形状的调整指数量可以大于调整句柄的数量。一个形状最多可有八种调整。
使用 Adjustments对象
使用 Adjustments属性返回 Adjustments对象。使用 Adjustments(index) 返回单个调整值，其中 index 是调整值的索引编号。
不同的形状有不同数量的调整值，不同的调整值以不同的方式改变形状的几何外形，且不同的调整值有不同的有效值范围。例如，以下示例显示右箭头标注的四个调整值分别如何影响该标注几何外形的定义。

注意  由于每个形状有不同的调整值集，校验指定形状的调整行为的最好方法是手动创建一个图例，在打开宏记录器的情况下作调整，然后检查记录的代码。
下表总结了不同类型调整值的有效范围。大多数情况下，如果指定了超出有效范围的值，调整值将被分配一个最接近所设值的有效值。
调整类型        有效值
线性（水平或垂直）        通常 0.0 值代表形状的左边界或上边界，而 1.0 值代表形状的右边界或下边界。有效值对应于有效的手动调整。例如，如果只能将调整控点手动拖动形状的一半宽度，则相应的调整值最大为 0.5。对于象连接符和标注这样的形状，0.0 和 1.0 值代表由它们的起始和终止点定义的矩形界限，此时负值和大于 1.0 的值是有效的。
径向        调整值 1.0对应于形状宽度。最大值为 0.5，或形状宽度的一半。
角度        调整值用度表示。如果指定的值超出了 - 180 到 180 这个范围，就将它在该范围内标准化。
以下示例向myDocument 中添加右箭头标注，并且设置该标注的调整值。请注意，尽管形状只有三个调整句柄，但是它有四个调整值。第三和第四个调整值都和箭头头部和颈部间的调整句柄相对应。
Set myDocument = ActivePresentation.Slides(1)
Set rac = myDocument.Shapes _
    .AddShape(msoShapeRightArrowCallout, 10, 10, 250, 190)
With rac.Adjustments
    .Item(1) = 0.5    'adjusts width of text box
    .Item(2) = 0.15   'adjusts width of arrow head
    .Item(3) = 0.8    'adjusts length of arrow head
    .Item(4) = 0.4    'adjusts width of arrow neck
End With

weiyingde

AnimationBehavior对象
AnimationBehaviors
AnimationBehavior
多个对象
代表动画效果的动作、主动画序列或交互式动画序列。AnimationBehavior对象是AnimationBehaviors集合中的成员。
使用 AnimationBehavior对象
使用Behaviors(index) 返回单个 AnimationBehavior对象，其中 index 是动作序列中动作的编号。以下示例设置旋转的起点和终点的位置。本示例假设主动画序列的第一个动作是一个RotationEffect对象。
Sub Change()
    With ActivePresentation.Slides(1).TimeLine.MainSequence(1) _
            .Behaviors(1).RotationEffect
        .From = 1
        .To = 180
    End With
End Sub
AnimationBehaviors集合
Effect
AnimationBehaviors
  AnimationBehavior
代表AnimationBehavior对象的集合。
使用 AnimationBehaviors集合
使用Add方法添加一个动画动作。以下示例在第一张幻灯片的主动画序列中添加一个五秒钟的动画旋转动作。
Sub AnimationObject()
    Dim timeMain As TimeLine
    'Reference the main animation timeline
    Set timeMain = ActivePresentation.Slides(1).TimeLine
    'Add a five-second animated rotation behavior
    'as the first animation in the main animation sequence
    timeMain.MainSequence(1).Behaviors.Add Type:=msoAnimTypeRotation, Index:=1
End Sub

weiyingde

AnimationPoint对象
AnimationPoints
AnimationPoint

代表动画动作的单个动画点。AnimationPoint对象是AnimationPoints集合的成员。AnimationPoints集合包含动画动作的所有动画点。
使用 AnimationPoint对象
若要添加或引用 AnimationPoint对象，请分别使用Add 或Item方法。使用 AnimationPoint对象的Time属性设置动画点之间的计时。使用Value属性设置其他动画点属性，如颜色。以下示例在当前演示文稿的主动画序列的第一个动作中添加三个动画点，然后更改每个动画点的颜色。
Sub AniPoint()
    Dim sldNewSlide As Slide
    Dim shpHeart As Shape
    Dim effCustom As Effect
    Dim aniBehavior As AnimationBehavior
    Dim aptNewPoint As AnimationPoint
    Set sldNewSlide = ActivePresentation.Slides.Add _
        (Index:=1, Layout:=ppLayoutBlank)
    Set shpHeart = sldNewSlide.Shapes.AddShape _
        (Type:=msoShapeHeart, Left:=100, Top:=100, _
        Width:=200, Height:=200)
    Set effCustom = sldNewSlide.TimeLine.MainSequence _
        .AddEffect(shpHeart, msoAnimEffectCustom)
    Set aniBehavior = effCustom.Behaviors.Add(msoAnimTypeProperty)
    With aniBehavior.PropertyEffect
        .Property = msoAnimShapeFillColor
        Set aptNewPoint = .Points.Add
        aptNewPoint.Time = 0.2
        aptNewPoint.Value = RGB(0, 0, 0)
        Set aptNewPoint = .Points.Add
        aptNewPoint.Time = 0.5
        aptNewPoint.Value = RGB(0, 255, 0)
        Set aptNewPoint = .Points.Add
        aptNewPoint.Time = 1
        aptNewPoint.Value = RGB(0, 255, 255)
    End With
End Sub
AnimationPoints集合
PropertyEffect
AnimationPoints
  AnimationPoint

代表PropertyEffect对象动画点的集合。
使用 AnimationPoints集合
使用PropertyEffect对象的Points属性返回 AnimationPoints集合对象。以下示例在当前演示文稿的主动画序列的第一个动作中添加一个动画点。
Sub AddPoint()
    ActivePresentation.Slides(1).TimeLine.MainSequence(1) _
        .Behaviors(1).PropertyEffect.Points.Add
End Sub
从一个动画点切换到另一动画点有时可能会不连续或不平稳。使用此Smooth属性可使切换更平稳。本示例使动画点之间的切换更平稳。
Sub SmoothTransition()
    ActivePresentation.Slides(1).TimeLine.MainSequence(1) _
        .Behaviors(1).PropertyEffect.Points.Smooth = msoTrue
End Sub

weiyingde

AnimationSettings对象
Shapes (Shape)
AnimationSettings
  ColorFormat
  PlaySettings
  SoundEffect
代表幻灯片放映时应用于指定形状的动画的特殊效果。
使用 AnimationSettings对象
使用 Shape对象的AnimationSettings属性返回 AnimationSettings对象。以下示例在当前演示文稿中添加一张幻灯片，其中包含标题和一个三项列表，然后设置该列表由第一级段落激活，从左侧飞入，被制成动画后变暗为指定颜色，并且其中的项目按逆向激活。
Set sObjs = ActivePresentation.Slides.Add(2, ppLayoutText).Shapes
sObjs.Title.TextFrame.TextRange.Text = "Top Three Reasons"
With sObjs.Placeholders(2)
    .TextFrame.TextRange.Text = _
        "Reason 1" & VBNewLine & "Reason 2" & VBNewLine & "Reason 3"
    With .AnimationSettings
        .TextLevelEffect = ppAnimateByFirstLevel
        .EntryEffect = ppEffectFlyFromLeft
        .AfterEffect = ppAfterEffectDim
        .DimColor.RGB = RGB(100, 120, 100)
        .AnimateTextInReverse = True
    End With
End With
Application对象
Application
多个对象
代表整个 Microsoft PowerPoint 应用程序。Application对象包括：
应用程序范围内的设置和选项（例如，当前打印机的名称）
用于返回顶层对象的属性，例如 ActivePresentation、Windows 等。
使用 Application对象
使用 Application属性返回 Application对象。以下示例返回应用程序文件的路径。
Dim MyPath As String
MyPath = Application.Path
以下示例在其他应用程序中创建一个 PowerPoint Application对象，并启动 PowerPoint（如果还未运行的话），然后打开一个名为“Ex_a2a.ppt”的现有演示文稿。
Set ppt = New Powerpoint.Application
ppt.Visible = True
ppt.Presentations.Open "c:\My Documents\ex_a2a.ppt"
说明
编写要在 PowerPoint 中运行的编码时，以下 Application对象的属性可以在没有对象限定符的情况下使用：ActivePresentation、ActiveWindow、AddIns、Assistant、CommandBars、Presentations、SlideShowWindows 和 Windows。例如，可以用ActiveWindow.Height = 200 来代替Application.ActiveWindow.Height = 200。

weiyingde

AutoCorrect对象
Application
AutoCorrect

代表 Microsoft PowerPoint 中的“自动更正”功能。
使用 AutoCorrect对象
使用AutoCorrect属性返回一个 AutoCorrect对象。以下示例禁止显示“自动更正选项”按钮。
Sub HideAutoCorrectOpButton()
    With Application.AutoCorrect
        .DisplayAutoCorrectOptions = msoFalse
        .DisplayAutoLayoutOptions = msoFalse
    End With
End Sub
Borders集合对象
多个对象
Borders (LineFormat)
LineFormat对象的集合，代表表格中某个单元格或单元格范围的边框和对角线。
使用 Borders集合
每个 Cell对象或 CellRange集合在 Borders集合中都具有六个元素。用户不能向 Borders集合中添加对象。
使用 Borders(index) 返回单个 Border对象，其中 index 标识单元格的边框线或对角线，Index 可以是任何PPBorderType 常数。
PPBorderType 可以是下列 PPBorderType 类型常数之一。
ppBorderBottom
ppBorderLeft
ppBorderRight
ppBorderTop
ppBorderDiagonalDown
ppBorderDiagonalUp
使用DashStyle属性可将虚线样式应用于 Border对象。本示例选择表格中的第二行，然后对下框线应用虚线样式。
ActiveWindow.Selection.ShapeRange.Table.Rows(2) _
    .Cells.Borders(ppBorderBottom).DashStyle = msoLineDash
BulletFormat对象
ParagraphFormat
BulletFormat
  Font
代表项目符号的格式。
使用 BulletFormat对象
使用Bullet属性返回 BulletFormat对象。以下示例设置当前演示文稿第一张幻灯片第二个形状中段落的项目符号大小和颜色。
With ActivePresentation.Slides(1).Shapes(2)
    With .TextFrame.TextRange.ParagraphFormat.Bullet
        .Visible = True
        .RelativeSize = 1.25
        .Character = 169
        With .Font
            .Color.RGB = RGB(255, 255, 0)
            .Name = "Symbol"
        End With
    End With
End With
CalloutFormat对象
Shapes (Shape)
CalloutFormat
包含应用于行标注的属性和方法。
使用 CalloutFormat对象
使用 Callout属性返回单个 CalloutFormat对象。以下示例指定的myDocument 中第三个形状（行标注）的属性如下：
标注中含有一个垂直的强调线，用于分隔文本和标注行。
标注行同标注文本框侧边所构成的角度为 30 度。
标注文本没有边框。
标注行将连接到标注文本框的顶部。
标注行中将包含两段。
要使本示例起作用，第三个形状必须是一个标注。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(3).Callout
    .Accent = True
    .Angle = msoCalloutAngle30
    .Border = False
    .PresetDrop msoCalloutDropTop
    .Type = msoCalloutThree
End With

weiyingde

Cell对象
多个对象
CellRange (Cell)
  多个对象
代表表格单元格。Cell对象属于CellRange集合的成员。CellRange集合代表指定列或行中的所有单元格。利用 Cells 关键字可使用 CellRange集合。
使用 Cell对象
使用方法为：Cell(row, column)，这里，row 表示行号，column 表示列标；或者也可这样使用：Cells(index)，这里 index 表示指定行或列中单元格的编号，使用后返回的结果为一个 Cell对象。单元格的编号方法是：在行中从左向右进行编号；在列中则从上到下进行编号。对于从右向左的语言设置，将使用相反的方案。以下示例将合并表格（第二张幻灯片上的第五个形状）中第一行上的前两个单元格。
With ActivePresentation.Slides(2).Shapes(5).Table
    .Cell(1, 1).Merge MergeTo:=.Cell(1, 2)
End With
本示例将表格第一列中第一个单元格的下框设置为虚线样式。
With ActivePresentation.Slides(2).Shapes(5).Table.Columns(1) _
        .Cells(1)
    .Borders(ppBorderBottom).DashStyle = msoLineDash
End With
使用Shape属性可访问 Shape对象并处理每个单元格中的内容。本示例删除第一个单元格（第一行、第一列）中的文本、并插入新文本，然后将整列的宽度设置为 110 磅。
With ActivePresentation.Slides(2).Shapes(5).Table.Cell(1, 1)
    .Shape.TextFrame.TextRange.Delete
    .Shape.TextFrame.TextRange.Text = "Rooster"
    .Parent.Columns(1).Width = 110
End With
说明
不能用编程的方法一次向 PowerPoint 表格中添加多个单元格或从中删除多个单元格。但使用 Columns 或 Rows集合的 Add方法可以向表格中添加一列或一行；使用 Columns 或 Rows集合的 Delete方法可以从表格中删除一列或一行。
CellRange集合对象
多个对象
CellRange (Cell)
  多个对象
表格列或行中Cell对象的集合。CellRange集合代表指定列或行中的所有单元格。利用 Cells 关键字可使用 CellRange集合。
使用 CellRange集合
使用 Cells属性可返回 CellRange集合。本示例将表格中第一列单元格的右边框设置为虚线样式。
With ActivePresentation.Slides(2).Shapes(5).Table.Columns(1).Cells
    .Borders(ppBorderRight).DashStyle = msoLineDash
End With
本示例返回选定表格中第一行的单元格数。
num = ActiveWindow.Selection.ShapeRange.Table.Rows(1).Cells.Count
使用 Cell(row, column)（其中 row 表示行号，column 表示列号）或者使用 Cells(index)（其中 index 表示指定行或列的单元格编号）返回一个 Cell对象。单元格的编号方法是：在行中从左向右进行编号，在列中则从上到下进行编号。对于从右向左的语言设置，将使用相反的方案。以下示例将合并第二张幻灯片第五个形状的表格中第一行的前两个单元格。
With ActivePresentation.Slides(2).Shapes(5).Table
    .Cell(1, 1).Merge MergeTo:=.Cell(1, 2)
End With
说明
虽然集合对象名为 CellRange 且显示在“对象浏览器”中，但此关键字不能用于 PowerPoint对象模型编程。而应该使用 Cells 关键字。
不能用编程的方法一次向 PowerPoint 表格中添加多个单元格或从中删除多个单元格。但使用 Table对象的 AddTable方法可以添加一个新表格；使用 Columns 或 Rows集合的 Add方法可以向表格中添加一列或一行；使用 Columns 或 Rows集合的 Delete方法可以从表格中删除一列或一行。

weiyingde

ColorEffect对象
AnimationBehavior
ColorEffect
  ColorFormat

代表动画动作的一种颜色效果。
使用 ColorEffect对象
使用AnimationBehavior对象的ColorEffect属性返回 ColorEffect对象。颜色效果可以使用 ColorEffect对象的From 和To属性更改，如下所示。颜色效果最初使用 To属性设置，然后可以使用By属性按指定的编号进行更改。以下示例向当前演示文稿的第一张幻灯片中添加一个形状，并且将颜色效果动画动作设置为更改新形状的填充颜色。
Sub ChangeColorEffect()
    Dim sldFirst As Slide
    Dim shpHeart As Shape
    Dim effNew As Effect
    Dim bhvEffect As AnimationBehavior
    Set sldFirst = ActivePresentation.Slides(1)
    Set shpHeart = sldFirst.Shapes.AddShape(Type:=msoShapeHeart, _
        Left:=100, Top:=100, Width:=100, Height:=100)
    Set effNew = sldFirst.TimeLine.MainSequence.AddEffect _
        (Shape:=shpHeart, EffectID:=msoAnimEffectChangeFillColor, _
        Trigger:=msoAnimTriggerAfterPrevious)
    Set bhvEffect = effNew.Behaviors.Add(Type:=msoAnimTypeColor)
    With bhvEffect.ColorEffect
        .From.RGB = RGB(Red:=255, Green:=0, Blue:=0)
        .To.RGB = RGB(Red:=0, Green:=0, Blue:=255)
    End With
End Sub

weiyingde

ColorFormat对象
多个对象
ColorFormat
代表单色对象的颜色、带有过渡或图案填充的对象的前景或背景色，或者指针的颜色。可以将颜色设为显式的红-绿-蓝值（使用RGB属性）或设为配色方案中的一种颜色（使用SchemeColor属性）。
使用 ColorFormat对象
使用下表中列出的属性之一返回 ColorFormat对象。
使用此属性       
对此对象        如果要返回一个 ColorFormat对象，该对象代表
DimColor
AnimationSettings        变暗对象使用的颜色
BackColor
FillFormat        背景填充色（用于底纹或图案填充）
ForeColor
FillFormat        前景填充色（或填充色仅为单色）
Color
Font        项目符号或字符颜色
BackColor
LineFormat        背景线颜色（使用带图案的线）
ForeColor
LineFormat        前景线颜色（或线条颜色仅为实线）
ForeColor
ShadowFormat        阴影颜色
PointerColor
SlideShowSettings        演示文稿的默认指针颜色
PointerColor
SlideShowView        幻灯片放映视图中的临时指针颜色
ExtrusionColor
ThreeDFormat        凸出对象的侧面颜色
可以使用SchemeColor属性将幻灯片元素的颜色设置为标准配色方案中的颜色。以下示例将当前演示文稿第二张幻灯片第一个形状的文本颜色设为标准配色方案的标题颜色。
ActivePresentation.Slides(2).Shapes(1).TextFrame _
    .TextRange.Font.Color.SchemeColor = ppTitle
使用RGB属性将颜色设置为显示的红-绿-蓝值。以下示例向myDocument 中添加一个矩形，然后设置矩形填充的前景色、背景色和过渡。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.AddShape(msoShapeRectangle, 90, 90, 90, 50).Fill
    .ForeColor.RGB = RGB(128, 0, 0)
    .BackColor.RGB = RGB(170, 170, 170)
    .TwoColorGradient msoGradientHorizontal, 1
End With
ColorScheme对象
多个对象
ColorScheme
  RGBColor
代表一种配色方案。该配色方案是八种颜色的组合，分别用于幻灯片、备注页或讲义中不同的元素，例如标题或背景（请注意，演示文稿中幻灯片、备注页或讲义的配色方案可以单独设置）。每种颜色由一个RGBColor对象代表。ColorScheme对象是ColorSchemes集合的成员。ColorSchemes集合包含演示文稿中所有的配色方案。
使用 ColorScheme对象
本节描述如何进行下列操作：
从演示文稿的所有配色方案的集合中返回 ColorScheme对象。
返回附加到指定幻灯片或母版的 ColorScheme对象。
从 ColorScheme对象返回单个幻灯片元素的颜色。
从演示文稿的所有配色方案的集合中返回 ColorScheme对象
使用 ColorSchemes(index) 返回单个 ColorScheme对象，其中 index 是幻灯片配色方案索引号。以下示例删除当前演示文稿第二个配色方案。
ActivePresentation.ColorSchemes(2).Delete
返回附加到指定幻灯片或母版的 ColorScheme对象
设置 Slide、SlideRange 或 Master对象的ColorScheme属性可分别返回一张幻灯片、一组幻灯片、或一个幻灯片母版的配色方案。以下示例创建一个基于当前幻灯片的配色方案，将新配色方案添加到演示文稿的标准配色方案集合中，并将幻灯片母版的配色方案设为新的配色方案。所有基于该母版的幻灯片将具有该配色方案。
Set newScheme = ActiveWindow.View.Slide.ColorScheme
newScheme.Colors(ppTitle).RGB = RGB(0, 150, 250)
Set newStandardScheme = _
    ActivePresentation.ColorSchemes.Add(newScheme)
ActivePresentation.SlideMaster.ColorScheme = newStandardScheme
从 ColorScheme对象返回单个幻灯片元素的颜色
使用Colors方法返回 RGBColor对象，该对象代表一个幻灯片元素类型的颜色。可以将一个 RGBColor对象设置为另一个 RGBColor对象，或使用RGB属性设置或返回 RGBColor对象的显式的红-绿-蓝（RGB）值。以下示例将第一个配色方案的背景色设为红色，并将标题颜色设为第二个配色方案中定义的标题颜色。
With ActivePresentation.ColorSchemes
    .Item(1).Colors(ppBackground).RGB = RGB(255, 0, 0)
    .Item(1).Colors(ppTitle) = .Item(2).Colors(ppTitle)
End With