ppt学习资料

weiyingde

Selected属性
如果已选择指定的表格单元格，则属性值为 True。只读。Boolean 类型。
expression.Selected
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例中，如果指定表格的第一个单元格为选中状态，则在其周围放置边框。
Sub IsCellSelected()
    Dim celSelected As Cell
    Set celSelected = ActivePresentation.Slides(1).Shapes(1) _
        .Table.Columns(1).Cells(1)
    If celSelected.Selected Then
        With celSelected
            .Borders(ppBorderTop).DashStyle = msoLineRoundDot
            .Borders(ppBorderBottom).DashStyle = msoLineRoundDot
            .Borders(ppBorderLeft).DashStyle = msoLineRoundDot
            .Borders(ppBorderRight).DashStyle = msoLineRoundDot
        End With
    End If
End Sub
Selection属性
返回一个Selection对象，该对象代表指定文档窗口中选定项。只读。
VBA示例
如果在活动窗口中选定了文本，本示例将该文本设为倾斜。
With Application.ActiveWindow.Selection
    If .Type = ppSelectionText Then
        .TextRange.Font.Italic = True
    End If
End With
Shadow属性
应用于 Font对象的Shadow属性。
决定指定的文本是否使用阴影。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 指定文本不使用阴影。
msoTriStateMixed 某些文本使用阴影，而某些则不使用。
msoTriStateToggle
msoTrue 指定文本使用阴影。
expression.Shadow
expression  必选。该表达式返回上述对象之一。
应用于 Shape 和 ShapeRange对象的 Shadow属性。
返回只读的ShadowFormat对象，该对象包含指定形状的阴影格式属性。
expression.Shadow
expression  必选。该表达式返回上述对象之一。
VBA示例
应用于 Font对象。
本示例为当前演示文稿第一张幻灯片的标题文本添加阴影。
Application.ActivePresentation.Slides(1).Shapes.Title _
    .TextFrame.TextRange.Font.Shadow = True
应用于 Shape 和 ShapeRange对象。
本示例在当前演示文稿第一张幻灯片中添加一个有阴影的矩形。蓝色浮凸效果的阴影距该矩形的右边 3 磅，下边 2 磅。
Set myShap = Application.ActivePresentation.Slides(1).Shapes
With myShap.AddShape(msoShapeRectangle, 10, 10, 150, 90).Shadow
    .Type = msoShadow17
    .ForeColor.RGB = RGB(0, 0, 128)
    .OffsetX = 3
    .OffsetY = 2
End With

weiyingde

Shape属性
返回Shape对象，该对象代表表格单元格中的形状（Cell对象）、图示中的图示节点（DiagramNode对象）或具有动画效果的形状（Effect对象）。
expression.Shape
expression  必选。该表达式返回上述对象之一。
VBA示例
本示例在新演示文稿中创建一个 3x3 表格，并向表格的第一个单元格中插入一个十字星。
With Presentations.Add
    With .Slides.Add(1, ppLayoutBlank)
        .Shapes.AddTable(3, 3).Select
        .Shapes(1).Table.Cell(1, 1).Shape _
            .AutoShapeType = msoShape4pointStar
    End With
End With
以下示例创建一个图示并且向根节点添加子节点。在每个子节点添加完毕后，根节点将显示它所拥有的子节点数。
Sub CountChildNodes()
    Dim dgnNode As DiagramNode
    Dim shpDiagram As Shape
    Dim intNodes As Integer
    Set shpDiagram = ActivePresentation.Slides(1).Shapes.AddDiagram _
        (Type:=msoDiagramRadial, Left:=10, Top:=15, _
        Width:=400, Height:=475)
    shpDiagram.DiagramNode.Children.AddNode
    Set dgnNode = shpDiagram.DiagramNode.Root
    For intNodes = 1 To 3
        dgnNode.Children.AddNode
        dgnNode.Shape.TextFrame.TextRange.Text = intNodes
    Next intNodes
End Sub
ShapeRange属性
返回一个ShapeRange对象，该对象代表指定幻灯片中所有选定的幻灯片对象。其范围包括幻灯片中的绘图对象、形状、OLE对象、图片、文本对象、标题、页眉、页脚、幻灯片编号、占位符以及日期和时间对象等。只读。
说明
只有演示文稿在普通、幻灯片或任意母版视图时，才能从选定的内容中返回一个形状区域。
VBA示例
本示例设置第一个窗口中所有选定形状的前景填充颜色。
Windows(1).Selection.ShapeRange.Fill _
    .ForeColor.RGB = RGB(255, 0, 255)

