[72期]哪些灯亮着？

泓()

39
=IF((ROW(A2)-1)^2>256,"",(ROW(A2)-1)^2)

31
=IF(ROW(A1)^2>256,"",ROW(A1)^2)

[ 本帖最后由 泓() 于 2011-3-28 21:04 编辑 ]

incognito

公式：

{=IF(POWER(ROW(A2:A30)-1,2)>256,"",POWER(ROW(A2:A30)-1,2))}
OR
{=IF((ROW(A2:A30)-1)>SQRT(256),"",SMALL(POWER(ROW(A2:A30)-1,2),ROW(INDIRECT("1:"&SQRT(256)))))}

[ 本帖最后由 incognito 于 2011-3-29 06:24 编辑 ]

羽希

多单元数组好像可以占点字符优势
长度102:
=TEXT(SMALL(IF(MOD(FREQUENCY(ROW(1:256)*COLUMN(1:1),ROW(1:255)),2),ROW(1:256),999),ROW()-1),"[=999] ")

长度87:
=TEXT(SMALL(IF(ROW(1:256)/COLUMN(1:1)=COLUMN(1:1),ROW(1:256),999),ROW()-1),"[=999] ")

[ 本帖最后由 羽希 于 2011-3-30 14:22 编辑 ]

fjrlgj

106个字符
=TEXT(SMALL(IF(MOD(FREQUENCY(ROW($1:$256)*COLUMN(2:2),COLUMN(2:2)),2),ROW($1:$257),257),ROW(B1)),"[<257]")

25个字符(完全平方数的约数的个数是奇数)
=TEXT(ROW(A1)^2,"[<257]")

[ 本帖最后由 fjrlgj 于 2011-4-13 14:34 编辑 ]

wangexcel009

{=IF(LEN(SQRT(ROW(B2:B30)-1))<3,"灯亮",)}

syz105729913

投机公式，=IF(ROW(A1)^2>256,"",ROW(A1)^2)

[ 本帖最后由 syz105729913 于 2011-4-12 18:04 编辑 ]

goalone1985

=TEXT(IF(ISEVEN(SUM(IF(MOD(ROW(1:1),ROW($1:1)),,1))),,1)*ROW(1:1),"0;;")

fugb-2010

①    第1至第256个人通过第1至第256盏灯,每盏灯每次发生动作以1为代表,公式为:
=N(MOD(COLUMN(1:1),ROW(1:256))=0)
    第1至第256盏灯发生动作累加次数公式为:
=MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),1^ROW(1:256))
    第1至第256盏灯累加次数为单数时以其位置行标表示,次数为双数时以10000+位置行标表示,公式为:
=MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),1^ROW(1:256))-1,2)/1%%+ROW(1:256)
    位置由小到大排列,公式为:
=TEXT(SMALL(MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),1^ROW(1:256))-1,2)/1%%+ROW(1:256),ROW(1:30)),"[<257]") 多单元数组公式（连等号109字元）
②    因上述公式存在-1+位置行标，同时第1个人均拨动256盏灯，把第257个人代替第1个人，则累加次数为双数时以其位置行标表示,次数为单数时以10000+位置行标表示，公式为:
=TEXT(SMALL(MOD(MMULT(N(MOD(ROW(2:257),COLUMN(1:1))=1),1^ROW(1:256)),2)/1%%+ROW(1:256),ROW(1:30)),"[<257]")多单元数组公式（连等号107字元）
③    最后规律简化公式为:
=TEXT(ROW(1:30)^2,"[<257]")多单元数组公式（连等号27字元）

[ 本帖最后由 fugb-2010 于 2011-4-12 11:08 编辑 ]

yvhgydn

先留个，多单元格数组公式，字数超了
113=TEXT(SMALL(IF(ISODD(MMULT(IF(MOD(ROW(1:256)/COLUMN(1:1),1),,1),M1:M256+1)),ROW(1:256),999),ROW(1:29)),"[<999];")
111=TEXT(SMALL(IF(ISODD(MMULT(N(MOD(ROW(1:256)/COLUMN(1:1),1)=0),M1:M256+1)),ROW(1:256),999),ROW(1:29)),"[<999];")
110=TEXT(SMALL(IF(ISODD(MMULT(N(LEN(ROW(1:256)%/COLUMN(1:1))<5),M1:M256+1)),ROW(1:256),999),ROW(1:29)),"[<999];")
108=TEXT(SMALL(IF(ISODD(MMULT(N(LEN(ROW(1:256)%/COLUMN(1:1))<5),M1:M256+1)),ROW(1:256),999),ROW()-1),"[<999];")
LEN(ROW(1:256)%/COLUMN(1:1))<5   用1至256中的每一个数去除以1至256中的每一个数，再除以100，形成一个矩阵，用LEN判断如果小于5则证明商为整数
ISODD(MMULT(N(。。。),M1:M256+1))  判断矩阵中的每一行的整数的个数是否为奇数，
IF（。。）如果为奇数，返回ROW(1:256),该行值的灯为亮的，再套以SMALL，用TEXT将不亮的显示为空

另：按照上面的思路，如果ROW(1:256)/COLUMN(1:1),所形成的矩阵的每一行的整数个数为偶数，则ROW(1:256)的行值表示的灯为熄，否则（为奇数），ROW(1:256)表示的行值的灯为亮
进一步，当被除数为整数，除以除数的商值为整数时，则除数也为整数，所以除数与商将以成对的整数出现，所以当被除数开方为整数时，该被除数的值的灯亮
即公式：=TEXT(SMALL(IF(MOD(ROW(1:256)^0.5,1),999,ROW(1:256)),ROW()-1),"[<999];")
再进一步，从1至N的数，他的平方值即能被点亮，同时最大值不超过256
即公式：=TEXT((ROW()-1)^2,"[<257];")
但不知此说法是否就是楼主所述：解答公式没有能体现解题思路

[ 本帖最后由 yvhgydn 于 2011-4-17 23:34 编辑 ]

hopeson2010

刚好108，不知是否能通过！
=TEXT(SMALL(100^(-1^MMULT(-(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0))*ROW(1:256)/1%,ROW(1:99)),"[<257]")