ppt学习资料

weiyingde

ColorSchemes集合对象
Presentation
ColorScheme
  RGBColor
指定演示文稿中的所有ColorScheme对象的集合。每个 ColorScheme对象代表一种配色方案，即用于幻灯片的一组颜色。
使用 ColorSchemes集合
使用ColorSchemes属性返回 ColorSchemes集合。使用 ColorSchemes(index) 返回单个 ColorScheme对象，其中 index 是配色方案索引号。以下示例删除当前演示文稿的第二个配色方案。
ActivePresentation.ColorSchemes(2).Delete
使用Add方法新建配色方案并将其添加到 ColorSchemes集合中。以下示例在当前演示文稿中添加一种配色方案，并设置该配色方案的标题颜色和背景色（由于使用 Add方法未加参数，添加的配色方案与演示文稿中第一个标准配色方案相同）。
With ActivePresentation.ColorSchemes.Add
    .Colors(ppTitle).RGB = RGB(255, 0, 0)
    .Colors(ppBackground).RGB = RGB(128, 128, 0)
End With
设置 Slide、SlideRange 或 Master对象的ColorScheme属性，分别返回一张幻灯片、一组幻灯片或一个幻灯片母版。以下示例将当前演示文稿中所有幻灯片的配色方案设为演示文稿中的第三个配色方案。
With ActivePresentation
    .Slides.Range.ColorScheme = .ColorSchemes(3)
End With
Column对象
Table
Columns (Column)
  CellRange (Cell)
代表表格中的一列。Column对象是Columns集合中的成员。Columns集合包括表格中的所有列。
使用 Column对象
使用 Columns(index) 可返回一个 Column对象。Index 代表 Columns集合中列的位置（通常是从左向右计算的；但TableDirection属性可变换计算方向）。本示例选择第二张幻灯片第五个形状的表格中的第一列。
ActivePresentation.Slides(2).Shapes(5).Table.Columns(1).Select
使用 Cell对象可间接引用 Column对象。本示例删除第一个单元格（第一行，第一列）中的文本，并插入新文本，然后将整列的宽度设置为 110 磅。
With ActivePresentation.Slides(2).Shapes(5).Table.Cell(1, 1)
    .Shape.TextFrame.TextRange.Delete
    .Shape.TextFrame.TextRange.Text = "Rooster"
    .Parent.Columns(1).Width = 110
End With
使用Add方法可向表格中添加一列。本示例在现有表格中创建一列，然后将列宽设置为 72 磅（1 英寸）。
With ActivePresentation.Slides(2).Shapes(5).Table
    .Columns.Add.Width = 72
End With
说明
使用Cells属性可修改 Column对象中的个别单元格。本示例选择表格的第一列并对其下边框应用虚线样式。
ActiveWindow.Selection.ShapeRange.Table.Columns(1) _
    .Cells.Borders(ppBorderBottom).DashStyle = msoLineDash

weiyingde

DefaultWebOptions对象
Application
DefaultWebOptions

包含全局的应用程序级属性；当将整个或部分演示文稿作为 Web 页发布或保存，或打开 Web 页时，Microsoft PowerPoint 会使用这些属性。用户可以在应用程序（全局）级或演示文稿级返回或设置属性。（请注意，不同演示文稿的属性值可能不同，这取决于保存演示文稿时的属性值。）演示文稿级的属性设置会覆盖应用程序级的属性设置。演示文稿级的属性包含在WebOptions对象中。
使用 DefaultWebOptions对象
使用DefaultWebOptions属性可返回 DefaultWebOptions对象。以下示例将检查是否可以将 PNG（可移植网络图形）作为图像格式，然后相应地设置strImageFileType 变量。
Set objAppWebOptions = Application.DefaultWebOptions
With objAppWebOptions
    If .AllowPNG = True Then
        strImageFileType = "PNG"
    Else
        strImageFileType = "JPG"
    End If