weiyingde

Shapes属性
返回一个Shapes集合，该集合代表被放置或插入到指定幻灯片、幻灯片母版、或幻灯片组的所有元素。该集合可以包含绘图、OLE对象、图片、文本对象、页眉、页脚、幻灯片编号、以及日期和时间对象，这些对象位于幻灯片或备注页中的幻灯片映像上。只读。
有关返回集合中单个元素的详细信息，请参阅返回集合中的对象。
VBA示例
本示例添加一个宽 100 磅、高 50 磅的矩形，它的左上角距当前演示文稿第一张幻灯片的左边 5 磅、上边 25 磅。
Set firstSlide = ActivePresentation.Slides(1)
firstSlide.Shapes.AddShape msoShapeRectangle, 5, 25, 100, 50
本示例设置当前演示文稿第一张幻灯片的第三个形状的填充纹理。
Set newRect = ActivePresentation.Slides(1).Shapes(3)
newRect.Fill.PresetTextured msoTextureOak
假设当前演示文稿第一张幻灯片包含一个标题，以下示例的第二行和第三行设置该演示文稿第一张幻灯片的标题文本。
Set firstSl = ActivePresentation.Slides(1)
firstSl.Shapes.Title.TextFrame.TextRange.Text = "Some title text"
firstSl.Shapes(1).TextFrame.TextRange.Text = "Other title text"
假设当前演示文稿第二张幻灯片中的第二个形状包含文本框架，以下示例向该幻灯片添加一系列的段落。请注意：Chr(13) 用于在该文本中插入段落标记。
Set tShape = ActivePresentation.Slides(2).Shapes(2)
tShape.TextFrame.TextRange.Text = "First Item" & Chr(13) & _
    "Second Item" & Chr(13) & "Third Item"
对于大多数幻灯片版式，第一个形状为文本占位符。以下示例与上例完成相同功能。
Set testShape = ActivePresentation.Slides(2).Shapes.Placeholders(2)
testShape.TextFrame.TextRange.Text = "First Item" & _
    Chr(13) & "Second Item" & Chr(13) & "Third Item"

weiyingde

ShowandReturn属性
决定 MicrosoftPowerPoint 是否返回初始的幻灯片放映和返回的条件。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 默认值。PowerPoint 不会从未激活的自定义幻灯片放映返回初始幻灯片放映。
msoTriStateMixed
msoTriStateToggle
msoTrue PowerPoint 从取消激活的自定义幻灯片放映返回初始幻灯片放映，该自定义幻灯片放映通过初始演示文稿的Hyperlink或ActionSetting对象激活。

VBA示例
本示例设置活动演示文稿中第一张幻灯片上第五个形状的鼠标单击动作为：显示名为“techtalk”的自定义幻灯片放映。当该自定义幻灯片放映结束后，将自动返回演示文稿在鼠标单击前的最初状态。
With ActivePresentation.Slides(1).Shapes(5) _
        .ActionSettings(ppMouseClick)
    .Action = ppActionNamedSlideShow
    .SlideShowName = "techtalk"
    .ShowandReturn = msoTrue
End With
ShowScrollbar属性
属性值为 MsoTrue 时，在浏览模式下显示幻灯片放映时使用的滚动条。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue 不应用于此属性。
msoFalse
msoTriStateMixed 不应用于此属性。
msoTriStateToggle 不应用于此属性。
msoTrue
expression.ShowScrollbar
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
在设置 ShowScrollbar属性之前使用ShowType属性。
VBA示例
本示例指定在某个窗口中显示当前演示文稿的幻灯片放映，并且在幻灯片放映时显示用于浏览幻灯片的滚动条。
Sub ShowSlideShowScrollBar()
    With ActivePresentation.SlideShowSettings
        .ShowType = ppShowTypeWindow
        .ShowScrollBar = msoTrue
    End With
End Sub

weiyingde

ShowSlideAnimation属性
决定在预览、保存或发布 Web 演示文稿时是否启用幻灯片动画。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 默认值。
msoTriStateMixed
msoTriStateToggle
msoTrue 在预览、保存或发布 Web 演示文稿时启用幻灯片动画。
VBA示例
本示例指定对 Web 演示文稿启用第二篇演示文稿的幻灯片动画。再预览该 Web 页。
With Presentations(2)
    .WebOptions.ShowSlideAnimation = msoTrue
    .WebPagePreview
