怎么根据日期提取单元格中日期后面的文字和数值？

jivy1212

1. =IFERROR(VLOOKUP("0",TEXT(LEFT(SUBSTITUTE(FILTERXML("<a><b>"&SUBSTITUTE($B2,"，","</b><b>")&"</b></a>","a/b"),TEXT(C$1,"m/d"),),{1,66}),{";;;!0",0}),2,),"")

复制代码

如果日期的天都是2位就容易多了。

yibao2

=IFERROR(IF(ISNUMBER(-MID($B2,FIND(TEXT(C$1,"m/d"),$B2)+LEN(TEXT(C$1,"m/d")),1)),"",SUBSTITUTE(LEFT(MID($B2,FIND(TEXT(C$1,"m/d"),$B2),99),FIND("，",MID($B2,FIND(TEXT(C$1,"m/d"),$B2),99)&"，")-1),TEXT(C$1,"m/d"),)),"")
日期不统一确实麻烦

菜狗一只

1. =LET(X,IFERROR(SUBSTITUTE(INDEX(TEXTSPLIT(INDIRECT("$B"&ROW(A2)),,"，"),MATCH(1,SEARCH("*"&TEXT(C$1,"M/D")&"*",TEXTSPLIT(INDIRECT("$B"&ROW(A2)),,"，")),0)),TEXT(C$1,"M/D"),""),""),IF(ISNUMBER(ABS(LEFT(X,1))),"",X))

复制代码

公式右拉、下拉
需要新函数，你的excel版本不太够，可以下个wps

SZWZYY

菜狗一只 发表于 2024-3-28 10:46
公式右拉、下拉
需要新函数，你的excel版本不太够，可以下个wps

太难了,高手，这么复杂能写出来，谢谢

SZWZYY

yibao2 发表于 2024-3-28 09:51
=IFERROR(IF(ISNUMBER(-MID($B2,FIND(TEXT(C$1,"m/d"),$B2)+LEN(TEXT(C$1,"m/d")),1)),"",SUBSTITUTE(LEFT( ...

感谢，可以用。

SZWZYY

tmplinshi 发表于 2024-3-27 21:27
C2 公式: (右拉，下拉）

感谢回答，没有花花了，明天送你。

edwin11891

换个思路，分析日期段长度，C2单元格：

1. =IFNA(VLOOKUP(TEXT(C$1:BJ$1,"m/d"),LET(src,TEXTSPLIT(B2,,"，"),REDUCE("",src,LAMBDA(ys,y,LET(n,MAP(LEFT(y,5),LAMBDA(x,SUM(N(CODE(MID(x,SEQUENCE(5),1))<90)))),m,VSTACK(ys,HSTACK(LEFTB(y,n),MIDB(y,n+1,90))),(m))))),2,0),"")

复制代码

下拉（无需右拉），需要WPS最新版（版本16460及以上）或MS365。

swl4561255

自定义函数：

1. Function tiqu(myr As String, mdate As Date)
   
2. Set reg = CreateObject("vbscript.regexp")
   
3. With reg
   
4.     .Global = False
   
5.     .Pattern = "[\u4E00-\u9FA5A]{2,}"
   
6. End With
   
7. sr = Split(myr, "，")
   
8. For i = 0 To UBound(sr)
   
9.    Set ma = reg.Execute(sr(i))
   
10.    st = reg.Replace(sr(i), "-")
    
11.    t = Split(st, "-")
    
12.     If DateValue(t(0)) = mdate Then
    
13.       tiqu = ma(0) & t(1)
    
14.       Exit Function
    
15.     Else
    
16.       tiqu = ""
    
17.     End If
    
18. Next
    
19. End Function
    

复制代码

橒♂蝣

=DROP(
    REDUCE(
        "",
        B2:B5,#将字符串进行遍历
        LAMBDA(s, t,
            LET(
                i, DROP(
                    REDUCE(
                        "",
                        TEXTSPLIT(t, , "，", 1),#将字符串进行分行
                        LAMBDA(x, y,
                            LET(
                                m, TAKE(
                                    TEXTSPLIT(#将字符串再次分列
                                        y,
                                        TEXTSPLIT(
                                            y,
                                            VSTACK(
                                                SEQUENCE(10) - 1,
                                                "/"
                                            ),
                                            ,
                                            1
                                        ),
                                        ,
                                        1
                                    ),
                                    ,
                                    1
                                ),
                                VSTACK(
                                    x,
                                    HSTACK(m, TEXTSPLIT(y, m, , 1))#形成日期与内容的对应二维表
                                )
                            )
                        )
                    ),
                    1
                ),
                j, MONTH(C1:BJ1) & "/" & DAY(C1:BJ1) & " ",#将日期变为与i对应的文本格式，加空格以区分单数日双数日
                VSTACK(
                    s,
                    MAP(
                        SEQUENCE(, COLUMNS(C1:BJ1)),
                        LAMBDA(a,
                            LET(
                                b, IF(
                                    ISNUMBER(
                                        FIND(INDEX(i, , 1) & " ", j)#与日期匹配形成几列数据
                                    ),
                                    INDEX(i, , 2),
                                    ""
                                ),
                                TEXTJOIN("", 1, INDEX(b, , a))#将几列数据合并成一列
                                
                            )
                        )
                    )
                )
            )
        )
    ),
    1
)