End With
Design对象
多个对象
Design
  Master
代表单张幻灯片设计模板。Design对象是Designs 和SlideRange集合以及Master 和Slide对象的成员。
使用 Design对象
使用 Master、Slide 或 SlideRange对象的Design属性访问 Design对象，例如：
ActivePresentation.SlideMaster.Design
ActivePresentation.Slides(1).Design
ActivePresentation.Slides.Range.Design
分别使用 Designs集合的Add、Item、Clone 或Load方法添加、引用、复制或加载一个 Design对象。例如，若要添加一个设计模板，请使用ActivePresentation.Designs.Add designName:="MyDesign"
Design对象的AddTitleMaster方法和HasTitleMaster属性可以用来添加和/或查询标题幻灯片母版的状态。例如：
Sub AddQueryTitleMaster(dsn As Design)
    dsn.AddTitleMaster
    MsgBox dsn.HasTitleMaster
End Sub
Designs集合
Presentation
Designs
  Design

代表幻灯片设计模板的集合。
使用 Designs集合
使用Presentation对象的Designs属性引用一个设计模板。
若要添加或复制单个的设计模板，请分别使用 Designs集合的Add 或Clone方法。若要引用单个的设计模板，请使用Item方法。
若要加载一个设计模板，请使用Load方法。
以下示例在 Designs集合中添加一个新设计模板并确认新模板已正确添加。
Sub AddDesignMaster()
    With ActivePresentation.Designs
        .Add designName:="MyDesignName"
        MsgBox .Item("MyDesignName").Name
    End With
End Sub

weiyingde

Diagram对象
多个对象
Diagram
  DiagramNodes
代表文档中的单个图示。Diagram对象是DiagramNode 和Shape对象以及ShapeRange集合的成员。
使用 Diagram对象
使用Shape对象或ShapeRange集合中的 Diagram属性返回一个 Diagram对象。
使用Convert方法将图示更改为其他类型。本示例将当前演示文稿第一张幻灯片上的第一个图示转换为一个射线图。本示例假设当前演示文稿中的第一个形状是一个图示，而不是其他类型的形状。
Sub DiagramConvert()
    ActivePresentation.Slides(1).Shapes(1).Diagram _
        .Convert Type:=msoDiagramRadial
End Sub
使用 Reverse属性翻转图示中节点的顺序，以使第一个节点成为最后一个节点，并使最后一个节点变为第一个节点，以此类推。本示例将当前演示文稿第一张幻灯片第二个形状的图示节点的顺序颠倒。本示例假设当前演示文稿的第二个形状为一个图示，而不是其他类型的形状。
Sub DiagramReverse()
    ActivePresentation.Slides(1).Shapes(2).Diagram.Reverse = msoTrue
End Sub
DiagramNode对象可以包含一个嵌套的 Diagram对象。使用 DiagramNode对象的Diagram属性返回嵌套的 Diagram对象。
DiagramNode对象
多个对象
DiagramNode
  多个对象
代表图示中的一个节点。
使用 DiagramNode对象
若要返回一个 DiagramNode对象，请使用下列方法或属性之一：
DiagramNode对象的AddNode、CloneNode、NextNode 或PrevNode方法，或Root属性。
DiagramNodeChildren集合的AddNode 或Item方法，或FirstChild 或LastChild属性。
DiagramNodes集合的Item方法。
Shape对象或ShapeRange集合的DiagramNode属性。
图示节点可以是终点或包含其他子图示、图示子节点或子形状：
若要引用子图示，请使用Diagram属性。
若要引用单个图示子节点，请使用AddNode、CloneNode、NextNode 或PrevNode方法，或Root属性。
若要引用图示子节点的集合，请使用Children属性。
若要引用形状，请使用Shape 或TextShape属性。
使用AddNode方法在图示或图示节点中添加一个节点。本示例假设当前演示文稿的第三个形状是一个图示，并向其中添加一个节点。
Sub AddDiagramNode()
    ActivePresentation.Shapes(3).DiagramNode.Children.AddNode