End With
ShowStartupDialog属性
属性值为MsoTrue 时，启动 Microsoft PowerPoint 后显示“新建演示文稿”任务窗格。可读写。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue 不应用于此属性。
msoFalse 隐藏“新建演示文稿”侧窗格。
msoTriStateMixed 不应用于此属性。
msoTriStateToggle 不应用于此属性。
msoTrue 默认值。显示“新建演示文稿”侧窗格。
expression.ShowStartupDialog
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
下面代码行在 PowerPoint 启动时禁用“新建演示文稿”任务窗格。
Sub DontShowStartup
    Application.ShowStartupDialog = msoFalse
End Sub

weiyingde

ShowType属性
返回或设置指定幻灯片放映的放映类型。可读写。PpSlideShowType 类型。
PpSlideShowType 可以是下列 PpSlideShowType 类型常数之一。
ppShowTypeKiosk
ppShowTypeSpeaker
ppShowTypeWindow
expression.ShowType
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例在窗口中运行当前演示文稿的一个幻灯片放映，从第二张幻灯片开始，到第四张幻灯片结束。新的幻灯片放映窗口位于屏幕左上角，宽度和高度均为 300 磅。
With ActivePresentation.SlideShowSettings
    .RangeType = ppShowSlideRange
    .StartingSlide = 2
    .EndingSlide = 4
    .ShowType = ppShowTypeWindow
    With .Run
        .Left = 0
        .Top = 0
        .Width = 300
        .Height = 300
    End With
End With
ShowWindowsInTaskbar属性
决定是否每一个打开的演示文稿都有单独的 Windows 任务栏按钮。 可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 默认值。每个打开的演示文稿都有单独的 Windows 任务栏按钮。
说明
当设置为 True 时，本属性将模拟单文档界面 (SDI) 的外观，这样便于在打开的演示文稿之间切换。但是，如果在处理多个演示文稿的同时还打开了其他应用程序，则可能要将该属性设置为 False，以避免不必要的按钮填充任务栏。
仅当使用 Microsoft Office with Windows 或 Windows 2000 时该属性可用。
VBA示例
本示例指定每个打开的演示文稿都不具有单独的 Windows 任务栏按钮。
Application.ShowWindowsInTaskbar = msoFalse

weiyingde

ShowWithAnimation属性
决定指定幻灯片放映是否显示具有分配动画设置的形状。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 指定幻灯片放映显示具有分配动画设置的形状。
VBA示例
本示例运行当前演示文稿的一个幻灯片放映，同时关闭动画和旁白。
With ActivePresentation.SlideShowSettings
    .ShowWithAnimation = msoFalse
    .ShowWithNarration = msoFalse
    .Run
End With
ShowWithNarration属性
决定显示指定幻灯片放映时是否有旁白。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 指定幻灯片放映显示时有旁白。
VBA示例
本示例运行当前演示文稿的一个幻灯片放映，关闭动画和旁白。
With ActivePresentation.SlideShowSettings
    .ShowWithAnimation = msoFalse
    .ShowWithNarration = msoFalse
    .Run
End With

weiyingde

Signatures属性
返回SignatureSet对象，该对象代表数字签名的集合。
expression.Signatures
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
下面代码行显示数字签名的数量。
Sub DisplayNumberOfSignatures
    MsgBox "Number of digital signatures: " & _
        ActivePresentation.Signatures.Count
End Sub
Size属性
返回或设置字符大小，以磅为单位。可读写。Single 类型。
VBA示例
本示例将第一张幻灯片第一个形状的附加文本的大小设为 24 磅。
Application.ActivePresentation.Slides(1) _
    .Shapes(1).TextFrame.TextRange.Font _
    .Size = 24
Slide属性
应用于 View对象的 Slide属性。
返回或设置一个Slide对象，该对象代表当前在指定文档窗口视图中显示的幻灯片。可读写。
expression.Slide
expression  必选。该表达式返回上述对象之一。
应用于 SlideShowView对象的 Slide属性。
返回一个Slide对象，该对象代表当前在指定幻灯片放映窗口视图中显示的幻灯片。只读。
expression.Slide
expression  必选。该表达式返回上述对象之一。
说明
如果当前显示的幻灯片来源于一个嵌入演示文稿，可以使用 Slide对象（从 Slide属性返回）的Parent属性返回包含该幻灯片的嵌入演示文稿。（SlideShowWindow对象或 DocumentWindow对象的Presentation属性返回建立该窗口的演示文稿，而不是该嵌入演示文稿。）
VBA示例
应用于 View对象。
本示例在剪贴板中存放当前显示于第一个幻灯片放映窗口中的幻灯片的一个副本。
SlideShowWindows(1).View.Slide.Copy
本示例显示正在第一个幻灯片放映窗口中运行的演示文稿的名称。
MsgBox SlideShowWindows(1).View.Slide.Parent.Name

