题目测试，欢迎参加，答对有奖

人海看客

看看自己处于什么水平

草民1982111

占位。附件已发送至邮箱。（已更新）

第五题

思路不错，只是使用顺序不当，最终返回的要求是 数值型数字       
可改为：
=IF(COUNTIF(A3,"*章"),MATCH(,1-ISERR((FIND("页",A4:A$27))),)-1,"")

第六题：

题目思路清晰，取巧取到家了，有效性设定最大是7，因此使用了 IF({1,1,1,1,1,1,1,0},
通过构造一个矩形数组，将 第7列 设定为所对应的行号
小于 B3:B12 的区域 让它等于 行号100的位置
从而实现了空单元格的形式

虽然 c61:c67 出现了错误，但公式的思路是正确的

可改为
=INDEX(A:A,--RIGHT(SMALL(IF(COLUMN(A:G)<7,IF(B$3:B$12>=COLUMN(A:G),ROW($3:$12)*1011,4^8),ROW($3:$12)*1001),ROW(A1)),3))&""

第七题：
离最佳答案很近了，却绕了个弯，FREQUENCY的基本用法已经了解了，只需将连续生成的数组和行号有效的联结起来，取最大、二大值，再取出相应的行号就可以了。

wangg913

草民.rar (13.98 KB, 下载次数: 10)

2011-3-3 16:03 上传

点击文件名下载附件

敬佩大头版主高超的解题技巧,更敬佩版主的敬业精神!谢谢你精彩的点评！

[ 本帖最后由 草民1982111 于 2011-3-3 16:52 编辑 ]

榴莲的味道

冥思苦想只想出了前5题，已经发送到版主所说的邮箱，请查收

第四题
这题没做出来，不知道 TEXT(,"AAAA") 的用法，可惜。

第五题
=IF(RIGHT(A3,1)="章",COUNTBLANK(C4:$C$25)-SUM(C4:$C$25),"")
题目做得好，完全使用 C列的数据互为引用

wangg913

榴莲的味道.rar (9.34 KB, 下载次数: 8)

2011-3-3 16:06 上传

点击文件名下载附件

[ 本帖最后由 wangg913 于 2011-3-3 16:06 编辑 ]

2011曾曾

新注册用户，先测试下自己。占位先

没有收到答案，wangg913

版主：只第三题做的出，IF(LEN(A3)>0,A3,OFFSET(A3,-1,1)) 。其他都做不好。

[ 本帖最后由 2011曾曾 于 2011-4-8 15:58 编辑 ]

oyzhjr

做出了 前5道，第6题有思路，先占位，传了， 以后再改。

第一题
第二答案
=SUM(--(MOD(DATE(A4,B4,1)-1+ROW(INDIRECT("1:" & DAY(DATE(A4,B4+1,0)))),7)>1))
可适当进行优化
=SUM(--(MOD(DATE(A4,B4,)+ROW(INDIRECT("1:"&DAY(DATE(A4,B4+1,)))),7)>1))

wangg913

张.rar (12.07 KB, 下载次数: 9)

2011-3-3 16:09 上传

点击文件名下载附件

[ 本帖最后由 wangg913 于 2011-3-3 16:09 编辑 ]

gufengaoyue

只做了1-5
6的没弄出现，就用VBA写了一个，哈
已发到版主信箱了，请查收！

================================

我的答案：

1. 做错了。12月份没想好。
2. =OFFSET($A$3,(ROW(A1)-1)/4,)
3.=IF(A3="",C2,A3)
4.=IF(MOD(A3,7)<2,"周末",TEXT(A3,"aaaa"))
5.=IF(RIGHT(A3)="页","",MATCH("章*",RIGHT(A4:A$26)&"章",)-1)

'================================

第一题
=NETWORKDAYS(A4&"-"&B4,(A4&"-"&(B4+1))-1)
上面的公式不对，遇到12月份就出问题了。
第二个公式使用的 2010版公式，我没有验证

第五题
=IF(RIGHT(A3)="页","",MATCH("章*",RIGHT(A4:A$26)&"章",)-1)
思路很好，通过尾字符来做文章

第六题使用了VBA，这个我看不懂。
wangg913

谢谢版主指点! 辛苦了！

[ 本帖最后由 gufengaoyue 于 2011-3-4 00:17 编辑 ]

chenzyyysl

先占位占位占位
已上传，期待点评

第五题
=IF(RIGHT(A3)="章",MATCH(TRUE,RIGHT(A4:A$26)<>"页",)-1,"")
思路很好，找到那个 尾字符 不是“章”的位置 （版主写错了，后面第一个尾字符 不是“页”的位置）

第六题
=IF(ISNUMBER(MATCH((ROW()-15),SUBTOTAL(9,OFFSET(B$2,,,ROW($1:$10)))+ROW($1:$10),0)),INDIRECT("a"&2+MATCH((ROW()-15),SUBTOTAL(9,OFFSET(B$2,,,ROW($1:$10)))+ROW($1:$10),0)),"")
思路清晰，就是判断的时候加长了公式。

第七题
使用名称后，思路清晰，用法基本和 piny 2楼的相同，只是好像受限于函数嵌套，以至于使用了名称

wangg913

自评：
第一题：66字公式1｛=SUM(--(MOD(ROW(INDIRECT(DATE(A4,B4,1)&":"&DATE(A4,B4+1,))),7)>1))｝        
        42字公式2  =NETWORKDAYS(DATE(A4,B4,1),DATE(A4,B4+1,))
达到要求，但以前不会日期的下面公式表达方式，下面是本次学习收获的结果：
         33字公式2  =NETWORKDAYS(A4&-B4,(A4&-B4-1)-1)
第二题：  =INDEX($A$1:$A$7,(ROW()+1)/4)
第三题： =IF(A3="",B2,A3)
第四题：=IF(MOD(A3,7)>1,TEXT(A3,"aaaa"),"周末")
             本次学习收获，2个等价30字
               =TEXT(MOD(A3,7),"[>1]aaaa;周末")
               =TEXT(MOD(A3,7),"[<2]周末;aaaa")
第六题 还要想想老师所讲的如何改
第七题 学习110楼 fjrlgj 的处理方式
=ABS(SUM(RIGHT(LARGE(FREQUENCY(ROW(3:21),(A4:A22<>A3:A21)*ROW(3:21))*100+ROW(3:22),{1,2}),2)*{1,-1}))+1
=IF(LARGE(FREQUENCY(ROW(3:21),(A4:A22<>A3:A21)*ROW(3:21)),2)>1,ABS(SUM(RIGHT(LARGE(FREQUENCY(ROW(3:21),(A4:A22<>A3:A21)*ROW(3:21))*100+ROW(3:22),{1,2}),2)*{1,-1}))+1,"无两连续组")
本人原公式在参数上和110楼的类似有点小错，版主没发现，呵呵。

第一题，说过了这个公式不对，遇到12月份不能判定是日期了
33字公式2  =NETWORKDAYS(A4&-B4,(A4&-B4-1)-1)

第六题
使用 MATCH函数 精确查找目标值，如果找不到，就会出错
因此，可以构造一个数组，让它一定能找到就可以了。
SUBTOTAL(9,OFFSET(B$2,,,ROW($1:$11)))+ROW($1:$11) 是一个11*1的数组，可能没有你所查找的 ROW()-15
为了让它一定有，可将这个数组扩充为12*1的数组，第12个元素让它等于ROW()-15不就行了？

MATCH(ROW()-15,IF(ROW($1:12)<12,SUBTOTAL(9,OFFSET(B$2,,,ROW($1:$11)))+ROW($1:$11),ROW()-15),)

另外，不用 match函数查找，使用其他方法，30楼和38楼有很好的公式，可去看看。
wangg913

[ 本帖最后由 wangg913 于 2011-3-7 12:04 编辑 ]

zm0115

已发，惭愧最后一题感觉好繁琐
终于全部做完了，就是不知是否符合要求。

第一题，第二解思路不对，如果是12月份，工作日的月份数组将不是升序序列，使用模糊查找将得不到想要的值，
但我验证了100年也没发现错误，这个以后单独讨论一下。

=LOOKUP(B4,MONTH(WORKDAY(DATE(A4,B4,0),ROW($1:$30))),ROW($1:$30))
改为这样合理
=MATCH(1,0/(B4=MONTH(WORKDAY(DATE(A4,B4,0),ROW($1:$30)))))


第六题
=IFERROR(INDEX($A$3:$A$12,MATCH(ROW()-15,ROW($1:$10)+SUBTOTAL(9,OFFSET($B$2,0,,ROW($1:$10))),)),"")
使用了 2007版的 IFERROR函数判断，公式简洁漂亮

第七题
=ABS(SUM(MMULT((FREQUENCY(IF((A$2:A$20=A$3:A$21)+(A$3:A$21=A$4:A$22),ROW(A$3:A$21)),IF((A$2:A$20=A$3:A$21)+(A$3:A$21=A$4:A$22),,ROW(A$3:A$21)))=LARGE(FREQUENCY(IF((A$2:A$20=A$3:A$21)+(A$3:A$21=A$4:A$22),ROW(A$3:A$21)),IF((A$2:A$20=A$3:A$21)+(A$3:A$21=A$4:A$22),,ROW(A$3:A$21))),{1,2}))*1,{1;-1})*ROW(A3:A22)))+1

FREQUENCY的用法比较熟练了，只是没有想到将连续的数量与行号直接结合起来。

wangg913

经验证楼主的第一题第二解是正确的。wangg913

验证的附件见

zm0115的第一题第二解验证.rar (290.97 KB, 下载次数: 18)

2011-3-5 13:13 上传

点击文件名下载附件

[ 本帖最后由 wangg913 于 2011-3-5 13:14 编辑 ]

一指禅

占位参加测试

老朋友了，没收到邮件，wangg913

您好！近来太忙，不好意思！您出的好多题都没有好的思路！所以没法邮件，本次只能站脚助威，以后有机会再参加！请您见谅！

[ 本帖最后由 一指禅 于 2011-3-4 18:28 编辑 ]

ctp_119

先做个记号，回去好好研究，研究好了就上传，不知道自己能力怎么样，先试试吧！呵呵

我没有收到答案，wangg913