End Sub
使用Delete方法从图示或图示节点中删除一个节点。本示例假设演示文稿中的第二个形状是一个图示，并删除其中的第一个节点。
Sub DeleteDiagramNode()
    ActivePresentation.Shapes(2).DiagramNode.Children(1).Delete
End Sub

weiyingde

DiagramNodeChildren集合
DiagramNode
DiagramNodeChildren
  DiagramNode

DiagramNode对象的集合，该集合代表图示中的子节点。
使用 DiagramNodeChildren集合
使用DiagramNode对象的Children属性返回 DiagamNodeChildren集合。若要在集合中添加单个图示子节点，请使用AddNode方法。若要返回集合中的单个图示子节点，请使用FirstChild 或LastChild属性或Item方法。
本示例删除文档中第一个图示第二个节点的第一个子节点。本示例假设当前文档的第一个形状为一个图示；并且该图示中至少有两个节点，且其中一个节点有子节点。
Sub DiagramNodeChild()
    ActiveDocument.Shapes(1).Diagram.Nodes.Item(2) _
        .Children.FirstChild.Delete
End Sub
DiagramNodes集合
Diagram
DiagramNodes
  DiagramNode

DiagramNode对象的集合，该集合代表图示中的所有节点。
使用 DiagramNodes集合
使用Diagram对象的Nodes属性返回一个 DiagramNodes集合。使用Item方法选择并使用图示中的单个图示节点。本示例假设当前演示文稿第一张幻灯片上的第一个形状是一个图示，本示例将选择第一个节点并将它删除。
Sub FillDiagramNode()
    ActivePresentation.Slides(1).Shapes(1).Diagram.Nodes.Item(1).Delete
End Sub
使用SelectAll方法选择并使用图示中的所有节点。本示例假设当前演示文稿第一张幻灯片上的第一个形状是一个图示，本示例将选择所有节点并使用指定图案填充它们。
Sub FillDiagramNodes()
    ActivePresentation.Slides(1).Shapes(1).Diagram.Nodes.SelectAll
    ActiveWindow.Selection.ShapeRange.Fill.Patterned _
        Pattern:=msoPatternSmallConfetti
End Sub
DocumentWindow对象
多个对象
DocumentWindows (DocumentWindow)
  Panes (Pane)
  Presentation
  Selection
  View
代表一个文档窗口。DocumentWindow对象是DocumentWindows集合的成员。DocumentWindows集合包含所有打开的文档窗口。
使用 DocumentWindow对象
使用 Windows(index) 返回单个 DocumentWindow对象，其中 index 是文档窗口索引号。以下示例激活第二个文档窗口。
Windows(2).Activate
DocumentWindows集合的第一个成员Windows(1) 始终返回当前文档窗口。另外，还可以使用ActiveWindow属性返回当前文档窗口。以下示例将当前窗口最大化。
ActiveWindow.WindowState = ppWindowMaximized
使用 Panes(index) 可处理文档窗口的普通视图、幻灯片视图、大纲视图或备注页视图中的窗格，其中 index 表示窗格的索引号。以下示例激活第三个窗格，也就是备注窗格。
ActiveWindow.Panes(3).Activate
使用ActivePane属性可返回文档窗口中的当前窗格。以下示例检查当前窗格是否为大纲窗格。如果不是，则激活大纲窗格。
mypane = ActiveWindow.ActivePane.ViewType
    If mypane <> 1 Then
        ActiveWindow.Panes(1).Activate
    End If
使用Presentation属性可返回指定文档窗口中当前运行的演示文稿。
使用Selection属性可返回选定内容。
使用SplitHorizontal属性可返回普通视图中大纲窗格所占屏幕宽度的百分比。
使用SplitVertical属性可返回普通视图中幻灯片窗格所占屏幕高度的百分比。
使用View属性可返回指定文档窗口中的视图。

