数据按指定品名进行合并

tpb123

各位EH函数老师和大佬们下午好，请教一个比较难的案例，使用函数将下图的左边的数据变成右边的数据，如何做到？谢谢各位老师，文件已附上。

tpb123

有厉害的无敌大神？

tmplinshi

1. =LET(
   
2.     src, A1:B33,
   
3.     fruits, K1:K11,
   
4.     fn, LAMBDA(self, [i], [isPreFruit], [out],
   
5.         LET(
   
6.             i, i + 1,
   
7.             a, INDEX(src, i, 1),
   
8.             b, INDEX(src, i, 2),
   
9.             isFruit, COUNTIF(fruits, b),
   
10.             out, IF(
    
11.                 AND(a = "", isFruit, isPreFruit),
    
12.                 out & "、" & b,
    
13.                 out & ";" & a & "," & b
    
14.             ),
    
15.             IF(i < ROWS(src), self(self, i, isFruit, out), out)
    
16.         )
    
17.     ),
    
18.     TEXTSPLIT(REPLACE(fn(fn), 1, 1, ), ",", ";", , , "")
    
19. )

复制代码

示例结果少了一个“苹果”。

tpb123

tmplinshi 发表于 2024-3-14 16:44
示例结果少了一个“苹果”。

楼主太牛逼了，真的强，佩服佩服，好好学习一下

世界客都

数据和示范.zip (15.64 KB, 下载次数: 18)

2024-3-14 21:52 上传

点击文件名下载附件

非365，采用了辅助列，供参考

edwin11891

tmplinshi 发表于 2024-3-14 16:44
示例结果少了一个“苹果”。

竟然都没用365循环函数！

mykitami

=LET(a,SCAN(,A2:A33,LAMBDA(x,y,IF(y="",x,y))),w,REDUCE(A1:B1,UNIQUE(a),LAMBDA(x,y,LET(b,FILTER(B2:B33,a=y),c,FILTER(b,MAP(b,LAMBDA(z,ISNUMBER(MATCH(z,K1:K11,)))),""),d,FILTER(b,MAP(b,LAMBDA(z,1-ISNUMBER(MATCH(z,K1:K11,)))),""),VSTACK(x,IFNA(HSTACK(y,VSTACK(TEXTJOIN("、",,c),d)),y))))),p,FILTER(w,TAKE(w,,-1)<>""),HSTACK(SCAN("",SEQUENCE(ROWS(TAKE(p,,1))),LAMBDA(m,n,IF(SUM(N(TAKE(TAKE(p,,1),n)=INDEX(TAKE(p,,1),n)))=1,INDEX(TAKE(p,,1),n),""))),TAKE(p,,-1)))

tmplinshi

还可以简单一点

1. =LET(
   
2.     src, A1:B33,
   
3.     fruits, K1:K11,
   
4.     a, INDEX(src, , 1),
   
5.     b, INDEX(src, , 2),
   
6.     isFruit, ISNUMBER(MATCH(b, fruits, 0)),
   
7.     isPreFruit, VSTACK(0, DROP(isFruit, -1)),
   
8.     str, CONCAT(IF((a = "") * isFruit * isPreFruit, "、" & b, ";" & a & "," & b)),
   
9.     TEXTSPLIT(REPLACE(str, 1, 1, ), ",", ";", , , "")
   
10. )

复制代码

992146

厉害！！！！！！！！！

tpb123

世界客都 发表于 2024-3-14 21:52
非365，采用了辅助列，供参考

低版本注重的就是逻辑，看了大神的公式，思路非常牛逼，公式也简短，厉害