求助自动生成逐天调休方式

baoxuehero

A至F列是录入的姓名、假别和调休时段，希望在H至K列，通过公式，自动生成A至F列对应的姓名、假别、调休日期和调休方式，逐天列出，文件H至K列是手动写的要实现的目标，请问有没有办法通过公式自动生成姓名、假别、调休日期和调休方式？
PS：后续还会增加录入，不同的人有可能同一天调休。

溺水鱼

F、G列手动写的逻辑是什么？24跟26号都是下午 凭什么24是全天 26就是下午？？？23跟28都是上午 凭什么23是全天 28又是上午？？？公式也得有逻辑才能写，完全没有逻辑的这怎么写？

baoxuehero

溺水鱼 发表于 2025-2-23 11:19
F、G列手动写的逻辑是什么？24跟26号都是下午 凭什么24是全天 26就是下午？？？23跟28都是上午 凭什么23是 ...

24号那个是从2月23日上午调休到2月24日下午，等于23日、24日全天调休；
26号那个是从2月26日下午调休到2月28日上午，等于26日下午、27日全天、28日上午调休。

溺水鱼

baoxuehero 发表于 2025-2-23 11:32
24号那个是从2月23日上午调休到2月24日下午，等于23日、24日全天调休；
26号那个是从2月26日下午调休到2 ...

26号那个是从2月26日下午调休到2月28日上午，等于26日下午、27日全天、28日上午调休。
按照这个逻辑，22号怎么不算了？

溺水鱼

1. =LET(a,A2:B5,b,C2:D5,fx,LAMBDA(x,BYROW(x,CONCAT)),fy,LAMBDA(x,y,SEQUENCE(x-y+1,,y)),fz,LAMBDA(x,y,HSTACK(x,IF(x,y))),t,fy(MAX(TAKE(b,,1)),MIN(TAKE(a,,1))),c,SORT(VSTACK(fz(t,"上午"),fz(t,"下午"))),d,fx(c),e,DROP(REDUCE("",SEQUENCE(ROWS(a)),LAMBDA(m,n,VSTACK(m,CHOOSEROWS(c,fy(MATCH(CONCAT(INDEX(b,n,)),d,),MATCH(CONCAT(INDEX(a,n,)),d,)))))),1),DROP(REDUCE("",UNIQUE(TAKE(e,,1)),LAMBDA(s,k,VSTACK(s,IF(ROWS(FILTER(e,TAKE(e,,1)=k))>1,HSTACK(k,"全天"),FILTER(e,TAKE(e,,1)=k))))),1))

复制代码

前面理解错误，想了半天= =只能搞个笨办法

baoxuehero

baoxuehero 发表于 2025-2-23 11:32
24号那个是从2月23日上午调休到2月24日下午，等于23日、24日全天调休；
26号那个是从2月26日下午调休到2 ...

举例的，22号不一定要调休

baoxuehero

溺水鱼 发表于 2025-2-23 13:40
前面理解错误，想了半天= =只能搞个笨办法

感谢大神的耐心回复，公式能实现预定效果，不过后面还要继续录入，需要动态调整，请问公式要如何修改，我试了一下，“LET(a,A2:B5,b,C2:D5”定义的必须是已有数据的区域，后面新增数据得手动修改列数字。

baoxuehero

溺水鱼 发表于 2025-2-23 13:40
前面理解错误，想了半天= =只能搞个笨办法

1. =LET(end_row,MATCH(2,1/(A:A<>"")),a,A2:INDEX(B:B,end_row),b,C2:INDEX(D:D,end_row),fx,LAMBDA(x,BYROW(x,CONCAT)),fy,LAMBDA(x,y,SEQUENCE(x-y+1,,y)),fz,LAMBDA(x,y,HSTACK(x,IF(x,y))),t,fy(MAX(TAKE(b,,1)),MIN(TAKE(a,,1))),c,SORT(VSTACK(fz(t,"上午"),fz(t,"下午"))),d,fx(c),e,DROP(REDUCE("",SEQUENCE(ROWS(a)),LAMBDA(m,n,VSTACK(m,CHOOSEROWS(c,fy(MATCH(CONCAT(INDEX(b,n,)),d,),MATCH(CONCAT(INDEX(a,n,)),d,)))))),1),DROP(REDUCE("",UNIQUE(TAKE(e,,1)),LAMBDA(s,k,VSTACK(s,IF(ROWS(FILTER(e,TAKE(e,,1)=k))>1,HSTACK(k,"全天"),FILTER(e,TAKE(e,,1)=k))))),1))

复制代码

修改了一下，可以动态调整了，再次感谢大神的指导！希望还有其他大神提供简练一点的公式

baoxuehero

溺水鱼 发表于 2025-2-23 13:40
前面理解错误，想了半天= =只能搞个笨办法

大神，如果增加一列姓名列，一列假别，请问代码该如何完善，附件已更新

edwin11891

baoxuehero 发表于 2025-2-23 17:52
修改了一下，可以动态调整了，再次感谢大神的指导！希望还有其他大神提供简练一点的公式

如果是WPS新版，还可以：
a,trimrange(A2:B1000),b,trimrange(C2:D1000)