求助自动生成逐天调休方式

baoxuehero

edwin11891 发表于 2025-2-23 18:07
如果是WPS新版，还可以：
a,trimrange(A2:B1000),b,trimrange(C2:D1000)

感谢，试了一下，可以

edwin11891

baoxuehero 发表于 2025-2-23 18:04
大神，如果增加一列姓名列，一列假别，请问代码该如何完善，附件已更新

在5楼老师的方法基础上修改完成，简练了一下，还是火车：

1. =LET(fxyz,LAMBDA(x,y,z,LET(a,x,b,y,sName,z,fx,LAMBDA(x,BYROW(x,CONCAT)),fy,LAMBDA(x,y,SEQUENCE(x-y+1,,y)),fz,LAMBDA(x,y,HSTACK(x,IF(x,y))),t,fy(INDEX(b,1),INDEX(a,1)),c,SORT(VSTACK(fz(t,"上午"),fz(t,"下午"))),d,fx(c),e,CHOOSEROWS(c,fy(MATCH(CONCAT(INDEX(b,1,)),d,),MATCH(CONCAT(INDEX(a,1,)),d,))),f,GROUPBY(TAKE(e,,1),TAKE(e,,-1),ARRAYTOTEXT,0,0),g,IFNA(HSTACK(sName,TAKE(f,,1),SUBSTITUTE(TAKE(f,,-1),"上午, 下午","全天")),sName),g)),DROP(REDUCE("",A2:A5,LAMBDA(x,y,VSTACK(x,fxyz(OFFSET(y,,2,,2),OFFSET(y,,4,,2),OFFSET(y,,,,2))))),1))

复制代码

baoxuehero

edwin11891 发表于 2025-2-24 09:51
在5楼老师的方法基础上修改完成，简练了一下，还是火车：

能实现目标就好，还要啥自行车，感谢大神的无私解答

溺水鱼

baoxuehero 发表于 2025-2-23 18:04
大神，如果增加一列姓名列，一列假别，请问代码该如何完善，附件已更新

下班回家没电脑，也没怎么上论坛看，上班也就有空来论坛学习的，这个下面大佬回复的就可以了，我要改的话只会后面再加函数让我从头开始改的话有点头大哈，范围选择可以用TRIMRANGE()函数多框选点。

1. =LET(a,C2:D5,b,E2:F5,j,A2:B5,fx,LAMBDA(x,BYROW(x,CONCAT)),fy,LAMBDA(x,y,SEQUENCE(x-y+1,,y)),fz,LAMBDA(x,y,HSTACK(x,IF(x,y))),t,fy(MAX(TAKE(b,,1)),MIN(TAKE(a,,1))),c,SORT(VSTACK(fz(t,"上午"),fz(t,"下午"))),d,fx(c),e,DROP(REDUCE("",SEQUENCE(ROWS(a)),LAMBDA(m,n,VSTACK(m,CHOOSEROWS(c,fy(MATCH(CONCAT(INDEX(b,n,)),d,),MATCH(CONCAT(INDEX(a,n,)),d,)))))),1),w,DROP(REDUCE("",UNIQUE(TAKE(e,,1)),LAMBDA(s,k,VSTACK(s,IF(ROWS(FILTER(e,TAKE(e,,1)=k))>1,HSTACK(k,"全天"),FILTER(e,TAKE(e,,1)=k))))),1),gy,LAMBDA(y,MAP(TAKE(w,,1),LAMBDA(x,FILTER(y,(x>=TAKE(a,,1))*(x<=TAKE(b,,1)))))),HSTACK(gy(TAKE(j,,1)),gy(TAKE(j,,-1)),w))

复制代码

baoxuehero

溺水鱼 发表于 2025-2-24 13:44
下班回家没电脑，也没怎么上论坛看，上班也就有空来论坛学习的，这个下面大佬回复的就可以了，我要改的话 ...

再次感谢，应该一次性把需求提完的，好在有你们的耐心解答，问题完美解决

baoxuehero

edwin11891 发表于 2025-2-24 09:51
在5楼老师的方法基础上修改完成，简练了一下，还是火车：

大神，不好意思，实际工作中发现还要增加一列备注，有空的时候，麻烦再看看代码如何完善，不胜感激！

edwin11891

baoxuehero 发表于 2025-2-26 17:18
大神，不好意思，实际工作中发现还要增加一列备注，有空的时候，麻烦再看看代码如何完善，不胜感激！

直接加一列就好了：

1. =LET(fxyz,LAMBDA(x,y,z,xx,LET(a,x,b,y,sName,z,Mem,xx,fx,LAMBDA(x,BYROW(x,CONCAT)),fy,LAMBDA(x,y,SEQUENCE(x-y+1,,y)),fz,LAMBDA(x,y,HSTACK(x,IF(x,y))),t,fy(INDEX(b,1),INDEX(a,1)),c,SORT(VSTACK(fz(t,"上午"),fz(t,"下午"))),d,fx(c),fm,LAMBDA(x,MATCH(CONCAT(INDEX(x,1,)),d,)),e,CHOOSEROWS(c,fy(fm(b),fm(a))),f,GROUPBY(TAKE(e,,1),TAKE(e,,-1),ARRAYTOTEXT,0,0),g,CHOOSE({1,2,3,4,5},TAKE(sName,,1),TAKE(sName,,-1),TAKE(f,,1),SUBSTITUTE(TAKE(f,,-1),"上午, 下午","全天"),Mem),g)),REDUCE(I1:M1,A2:A5,LAMBDA(x,y,VSTACK(x,fxyz(OFFSET(y,,2,,2),OFFSET(y,,4,,2),OFFSET(y,,,,2),OFFSET(y,,6)&"")))))

复制代码

baoxuehero

edwin11891 发表于 2025-2-26 19:24
直接加一列就好了：

感谢大神，请收下我的膝盖

baoxuehero

溺水鱼 发表于 2025-2-23 13:40
前面理解错误，想了半天= =只能搞个笨办法

大神，您好，最开始提的需求，您写的这个公式可以完美运行，后面增加了需求，麻烦看看能不能再修改一下，新的需求请看图片和附件，另一个大神其实也实现了，但是使用了OFFSET函数，有个问题，在工作表中使用Private Sub Worksheet_Calculate()监控表格变化，别的工作表单元格数据变化，也会触发该工作表重新计算，数据量大的时候，会很卡，再次感谢！

1. =LET(a,TRIMRANGE(A2:B1000),b,TRIMRANGE(C2:D1000),fx,LAMBDA(x,BYROW(x,CONCAT)),fy,LAMBDA(x,y,SEQUENCE(x-y+1,,y)),fz,LAMBDA(x,y,HSTACK(x,IF(x,y))),t,fy(MAX(TAKE(b,,1)),MIN(TAKE(a,,1))),c,SORT(VSTACK(fz(t,"上午"),fz(t,"下午"))),d,fx(c),e,DROP(REDUCE("",SEQUENCE(ROWS(a)),LAMBDA(m,n,VSTACK(m,CHOOSEROWS(c,fy(MATCH(CONCAT(INDEX(b,n,)),d,),MATCH(CONCAT(INDEX(a,n,)),d,)))))),1),DROP(REDUCE("",UNIQUE(TAKE(e,,1)),LAMBDA(s,k,VSTACK(s,IF(ROWS(FILTER(e,TAKE(e,,1)=k))>1,HSTACK(k,"全天"),FILTER(e,TAKE(e,,1)=k))))),1))

复制代码