weiyingde

DocumentWindows集合对象
多个对象
DocumentWindows (DocumentWindow)
  Presentation
  Selection
  View
在 PowerPoint 中，所有当前打开的DocumentWindow对象的集合。该集合不包含打开的幻灯片放映窗口，这些窗口包含在SlideShowWindows集合中。
使用 DocumentWindows集合
使用Windows属性返回 DocumentWindows集合。以下示例平铺打开的文档窗口。
Windows.Arrange ppArrangeTiled
使用NewWindow方法创建一个文档窗口并将其添加到 DocumentWindows集合中。以下示例为当前演示文稿新建一个窗口。
ActivePresentation.NewWindow
使用 Windows(index) 返回单个 DocumentWindow对象，其中 index 是窗口索引号。以下示例关闭第二个文档窗口。
Windows(2).Close
Effect对象
Sequence
Effect
  多个对象
代表有关幻灯片动画的计时信息。
使用 Effect对象
使用AddEffect方法添加一个效果。本示例在当前演示文稿的第一张幻灯片中添加一个形状，并为该形状添加一种效果和一个动作。
Sub NewShapeAndEffect()
    Dim shpStar As Shape
    Dim sldOne As Slide
    Dim effNew As Effect
    Set sldOne = ActivePresentation.Slides(1)
    Set shpStar = sldOne.Shapes.AddShape(Type:=msoShape5pointStar, _
        Left:=150, Top:=72, Width:=400, Height:=400)
    Set effNew = sldOne.TimeLine.MainSequence.AddEffect(Shape:=shpStar, _
        EffectId:=msoAnimEffectStretchy, Trigger:=msoAnimTriggerAfterPrevious)
    With effNew
        With .Behaviors.Add(msoAnimTypeScale).ScaleEffect
            .FromX = 75
            .FromY = 75
            .ToX = 0
            .ToY = 0
        End With
        .Timing.AutoReverse = msoTrue
    End With
End Sub
若要引用现有的 Effect对象，请使用MainSequence(index)，其中 index 是 Effect对象在Sequence集合中的编号。本示例更改第一个序列的效果并为该效果指定动作。
Sub ChangeEffect()
    With ActivePresentation.Slides(1).TimeLine _
        .MainSequence(1)
        .EffectType = msoAnimEffectSpin
        With .Behaviors(1).RotationEffect
            .From = 100
            .To = 360
            .By = 5
        End With
    End With
End Sub
不管幻灯片是否有动画，每张幻灯片中至少有一个 Effect对象。

weiyingde

EffectInformation对象
Effect
EffectInformation
  多个对象
代表Effect对象的各种动画选项。
使用 EffectInformation对象
使用 EffectInformation对象的成员返回 Effect对象的当前状态（例如，动画播放后的效果、背景是否与相应的文本一起动画显示、文本是否要反向动画显示、播放设置、声音效果、文本创建动作等等）。EffectInformation对象的所有成员都是只读的。若要更改任何效果信息属性，必须使用相应的Sequence对象的方法。
使用Effect对象的EffectInformation属性返回 EffectInformation对象。以下示例设置主动画序列中的播放设置的HideWhileNotPlaying属性。
Sub HideEffect()
    ActiveWindow.Selection.SlideRange(1).TimeLine _
        .MainSequence(1).EffectInformation.PlaySettings _
        .HideWhileNotPlaying = msoTrue
End Sub
EffectParameters对象
Effect
EffectParameters
  ColorFormat
