[72期]哪些灯亮着？

fangjianp

题目见附件说明。

题目不难，因此不提供模拟结果，需要自己测算。

截止 2011-4-17，之后解答不再评分。







注意：解答公式必须能体现解题思路

本题解说贴在59楼。第一次出题，难免考虑不周，欢迎大家随时指正！谢谢大家！！！

评分结果在64楼，若有错误，请及时指正！谢谢。

[ 本帖最后由 fangjianp 于 2011-4-18 12:24 编辑 ]

wenshui2006

好像有16盏灯亮吧,,
B2=TEXT(ROW(1:1)^2,"[<=256];")
下拉,
按照此规律,有N盏灯,N个人走过,则最后亮着的灯编号应该为:
=TEXT(ROW(1:N)^2,"[<=N];")


b2:b30多单元格数组公式:=TEXT(SMALL(IF(MOD(MMULT(--(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0),2),ROW(1:256),257),ROW(1:29)),"[<=256];")

[ 本帖最后由 wenshui2006 于 2011-4-17 01:19 编辑 ]

天使之泪.

刚好108,功力不够呀,办法都想尽了,东拼西凑的.

[ 本帖最后由 天使之泪. 于 2011-4-11 12:22 编辑 ]

chenhh803

占位高层，
118字符
=TEXT(SMALL(IF(MOD(MMULT(--(MOD(ROW($1:$256),COLUMN(1:1))=0),ROW($1:$256)^0),2),ROW($1:$256),257),ROW(A1)),"[<257]#;")
再精简114字符
=TEXT(SMALL(IF(MOD(MMULT(--(MOD(ROW($1:$300),COLUMN(1:1))=0),ROW($1:$256)^0),2),ROW($1:$300)),ROW(A1)),"[<257]#;")
再精简108字符
=TEXT(SMALL(MOD(MMULT(N(MOD(ROW($1:$300),COLUMN(1:1))=0),ROW(1:256)^0),2)*ROW($1:$300),ROW(A242)),"[<257];")
再来一个其它思路的:108字符;
=TEXT(SMALL(IF(MOD(FREQUENCY(ROW($1:$256)*COLUMN(1:1),ROW($1:$300)),2),ROW($1:$301),257),ROW(A1)),"[<257];")
再精简102字符
=TEXT(SMALL(MOD(FREQUENCY(ROW($1:$256)*COLUMN(1:1),ROW($1:$998)),2)*ROW($1:$999),ROW(A968)),"[<257];")
以上公式只适合于03版,如在07版或以上运行需更改COLUMN(1:1),呵呵!

[ 本帖最后由 chenhh803 于 2011-3-27 19:11 编辑 ]

chunlin1wang

=TEXT(SMALL(IF(MOD(FREQUENCY(ROW($1:$26)*COLUMN(A:Z),ROW($1:$256)),2),ROW($1:$256),257),ROW(A1)),"[>256] ")
107字符刚好达标（汗）
=TEXT(ROW(A1)^2,"[>256] ")

Zaezhong

1. =TEXT(SMALL(IF(MMULT(-(ROW($1:$256)^0.5=COLUMN(1:1)),ROW(1:256)^0),ROW($1:$256),999),ROW(A1)),"[>256]G")

复制代码

长度104

1. =TEXT(SMALL(IF(ROW($1:$29)^2<=256,ROW($1:$29)^2,999),ROW(A1)),"[>256]G")

复制代码

长度72
按奇数次灯开，偶数次灯不亮，同时根据题目可以知道灯号能被人的编号整除时才会按到开关，这样就转化为求1~256之间的各整数可以被多少个数整除，由于一个合数分解的时候是前后对应的，这样要求有奇数个数可以整除，就表明要求该数是一个完全平方数，根据这点写了以上2个公式，公式1通过开方数获取符合的灯号，公式2反一下，通过平方数。下图以256（最后灯亮），200（最后灯不亮）


[ 本帖最后由 Zaezhong 于 2011-3-29 18:26 编辑 ]

草民1982111

公式长度：109
=TEXT(SMALL(IF(MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0),2),ROW(1:256),4^8),ROW()-1),"[<257]")多单元数组公式。
公式长度：107
=TEXT(SMALL(999*MOD(315,MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0))+ROW(1:256),ROW()-1),"[<257]")多单元数组公式。
公式长度：28
=TEXT(ROW(1:256)^2,"[<257]")多单元数组公式。

[ 本帖最后由 草民1982111 于 2011-3-26 10:21 编辑 ]

lhx120824

正如你说的，问题确实不难，分析你提出的问题，实际上就是正整数分解因数的问题，比如4号灯，由1、2、4号人来按，12号灯，由1、2、3、4、6、12号号人来按。12包含的因数就是1、12、2、6、3、4这6个数，即12=1*12=2*6=3*4，而4=1*4=2*2……一个整数的因数是成对出现的。在你提出的这个问题中，12号灯的情况是1开2关3开4关6开12关，偶数个人的操作结果是关。只有象4号灯是1开2关4开，奇数个人操作是开。这样只有平方数才有成对相等的因数（4=2*2）。因此你的问题的解答公式是：
B2:B30
=IF(ROW(1:29)>256^0.5,"",ROW(1:29)^2)
多单元格数组公式。

下拉公式是：
B2
=IF(ROW()-1>256^0.5,"",(ROW()-1)^2)

一般的解法稍后再发。

再发一个没有容错得多单元格数组公式，供交流分享用：
=SMALL(IF(MOD(MMULT(IF(MOD(ROW(1:256),TRANSPOSE(ROW(1:256))),0,1),ROW(1:256)^0),2),ROW(1:256)),ROW(1:29))

加上容错：
=IF(ROW()-1>256^0.5,"",SMALL(IF(MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0),2),ROW(1:256)),ROW(1:29)))
(字符数已超，需换思路再考虑）


112字符的：
=TEXT(SMALL(IF(MOD(MMULT(N(MOD(ROW(1:256),COLUMN(1:1))=0),ROW(1:256)^0),2),ROW(1:256),300),ROW(1:29)),"[=300] ")

[ 本帖最后由 lhx120824 于 2011-4-1 15:48 编辑 ]

半半瓶醋

=TEXT(SMALL(IF(MOD(ROW($1:$256)^0.5,1),9^9,ROW($1:$256)),ROW()-1),"[<=256];")
数组
奇人数通过灯肯定是亮的，偶人数通过灯就是灭的。
那么一个数的约数个数就决定了灯得亮灭。
一般约数都是成双出现的,如6的约数1和6,2和3。只有平方数的约数是奇数个,如9的约数是1和9,3和3(重复)
所以题目结果实际就是找平方数。

楼主要求把思路写进公式，还真不知道怎么写。
至于公式满不满足题目要求无所谓，我只是参与下 。

[ 本帖最后由 半半瓶醋 于 2011-3-28 17:07 编辑 ]

angellbxsc

您好！
又来打扰您了。今天突然想到一个方法，重新做了调整。
思路仍然是原思路，但此次用的是乘法关系，并利用到了Frequency函数。逻辑上应该没有问题。
一种解法：
=TEXT(SMALL(-ROW(1:257)*MOD(FREQUENCY(ROW(1:16)*COLUMN(A:P),ROW(1:256)),2),ROW(A:A)),";0")
另一种解法：
=TEXT(SMALL((MOD(MMULT(N(MOD(ROW(1:256),COLUMN(A:IV))=0),ROW(1:256)^0),2)=1)*-ROW(1:256),ROW(1:256)),";0")

[ 本帖最后由 angellbxsc 于 2011-4-13 18:53 编辑 ]