题目测试，欢迎参加，答对有奖

wcymiss

已经发送，请查收，好题目，谢谢版主分享。

第一题
=NETWORKDAYS(A4&"-"&B4,DATE(A4,B4+1,))
=SUM(N(MOD(ROW(INDIRECT((A4&"-"&B4)*1&":"&DATE(A4,B4+1,))),7)>1))
第二题
=OFFSET(A$2,ROW(A4)/4,)
第三题
=IF(A3="",C2,A3)
第四题
=TEXT(MOD(A3,7),"[>1]aaaa;周末")
第五题
=IF(RIGHT(A3)="章",MATCH("*章",IF(ROW(5:$26)<26,A5:A$25,"章"),),"")
第六题
=INDEX(A:A,RIGHT(SMALL(IF(COLUMN(A:J)<=B$3:B$12+1,ROW($3:$12)*101+(COLUMN(A:J)>1)*13,9999),ROW(A1)),2))&""
第七题
=ABS(SUM(RIGHT(LARGE(MMULT(LARGE(((A3:A20=A4:A21)*(A4:A21<>A5:A22)+(A3:A20<>A4:A21)*(A4:A21=A5:A22))*ROW(1:18), {1;3;5;7;9}+{0,1} ),{101;-100}),{1,2}),2)*{1,-1}))+1

没有使用FREQUENCY函数判断连续，通过判定当前单元格是否与上下相连的两个单元格相同来判定连续，最后的 MMULT(,{101;-100})更是神来之笔，简化一下

=ABS(SUM(RIGHT(LARGE(MMULT(LARGE(((A3:A20=A4:A21)+(A4:A21=A5:A22)=1)*ROW(1:18),ROW(1:9)*2-{1,0}),{101;-100}),{1,2}),2)*{1,-1}))+1

<wangg913>

[ 本帖最后由 wangg913 于 2011-3-6 10:56 编辑 ]

chenqh06

先做了前5个题目，邮件已发送。
我的邮箱是：chenqh06@163.com


--------------------------------------------------------------
由于上次的第4题公式长度多了1个字符。修订后重新发的邮件，请楼主查收。
非常感谢楼主的的题目！

题目答案都正确，wangg913

[ 本帖最后由 wangg913 于 2011-3-4 13:12 编辑 ]

hopeson2010

留个位置，看有没有时间参与！谢谢！大头版主！

未收到 坤哥 答案，wangg913

山桑弓

原帖由 wangg913 于 2011-2-21 18:00 发表
为活跃论坛，测试一下大家对函数与公式的灵活运用能力，现出几个小题目，希望大家热情参与。

附件内容对每一道题目有明确的要求，如果题目不限定公式长度则无论长短都算正确完成。



按题目要求

1、同时完 ...

邮件已发送，只做出前面六题，第七题目实在不会了。

前五题，做的都很精彩。
第六题，题目要求只能引用 A、B列，你的公式引用了 C列上面的单元格，因此不能算正确。
仅就实现的效果是没有问题，比如 A列 数据稍有重复就出问题了。
=IF(COUNTIF(C$15:C15,OFFSET(A$1,MIN(IF(ROWS(C$15:C15)<=(SUBTOTAL(9,OFFSET(B$3,,,ROW(B$3:$B$12)-2,))+ROW(A$3:A$12)-2),ROW(A$3:$A$12)-1)),))=0,OFFSET(A$1,MIN(IF(ROWS(C$15:C15)<=(SUBTOTAL(9,OFFSET(B$3,,,ROW(B$3:$B$12)-2,))+ROW(A$3:A$12)-2),ROW(A$3:$A$12)-1)),)&"","")

wangg913

[ 本帖最后由 wangg913 于 2011-3-4 13:22 编辑 ]

zzmxy

哟，都说后面两题很难，那先把前面的交了吧……
邮址：zzmxy@126.com

--------------------------------------------------------
增加第六、七题的公式，邮件已再发送，
主题为：题目测试更新-zzmxy
请版主查阅……谢谢！！

==========================================================================================

=NETWORKDAYS(DATE(A4,B4,1),DATE(A4,B4+1,0))
=COUNT(FIND(WEEKDAY(DATE(A4,B4,ROW(INDIRECT("1:"&DAY(DATE(A4,B4+1,0))))),2),{1,2,3,4,5}))

=INDEX(A$3:A$7,ROW(A4)/4)

=LOOKUP(1,0/(A$3:A3<>""),B$3:B3)

=IF(MOD(A3,7)<2,"周末",TEXT(A3,"AAAA"))

=IF(A3>"第吖",COUNTIF(OFFSET(A3,,,IFERROR(MATCH("*章",A4:A$25,),9)),"*页"),"")

=INDEX(A:A,RIGHT(SMALL(IF(B$3:B$12+1<COLUMN(A:I),4^6,ROW($3:$12)*101+(COLUMN(A:I)>1)*20),ROW(A1)),2))&""

最后一题，定义了两个名称，我没有测试通过，请楼主将不使用名称的公式整理上传。



<wangg913>
==========================================================================================

[ 本帖最后由 wangg913 于 2011-3-4 01:12 编辑 ]

安然祥和

回复 1楼 wangg913 的帖子
本人水平有限，想了好久，才弄好前五题。尚需更加努力。我的邮箱是：DEHSZ@126.COM
已发送，盼查收

第一题，两个答案都不对
=SUM(N(WEEKDAY(DATE(A4,B4,ROW($1:$31)),2)<6))
从1号到31号，没有31天的时候就成了下个月的日期了，因此思路不对。
=28/7*5+PRODUCT(--(TEXT(DATE(A4,B4,29),"AAA")<>{"六","日"}))+PRODUCT(--(TEXT(DATE(A4,B4,30),"AAA")<>{"六","日"}))+PRODUCT(--(TEXT(DATE(A4,B4,31),"AAA")<>{"六","日"}))

第四题，使用了自定义单元格格式
第五题，做的很好

wangg913

[ 本帖最后由 wangg913 于 2011-3-4 13:29 编辑 ]

caidf999

水平有限，想了好久，才弄好一题，留个位置。

未收到答案，wangg913

jayzoudequan

谢谢，先占一个位置

未收到答案，wangg913

goodkf

只做好了前5题，后两题还没有头绪。
邮件已发送

第一、二、三、四题，都做的很好。
第五题，
=IF(COUNTIF(A3,"*"&"章"),MATCH(1,(A4:A99="")+ISNUMBER(FIND("章",A4:A99)),0)-1,"")
可简化一下
=IF(COUNTIF(A3,"*章"),MATCH(1,(A4:A99="")+(RIGHT(A4:A99)="章"),)-1,"")
=IF(COUNTIF(A3,"*章"),MATCH(TRUE,RIGHT("章"&A4:A99)="章",)-1,"")

wangg913

[ 本帖最后由 wangg913 于 2011-3-4 13:37 编辑 ]

wingpan

我也进来学习一下，感觉还真不容易呢。

第五题，结果为数字的应该是数值型数字
因题目没有明确限定，也算正确。
不过这种计算方法不算好。

wangg913

wingpan(889436).rar (10.07 KB, 下载次数: 6)

2011-3-7 10:26 上传

点击文件名下载附件

[ 本帖最后由 wangg913 于 2011-3-7 10:27 编辑 ]