代表Effect对象的各种动画参数，如颜色、字体、大小和方向。
使用 EffectParameters对象
使用 Effect对象的EffectParameters属性返回 EffectParameters对象。以下示例创建一个形状，然后设置填充效果并更改起始和结束填充颜色。
Sub effParam()
    Dim shpNew As Shape
    Dim effNew As Effect
    Set shpNew = ActivePresentation.Slides(1).Shapes _
        .AddShape(Type:=msoShapeHeart, Left:=100, _
        Top:=100, Width:=150, Height:=150)
    Set effNew = ActivePresentation.Slides(1).TimeLine.MainSequence _
        .AddEffect(Shape:=shpNew, EffectID:=msoAnimEffectChangeFillColor, _
        Trigger:=msoAnimTriggerAfterPrevious)
    With effNew.EffectParameters
        .Color1.RGB = RGB(Red:=0, Green:=0, Blue:=255)
        .Color2.RGB = RGB(Red:=255, Green:=0, Blue:=0)
    End With
End Sub

weiyingde

ExtraColors对象
Presentation
ExtraColors
代表演示文稿中的其他颜色。该对象最多可以包含八种颜色，每种颜色由一个RGB 值表示。
使用 ExtraColors
使用ExtraColors属性返回 ExtraColors对象。使用 ExtraColors(index) 返回单个其他颜色的红-绿-蓝（RGB）值，其中 index 是其他颜色索引号。以下示例在当前演示文稿的第一张幻灯片中添加一个矩形，并将前景填充颜色设为第一种其他颜色。如果演示文稿中没有定义任何其他颜色，此示例将失败。
With ActivePresentation
    Set rect = .Slides(1).Shapes _
        .AddShape(msoShapeRectangle, 50, 50, 100, 200)
    rect.Fill.ForeColor.RGB = .ExtraColors(1)
End With
使用Add方法添加其他颜色。以下示例在当前演示文稿中添加一个其他颜色（如果该颜色尚未被添加）。
ActivePresentation.ExtraColors.Add RGB(69, 32, 155)
FillFormat对象
Shapes (Shape)
FillFormat
  ColorFormat
代表形状的填充格式。形状可以有单色、过渡、纹理、图案、图片或半透明填充。
使用 FillFormat对象
使用 Fill属性返回 FillFormat对象。以下示例向myDocument 中添加矩形并且设置矩形填充的过渡和颜色。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes _
        .AddShape(msoShapeRectangle, 90, 90, 90, 80).Fill
    .ForeColor.RGB = RGB(0, 128, 128)
    .OneColorGradient msoGradientHorizontal, 1, 1
End With
说明
FillFormat对象的许多属性是只读的。要设置这些属性，必须使用相应的方法。

weiyingde

Font对象
对个对象
Font
  ColorFormat
代表文本或项目符号的字符格式。Font对象是Fonts集合的成员。Fonts集合包含演示文稿中使用的所有字体。
使用 Font对象
本节描述如何进行下列操作：
返回 Font对象，该对象代表指定的项目符号、指定的文本范围或指定大纲级别的所有文本的字体属性。
从演示文稿使用的所有字体的集合中返回一个 Font对象。
返回 Font对象，该对象代表指定的项目符号、指定的文本范围或指定大纲级别的所有文本的字体属性
使用Font属性返回 Font对象，该对象代表指定的项目符号、文本范围或指定大纲级别的所有文本的字体属性。以下示例设置第一张幻灯片的标题文本并设置字体属性。
With ActivePresentation.Slides(1).Shapes.Title _
        .TextFrame.TextRange
    .Text = "Volcano Coffee"
    With .Font
        .Italic = True
        .Name = "Palatino"
        .Color.RGB = RGB(0, 0, 255)
    End With
End With
从演示文稿使用的所有字体的集合中返回一个 Font对象
使用 Fonts(index) 返回单个 Font对象，其中 index 是字体名称或索引号。以下示例检查当前演示文稿中的第一种字体是否已嵌入。
If ActivePresentation.Fonts(1).Embedded = _
    True Then MsgBox "Font 1 is embedded"
