怎么根据日期提取单元格中日期后面的文字和数值？

SZWZYY · 发表于 2024-3-27 20:45

本帖最后由 SZWZYY 于 2024-3-28 14:33 编辑

要怎么根据日期提取单元格中日期后面的文字和数值？

世界客都 · 发表于 2024-3-27 21:04

=IFERROR(IF(ISERR(-MID($B5,FIND(TEXT(AF$1,"m/d"),$B5)+LEN(TEXT(AF$1,"m/d")),1)),TRIM(LEFT(SUBSTITUTE(MID($B5,FIND(TEXT(AF$1,"m/d"),$B5)+LEN(TEXT(AF$1,"m/d")),99),"，",REPT(" ",19)),19)),""),"")
随便写的，未简化，但是能满足你的要求，右拉下拉。

miaojohn45 · 发表于 2024-3-27 21:17

本帖最后由 miaojohn45 于 2024-3-27 22:56 编辑

=IFNA(VLOOKUP(TEXT(C$1,"m/d"),MIDB(TEXTSPLIT($B2,,"，"),{1,5},{4,99}),2,),"")

复制代码

=LET(x,TEXTSPLIT($B2,,"，"),y,BYROW(MIDB(x,COLUMN($A:$F),1),LAMBDA(a,TRIM(CONCAT(a)))),XLOOKUP(TEXT(C$1,"m/d"),y,MID(x,LEN(y)+1,99),""))

复制代码

SZWZYY · 发表于 2024-3-27 21:26

世界客都发表于 2024-3-27 21:04
=IFERROR(IF(ISERR(-MID($B5,FIND(TEXT(AF$1,"m/d"),$B5)+LEN(TEXT(AF$1,"m/d")),1)),TRIM(LEFT(SUBSTITUTE ...

感谢，有点复杂，可以用。

tmplinshi · 发表于 2024-3-27 21:27

C2 公式: (右拉，下拉）

=IFERROR(LET(d,TEXT(C$1,"m/d"),b,SEARCHB(d&"??",$B2),e,FINDB("，",$B2&"，",b),REPLACEB(LEFTB($B2,e),1,b+LEN(d)-1,)),"")

复制代码

世界客都 · 发表于 2024-3-27 21:33

miaojohn45 发表于 2024-3-27 21:17

取4个字节对嘛？
如果是B2单元格是2月1日白菜30斤
那么MIDB出来会有一个空格，VLOOKUP是查找不到的

世界客都 · 发表于 2024-3-27 21:34

miaojohn45 发表于 2024-3-27 21:17

试试2月1日白菜30斤

世界客都 · 发表于 2024-3-27 21:35

SZWZYY 发表于 2024-3-27 21:26
感谢，有点复杂，可以用。

虽然长点，但是稳妥点哈哈。

miaojohn45 · 发表于 2024-3-27 21:51

世界客都发表于 2024-3-27 21:33
取4个字节对嘛？
如果是B2单元格是2月1日白菜30斤
那么MIDB出来会有一个空格，VLOOKUP是查找不到的

确实只针对当前日期数据适用。

edwin11891 · 发表于 2024-3-28 08:46

本帖最后由 edwin11891 于 2024-3-28 11:14 编辑

拉个火车，基本思路利用3楼的，增加了识别日期字符长度，并按照实际长度提取日期，避免直接以1、5位置提取时出错，无需右拉，只需下拉即可：

=IFNA(VLOOKUP(TEXT(C$1:BJ$1,"m/d"),LET(src,TEXTSPLIT(B2,,"，"),REDUCE("",src,LAMBDA(ys,y,LET(t,MAP(SEQUENCE(LENB(y)),LAMBDA(x,IF(TRIM(MIDB(y,1,x))=TRIM(MIDB(y,1,x-1)),x-1,""))),n,MIN(t),m,VSTACK(ys,HSTACK(LEFTB(y,n),MIDB(y,n+1,90))),(m))))),2,0),"")

复制代码

		自动登录	找回密码
密码			免费注册

[已解决] 怎么根据日期提取单元格中日期后面的文字和数值？

评分

评分

评分