数据按指定品名进行合并

tpb123

mykitami 发表于 2024-3-14 23:15
=LET(a,SCAN(,A2:A33,LAMBDA(x,y,IF(y="",x,y))),w,REDUCE(A1:B1,UNIQUE(a),LAMBDA(x,y,LET(b,FILTER(B2:B3 ...

厉害厉害，好多高级的新函数，可以好好学一下了

tpb123

tmplinshi 发表于 2024-3-15 00:19
还可以简单一点

天哪，直接在原来的基础上简短了一半都不止，真是神人

tpb123

tmplinshi 发表于 2024-3-15 00:19
还可以简单一点

大神  这种情况如果要追加一行重复，需要怎么实现，要一直VSTACK堆叠上去?？

tmplinshi

tpb123 发表于 2024-3-15 10:20
大神  这种情况如果要追加一行重复，需要怎么实现，要一直VSTACK堆叠上去?？

1. =LET(
   
2.     src, A1:B33,
   
3.     fruits, K1:K11,
   
4.     a, INDEX(src, , 1),
   
5.     b, INDEX(src, , 2),
   
6.     isFruit, ISNUMBER(MATCH(b, fruits, 0)),
   
7.     isPreFruit, VSTACK(0, DROP(isFruit, -1)),
   
8.     str, CONCAT(IF((a = "") * isFruit * isPreFruit, "、" & b, ";" & a & "," & b)),
   
9.     result1, TEXTSPLIT(REPLACE(str, 1, 1, ), ",", ";", , , ""),
   
10.    
    
11.     newA, INDEX(result1, , 1),
    
12.     newB, INDEX(result1, , 2),
    
13.     containsFruit, ISNUMBER(FIND("、", newB)) + COUNTIF(fruits, newB),
    
14.     newStr, CONCAT((";" & newA & "," & newB) & IF(containsFruit, ";," & newB, "")),
    
15.     TEXTSPLIT(REPLACE(newStr, 1, 1, ), ",", ";", , , "")
    
16. )

复制代码

方法二：

1. =LET(
   
2.     src, A1:B33,
   
3.     fruits, K1:K11,
   
4.     a, INDEX(src, , 1),
   
5.     b, INDEX(src, , 2),
   
6.     isFruit, ISNUMBER(MATCH(b, fruits, 0)),
   
7.     isPreFruit, VSTACK(0, DROP(isFruit, -1)),
   
8.     str, CONCAT(IF((a = "") * isFruit * isPreFruit, "、" & b, ";" & a & "," & b)),
   
9.     result1, TEXTSPLIT(REPLACE(str, 1, 1, ), ",", ";", , , ""),
   
10.    
    
11.     newB, INDEX(result1, , 2),
    
12.     newCols, IF(MATCH(TEXTBEFORE(newB,"、",,,,newB),fruits,0), HSTACK(TEXT(newB,";;;"), newB)),
    
13.     WRAPROWS(TOROW(HSTACK(result1, newCols), 2), 2)
    
14. )

复制代码

世界客都

tpb123 发表于 2024-3-15 10:08
低版本注重的就是逻辑，看了大神的公式，思路非常牛逼，公式也简短，厉害

呃，太繁杂了。没啥价值，还是365好，一步到位。

cnmlgb9998

用PQ！！！！！！！！！！！！！！！！！！！！！！

edwin11891

tmplinshi 发表于 2024-3-15 00:19
还可以简单一点

方法挺秒，尤其错行累积水果的算法。
就是有一个问题：当水果不是连续，比如小龙的“香蕉”改为非水果时，结果有误。楼上7楼的方法则依然正确。

你是那块小饼干

1. =LET(
   
2. X,SCAN("",A2:A33,LAMBDA(X,Y,IF(Y<>"",Y,X))),
   
3. Y,UNIQUE(X),
   
4. T,$O$1:$O$11,
   
5. REDUCE({"人名","采购类型"},Y,
   
6. LAMBDA(A,B,
   
7. LET(
   
8. Z,FILTER(B2:B33,X=B,""),
   
9. VSTACK(A,IFNA(HSTACK(B,TEXTSPLIT(TEXTJOIN("/",TRUE,VSTACK(TEXTJOIN(",",TRUE,FILTER(Z,ISNUMBER(MATCH(Z,T,0)),"")),
   
10. FILTER(Z,ISERROR(MATCH(Z,T,0)),""))),,"/",TRUE)),""))))))
    

复制代码

edwin11891

1. =LET(_m, UNIQUE((FILTER(A2:A33,A2:A33<>""))),t,SCAN("",A$2:A$33,LAMBDA(acc,a,IF(a="",acc,a))),
   
2.      REDUCE(A1:B1,_m,LAMBDA(y,x,
   
3.        LET(s,FILTER(B$2:B$33,t=x),
   
4.          m,IFERROR(FILTER(s,ISNUMBER(XLOOKUP(s,L$1:L$11,ROW($1:$11)))),""),
   
5.          n,IFERROR(FILTER(s,ISERROR(XLOOKUP(s,L$1:L$11,ROW($1:$11)))),""),
   
6.          mc, IF(ROWS(m)>0,TEXTJOIN(",",1,m),""), ns,IF(ROWS(n)=1,"",n),
   
7.          ms, IFERROR(VSTACK(ns,mc),""), mss,MAP(ms,LAMBDA(xp,IF(LEN(xp)=0,xp=1/0,xp))),
   
8.          md, TOCOL(mss,3),
   
9.          VSTACK(y,IFNA(HSTACK(x,md),"") )))))

复制代码

tmplinshi

如果要将不连续的水果组合在一起:

1. =LET(
   
2.     getSortNums, LAMBDA(self, src, fruits, [i], [n], [m],
   
3.         LET(
   
4.             i, i + 1,
   
5.             a, INDEX(src, i, 1),
   
6.             b, INDEX(src, i, 2),
   
7.             isFruit, ISNUMBER(MATCH(b, fruits, 0)),
   
8.             n, n + OR(a <> "", NOT(isFruit)),
   
9.             m, IF(a <> "", 0, m),
   
10.             newM, IF(isFruit, IF(m = 0, n, m) + 1%%, m),
    
11.             num, TEXT(IF(isFruit, newM, n), "00000.00000"),
    
12.             IF(i < ROWS(src), VSTACK(num, self(self, src, fruits, i, n, newM)), num)
    
13.         )
    
14.     ),
    
15. 
    
16.     src, A1:B33,
    
17.     fruits, K1:K11,
    
18.    
    
19.     a, INDEX(src, , 1),
    
20.     b, SORTBY(INDEX(src, , 2), getSortNums(getSortNums, src, fruits)),
    
21.     isFruit, ISNUMBER(MATCH(b, fruits, 0)),
    
22.     isPreFruit, VSTACK(0, DROP(isFruit, -1)),
    
23.     str, CONCAT(IF((a = "") * isFruit * isPreFruit, "、" & b, ";" & a & "," & b)),
    
24.     result1, TEXTSPLIT(REPLACE(str, 1, 1, ), ",", ";", , , ""),
    
25.    
    
26.     newA, INDEX(result1, , 1),
    
27.     newB, INDEX(result1, , 2),
    
28.     containsFruit, ISNUMBER(FIND("、", newB)) + COUNTIF(fruits, newB),
    
29.     newStr, CONCAT((";" & newA & "," & newB) & IF(containsFruit, ";," & newB, "")),
    
30.     TEXTSPLIT(REPLACE(newStr, 1, 1, ), ",", ";", , , "")
    
31. )

复制代码