Fonts集合对象
Presentation
Fonts (Font)
指定演示文稿中所有Font对象的集合。每个 Font对象代表演示文稿中使用的一种字体。
注意  “Geni Wizard”使用 Fonts集合来判断，Genigraphics对幻灯片进行图像处理时是否支持指定演示文稿中的字体。如果仅希望设置特定项目符号或文本范围的字符格式，请使用Font属性为项目符号或文本范围返回 Font对象。
使用 Fonts对象
使用Fonts属性返回 Fonts集合。以下示例显示当前演示文稿中使用的字体种数。
MsgBox ActivePresentation.Fonts.Count
使用 Fonts(index) 返回单个 Font对象，其中 index 是字体名称或索引号。以下示例检查当前演示文稿的第一种字体是否已嵌入。
If ActivePresentation.Fonts(1).Embedded = True Then
    MsgBox "Font 1 is embedded"

weiyingde

FreeformBuilder对象
多个对象
FreeformBuilder
  Shape
代表在创建任意多边形时使用的几何形状。
使用 FreeformBuilder对象
使用BuildFreeform方法返回一个 FreeformBuilder对象。使用AddNodes方法向任意多边形添加结点。使用ConvertToShape方法创建 FreeformBuilder对象中定义的形状并将其添加到Shapes集合中。以下示例在myDocument 中添加一个具有四段的任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.BuildFreeform(msoEditingCorner, 360, 200)
    .AddNodes msoSegmentCurve, msoEditingCorner, _
        380, 230, 400, 250, 450, 300
    .AddNodes msoSegmentCurve, msoEditingAuto, 480, 200
    .AddNodes msoSegmentLine, msoEditingAuto, 480, 400
    .AddNodes msoSegmentLine, msoEditingAuto, 360, 200
    .ConvertToShape
End With
GroupShapes集合对象
Shapes (Shape)
GroupShapes (Shape)
代表形状组中的单个形状。每个形状由一个Shape对象代表。对本对象使用Item方法，就可以使用形状组中的单个形状而无须对它们取消组合。
使用 Groupshapes集合
使用GroupItems属性返回 GroupShapes集合。使用 GroupItems(index) 返回 GroupShapes集合中的单个形状，其中 index 是组合形状中单个形状的数目。以下示例向myDocument 中添加三个三角形，将它们组合并设置整个组的颜色，然后只更改第二个三角形的颜色。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes
    .AddShape(msoShapeIsoscelesTriangle, 10, _
        10, 100, 100).Name = "shpOne"
    .AddShape(msoShapeIsoscelesTriangle, 150, _
        10, 100, 100).Name = "shpTwo"
    .AddShape(msoShapeIsoscelesTriangle, 300, _
        10, 100, 100).Name = "shpThree"
    With .Range(Array("shpOne", "shpTwo", "shpThree")).Group
        .Fill.PresetTextured msoTextureBlueTissuePaper
        .GroupItems(2).Fill.PresetTextured msoTextureGreenMarble
    End With
End With

weiyingde

HeaderFooter对象
Slides (Slide)
HeaderFooters
  HeaderFooter
代表幻灯片或母版中的页眉、页脚、日期和时间、幻灯片编号或页码。所有幻灯片或母版的 HeaderFooter对象包含在一个HeadersFooters对象中。
使用 HeaderFooter对象
使用以下表格中的属性之一返回 HeaderFooter对象。
使用此属性        返回
DateAndTime
代表幻灯片的日期和时间的 HeaderFooter对象。
Footer
代表幻灯片页脚的 HeaderFooter对象。
Header
代表幻灯片页眉的 HeaderFooter对象。仅对备注页和讲义有效，不用于幻灯片。
SlideNumber
代表幻灯片编号（在幻灯片中）或页码（在备注页或讲义中）的 HeaderFooter对象
注意  HeaderFooter对象对于代表备注页的 Slide对象无效。代表页眉的 HeaderFooter对象仅对备注母版或讲义母版有效。
可以为单张幻灯片设置 HeaderFooter对象的属性。以下示例设置当前演示文稿中第一张幻灯片的页脚文本。
ActivePresentation.Slides(1).HeadersFooters.Footer _
    .Text = "Volcano Coffee"