weiyingde

SlideIDs属性
返回指定命名幻灯片放映的一个幻灯片 ID 数组。只读。Variant 类型。
VBA示例
本示例将当前窗口中的当前幻灯片添加到自定义幻灯片放映“Marketing Short Version”中。请注意，要保存修改后的自定义幻灯片放映，必须删除原自定义放映，再使用相同名称重新添加。另请注意，要调整包含于 Variant 变量中的数组大小，必须在调整该数组大小前清楚地声明该变量。
'NOTE - The following code line is NOT optional.
'Can't redim array without this
Dim customShowSlideIDs As Variant
Dim customShowToExpand As NamedSlideShow
customShowName = "Marketing Short Version"
Set customShowToExpand = ActivePresentation.SlideShowSettings _
    .NamedSlideShows(customShowName)
slideToAddID = ActiveWindow.View.Slide.SlideID
customShowSlideIDs = customShowToExpand.SlideIDs
numSlides = UBound(customShowSlideIDs)
ReDim Preserve customShowSlideIDs(numSlides + 1)
customShowSlideIDs(numSlides + 1) = slideToAddID
customShowToExpand.Delete
ActivePresentation.SlideShowSettings.NamedSlideShows _
    .Add customShowName, customShowSlideIDs
SlideIndex属性
返回 Slides集合内指定幻灯片的索引号。只读。Long 类型。
说明
与SlideID属性不同，在演示文稿中添加或重新排列幻灯片时，Slide对象的 SlideIndex属性会改变。因此，与使用具有幻灯片索引号的Item方法相比，使用具有幻灯片 ID 号的FindBySlideID方法是从 Slides集合返回一个指定 Slide对象的更可靠方法。
VBA示例
本示例显示在第一个幻灯片放映窗口中当前放映幻灯片的索引号。
MsgBox SlideShowWindows(1).View.Slide.SlideIndex
SlideMaster属性
返回一个Master对象，该对象代表幻灯片母版。
expression.SlideMaster
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例设置当前演示文稿的幻灯片母版的背景图案。
Application.ActivePresentation.SlideMaster.Background.Fill _
    .PresetTextured msoTextureGreenMarble

weiyingde

SlideNumber属性
应用于 HeadersFooters对象的 SlideNumber属性。
返回一个HeaderFooter对象，该对象代表在幻灯片右下角的幻灯片编号或在备注页、打印讲义的页或大纲右下角的页编号。只读。
expression.SlideNumber
expression  必选。该表达式返回上述对象之一。
应用于 Slide 和 SlideRange对象的 SlideNumber属性。
返回幻灯片编号。只读。Integer 类型。
expression.SlideNumber
expression  必选。该表达式返回上述对象之一。
说明
Slide对象的 SlideNumber属性是显示幻灯片编号时在幻灯片右下角出现的实际编号。此编号由演示文稿（SlideIndex属性值）中的幻灯片编号以及作为演示文稿（FirstSlideNumber属性值)起始幻灯片的编号决定。幻灯片编号总是等于开始幻灯片编号 + 幻灯片索引号 - 1。
VBA示例
应用于 HeadersFooters 对象。
本示例隐藏当前演示文稿第二张幻灯片的幻灯片编号（如果该编号当前为可见），或显示该幻灯片编号（如果该编号当前为隐藏）。
With Application.ActivePresentation.Slides(2) _
        .HeadersFooters.SlideNumber
    If .Visible Then
        .Visible = False
    Else
        .Visible = True
    End If
End With
应用于 Slide 和 SlideRange对象。
本示例示范第一个幻灯片编号的变化对某特定幻灯片编号的影响。
With Application.ActivePresentation
    .PageSetup.FirstSlideNumber = 1   'starts slide numbering at 1
    MsgBox .Slides(2).SlideNumber     'returns 2
    .PageSetup.FirstSlideNumber = 10 'starts slide numbering at 10
    MsgBox .Slides(2).SlideNumber     'returns 11
End With