[72期]哪些灯亮着？

oyzhjr

此题较易，知道原理的就可以转化为判断一个数是否为完全平方数的问题，也等于判断一个数的约数是否为奇数个的问题。
谢谢楼主送分，给三种解法，分别长度为67(59),43,36
=IF(MOD(COUNT(1/(SIGN(MOD(ROW()-1,ROW($1:$256)))-1)),2),ROW()-1,"") 数组
此公式也可以简化写为：
=IF(MOD(COUNT(1/(MOD(ROW()-1,ROW($1:$256)))),2),ROW()-1,"")数组
转化为判断完全平方数的公式就更省事了
=IF(OR(ROW()=(ROW($1:$16)^2+1)),ROW()-1,"")数组
=IF(LEN(SQRT(ROW()-1))<3,ROW()-1,"")

====================================误解题意，还好LZ提醒，多谢=====================================
改了一下，不知道算不算：
=IF(ROW()-1<SQRT(257),(ROW()-1)^2,"")
=SUBSTITUTE(SMALL(IF(LEN(SQRT(ROW($1:$256)))<3,ROW($1:$256),300),ROW()-1),300,) 数组
附件不传了，开贴看高手的答案。

[ 本帖最后由 oyzhjr 于 2011-3-24 13:07 编辑 ]

fangjianp

占位。我的预设公式是：
=TEXT(1/SMALL(-1^MMULT(-(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0)/ROW(1:256),ROW()-1),";0")
（多单元格数组公式）

[ 本帖最后由 fangjianp 于 2011-3-24 10:40 编辑 ]

wangyuhu

本题的其实是一个证明题，证明一个约数个数定律：一个自然数的平方，它的约数个数一定是奇数个，否则为偶数个。（不知道教科书上有没有，好像我没学过，用公式列举法,VBA验证12万内满足;假设法也可证明）
-------------------
112字符，水平有限觉得挺难的，多区域数组，可能方向有点偏差，所以字符不太好减
=TEXT(SMALL(IF(MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:256))=0),ROW(1:256)^0),2),ROW(1:256),4^8),ROW()-1),"[>256] ")
============================
凑个数106字符
=TEXT(SMALL((-1^MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0)+1)/1%%+ROW(1:256),ROW()-1),"[>256] ")
============================

[ 本帖最后由 wangyuhu 于 2011-4-14 08:02 编辑 ]

羽希

做出来刚刚108 不过发现答案有规律 不知是不是理解有出入
=text(row(a1)^2,"[>256] ")

wangg913

参与一下。
=TEXT(SMALL(IF(-1^FREQUENCY(ROW(1:256)*COLUMN(1:1),ROW(1:256))+1,257,ROW(1:257)),ROW(1:29)),"[<257];")
多单元格数组公式。

=TEXT(SMALL((-1^FREQUENCY(ROW(1:256)*COLUMN(1:1),ROW(1:256))+2)^6*ROW(1:257),ROW(1:29)),"[<257];")

首先构造矩阵，ROW(1:256)*COLUMN(1:1)，用来模拟256人的通过情况
这个矩阵中，1~256 如果出现的是单数次数，那么灯就是亮者的，否则就是关闭的。

通过统计，发现1~256 一共出现了1466次，而大于256的一共出现64070次，
因此公式取巧，变成如下形式。
=TEXT(1/SMALL(-1^FREQUENCY(ROW(1:256)*COLUMN(1:1),ROW(1:256))/ROW(1:257),ROW(1:29)),";0")
还是多单元格数组公式。

yumoym

=TEXT(SMALL(ROW(1:256)^(-1^MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0)*4+5),ROW(1:29)),"[<257];")
多单元格数组公式。106字。
记得原先是30盏，怎么变成29盏了？
=TEXT(SMALL(ROW(1:257)^(-1^FREQUENCY(ROW(1:256)*COLUMN(1:1),ROW(1:256))*4+5),ROW(1:29)),"[<257];")
多单元数组。98字。
“;”也省去
=TEXT(SMALL(ROW(1:257)^(-1^FREQUENCY(ROW(1:256)*COLUMN(1:1),ROW(1:256))*4+5),ROW(1:29)),"[<257]")

[ 本帖最后由 yumoym 于 2011-4-13 14:43 编辑 ]

honggexjq

不知最后一句要体现思路是什么意思
=TEXT(ROW(A1)^2,"[<257]0;")
能体现吗？

Zamyi

函数表达数学题
B2=IF(ROW()>17,"",ROW(A1)^2)

[ 本帖最后由 Zamyi 于 2011-3-24 15:47 编辑 ]

zbwxlxy

多单元格数组公式
答案
=TEXT(SMALL(IF(MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0),2),ROW(1:256),999),ROW(1:29)),"[<999]0;;")

114字符，再也不会简化了

[ 本帖最后由 zbwxlxy 于 2011-4-16 08:21 编辑 ]

zhaojiaoyang200

多单元格数组公式：

1. =IF(MOD(MMULT(N(MOD(ROW(1:256),TRANSPOSE(ROW(1:256)))=0),ROW(1:256)^0),2),ROW(1:256),"")

复制代码