也可以将幻灯片母版、标题母版、备注母版或讲义母版的 HeaderFooter对象的属性设置为同时影响所有幻灯片、标题幻灯片、备注页或讲义及大纲。以下示例设置当前演示文稿幻灯片母版的页脚文本，设置日期和时间的格式，并打开幻灯片编号的显示。这些设置将应用于两类幻灯片：所有基于该母版并显示母版图形的幻灯片，没有页脚及日期和时间的幻灯片。
Set mySlidesHF = ActivePresentation.SlideMaster.HeadersFooters
With mySlidesHF
    .Footer.Visible = True
    .Footer.Text = "Regional Sales"
    .SlideNumber.Visible = True
    .DateAndTime.Visible = True
    .DateAndTime.UseFormat = True
    .DateAndTime.Format = ppDateTimeMdyy
End With
要清除为幻灯片单独设置的页眉和页脚信息，并保证所有幻灯片显示幻灯片母版中定义的页眉和页脚信息，请在运行前面的示例前运行以下代码：
For Each s In ActivePresentation.Slides
    s.DisplayMasterShapes = True
    s.HeadersFooters.Clear
Next
HeadersFooters对象
多个对象
HeadersFooters
  HeaderFooter
包含指定幻灯片、备注页、讲义或母版中的所有HeaderFooter对象。每个 HeaderFooter对象代表一个页眉、页脚、日期和时间或幻灯片编号。
注意  HeaderFooter对象对于代表备注页的Slide对象无效。代表页眉的 HeaderFooter对象仅对备注母版或讲义母版有效。
使用 HeaderFooters对象
使用HeadersFooters属性返回 HeadersFooters对象。使用DateAndTime、Footer、Header 或SlideNumber属性返回单个 HeaderFooter对象。以下示例设置当前演示文稿中第一张幻灯片的页脚文本。
ActivePresentation.Slides(1).HeadersFooters.Footer _
    .Text = "Volcano Coffee"
Hyperlink对象
多个对象
Hyperlink
代表与非占位符形状或文本相关联的超链接。可以使用超链接跳转到一个 Internet 或 Intranet 站点、另一个文件或当前演示文稿中的一张幻灯片上。Hyperlink对象是Hyperlinks集合的成员。Hyperlinks集合包含幻灯片或母版中的所有超链接。
使用 Hyperlink对象
使用Hyperlink属性返回形状的超链接。一个形状可以被赋予两种不同的超链接：一种在幻灯片放映中用户单击该形状时响应，另一种在幻灯片放映中用户将鼠标移过形状时响应。要使超链接在幻灯片放映中激活，必须将 Action属性设为 ppActionHyperlink。以下示例设置单击当前演示文稿第一张幻灯片的第三个形状时，连接到 Internet 上。
With ActivePresentation.Slides(1).Shapes(3) _
        .ActionSettings(ppMouseClick)
    .Action = ppActionHyperlink
    .Hyperlink.Address = "http://www.microsoft.com"
End With
一张幻灯片可以包含多个超链接。每个非占位符形状都可以有一个超链接；形状中的文本也可以有自己的超链接；而且每个单独的字符也可以有自己的超链接。使用 Hyperlinks(index) 可返回单个 Hyperlink对象，其中 index 表示超链接编号。以下示例可以将第三个形状的鼠标单击超链接添加到“收藏夹”文件夹。
ActivePresentation.Slides(1).Shapes(3) _
    .ActionSettings(ppMouseClick).Hyperlink.AddToFavorites
注意  在使用本方法向 Microsoft Internet Explorer 的“收藏夹”文件夹中添加超链接时，会向“收藏”菜单中添加一个图标，但并没有相应的名称。必须在 Internet Explorer 中为其添加名称。