ppt学习资料

weiyingde

RewindAtEnd属性
设置或返回MsoTriState 类型常数，该常数代表动画结束后对象是否返回其初始位置。可读写。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue 不应用于此属性。
msoFalse 默认值。动画结束后对象不返回其初始位置。
msoTriStateMixed 不应用于此属性。
msoTriStateToggle 不应用于此属性。
msoTrue 动画结束后对象返回其初始位置。
expression.RewindAtEnd
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例添加一个形状并向该形状添加一个动画，然后指示该形状在动画结束后返回其初始位置。
Sub AddShapeSetTiming()
    Dim effDiamond As Effect
    Dim shpRectangle As Shape
    'Adds shape and sets animation effect
    Set shpRectangle = ActivePresentation.Slides(1).Shapes _
        .AddShape(Type:=msoShapeRectangle, Left:=100, _
        Top:=100, Width:=50, Height:=50)
    Set effDiamond = ActivePresentation.Slides(1).TimeLine.MainSequence _
        .AddEffect(Shape:=shpRectangle, effectId:=msoAnimEffectPathDiamond)
    'Sets duration of animation and returns shape to its original position
    With effDiamond.Timing
        .Duration = 3
        .RewindAtEnd = msoTrue
    End With
End Sub

weiyingde

RewindMovie属性
决定是否一旦指定的影片放映完毕后，自动重播该影片的第一帧。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 一旦指定的影片放映完毕，自动重新显示该影片的第一帧。
VBA示例
本示例指定影片的第一帧（由当前演示文稿第一张幻灯片的第三个形状代表）在影片播放完毕后重新显示。第三个形状必须是影片对象。
Set OLEobj = ActivePresentation.Slides(1).Shapes(3)
OLEobj.AnimationSettings.PlaySettings.RewindMovie = msoTrue
RGB属性
应用于 ColorFormat对象的 RGB属性。
返回或设置指定颜色的红-绿-蓝 (RGB) 值。可读写。Long 类型。
应用于 RGBColor对象的 RGB属性。
返回或设置 RGB（红-绿-蓝）值，该值属于指定配色方案中的颜色，或属于可读写PpColorSchemeIndex 常数使用的额外颜色。使用 Colors方法返回 RGBColor对象。
PpColorSchemeIndex 可以是下列 PpColorSchemeIndex 类型常数之一。
ppAccent1
ppAccent2
ppAccent3
ppBackground
ppFill
ppForeground
ppShadow
ppTitle
VBA示例
应用于 ColorFormat对象。
本示例为当前演示文稿的第三个配色方案设定背景色，并将配色方案应用于基于幻灯片母版的演示文稿中所有的幻灯片。
With ActivePresentation
    Set cs1 = .ColorSchemes(3)
    cs1.Colors(ppBackground).RGB = RGB(128, 128, 0)
    .SlideMaster.ColorScheme = cs1
End With
应用于 RGBColor对象。
本示例显示当前文档第一张幻灯片的第一个形状中前景填充颜色的红、绿、蓝分配值。
Set myDocument = ActivePresentation.Slides(1)
c = myDocument.Shapes(1).Fill.ForeColor.RGB
redComponent = c Mod 256
greenComponent = c \ 256 Mod 256
blueComponent = c \ 65536 Mod 256
MsgBox "RGB components: " & redComponent & _
    ", " & greenComponent & ", " & blueComponent

weiyingde

Root属性
返回DiagramNode对象，该对象代表图示源节点所属的图示根节点。
expression.Root
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例创建一个组织结构图，并向图示根节点中添加子节点。
Sub AddChildNodesToRoot()
    Dim dgnNode As DiagramNode
    Dim shpOrgChart As Shape
    Dim intNodes As Integer
        'Adds organization chart and first node
    Set shpOrgChart = ActivePresentation.Slides(1).Shapes _
        .AddDiagram(Type:=msoDiagramOrgChart, Left:=10, _
        Top:=15, Width:=400, Height:=475)
    shpOrgChart.DiagramNode.Children.AddNode
    Set dgnNode = shpOrgChart.DiagramNode.Root
      'Adds three child nodes to root node
    For intNodes = 1 To 3
        dgnNode.Children.AddNode
    Next intNodes
End Sub
RotatedChars属性
决定是否将指定艺术字中的字符相对于艺术字边框形状旋转 90 度。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 指定艺术字中的字符保留原有的相对于边框形状的方向。
msoTriStateMixed
msoTriStateToggle
msoTrue 将指定艺术字中的字符相对于艺术字边框形状旋转 90 度。
说明
如果艺术字中含有水平文字，将 RotatedChars属性设置为 msoTrue 可将该字符逆时针旋转 90 度。如果艺术字中含有垂直文字，将 RotatedChars属性设置为 msoFalse 可将该字符顺时针旋转 90 度。使用 ToggleVerticalText方法在水平文字流和垂直文字流之间切换。
Shape对象的Flip方法和Rotation属性以及 TextEffectFormat对象的 RotatedChars属性 和ToggleVerticalText方法都影响代表艺术字的 Shape对象中文本流的字符方向。您可能需要多次试验，才能找出如何组合这些属性和方法的效果获得预期结果。
VBA示例
本例向myDocument 中添加带有“Test”文本的艺术字，并将该字符逆时针旋转 90 度。
Set myDocument = ActivePresentation.Slides(1)
Set newWordArt = myDocument.Shapes.AddTextEffect _
    (PresetTextEffect:=msoTextEffect1, Text:="Test", _
    FontName:="Arial Black", FontSize:=36, _
    FontBold:=msoFalse, FontItalic:=msoFalse, Left:=10, Top:=10)
newWordArt.TextEffect.RotatedChars = msoTrue

weiyingde

Rotation属性
返回或设置指定形状绕Z 轴旋转的度数。正值表示顺时针旋转，负值表示逆时针旋转。可读写。Single 类型。
说明
可以使用ThreeDFormat对象的RotationX属性或RotationY属性设置一个三维形状绕 X 轴和 Y 轴的旋转。
VBA示例
本示例调整myDocument 中所有形状的旋转以便和第一个形状的旋转相适应。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes
    sh1Rotation = .Item(1).Rotation
    For o = 1 To .Count
        .Item(o).Rotation = sh1Rotation
    Next
End With
RotationEffect属性
返回动画动作的RotationEffect对象。
expression.RotationEffect
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
以下示例在第一张幻灯片中添加一个新形状并设置旋转动画动作。
Sub AddRotation()
    Dim shpNew As Shape
    Dim effNew As Effect
    Dim aniNew As AnimationBehavior
    Set shpNew = ActivePresentation.Slides(1).Shapes _
        .AddShape(Type:=msoShape5pointStar, Left:=0, _
        Top:=0, Width:=100, Height:=100)
    Set effNew = ActivePresentation.Slides(1).TimeLine.MainSequence _
        .AddEffect(Shape:=shpNew, effectId:=msoAnimEffectCustom)
    Set aniNew = effNew.Behaviors.Add(msoAnimTypeRotation)
    With aniNew.RotationEffect
        'Rotate 270 degrees from current position
        .By = 270
    End With
End Sub

weiyingde

RotationX属性
返回或设置延伸形状绕X 轴的旋转，以“度”为单位。可为 - 90 到 90 之间的值。正值表示向上旋转，负值表示向下旋转。可读写。Single 类型。
说明
若要设置延伸形状绕 Y 轴的旋转，请使用 ThreeDFormat对象的RotationY属性。若要设置延伸形状绕 Z 轴的旋转，请使用Shape对象的Rotation属性。若要更改延伸路径的方向而不旋转延伸的正面，请使用SetExtrusionDirection方法。
VBA示例
本示例向myDocument 中添加三个相同的延伸椭圆，并设置分别绕 x 轴旋转 - 30、0 和 30 度。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes
    With .AddShape(msoShapeOval, 30, 60, 50, 25).ThreeD
        .Visible = True
        .RotationX = -30
    End With
    With .AddShape(msoShapeOval, 90, 60, 50, 25).ThreeD
        .Visible = True
        .RotationX = 0
    End With
    With .AddShape(msoShapeOval, 150, 60, 50, 25).ThreeD
        .Visible = True
        .RotationX = 30
    End With
End With
RotationY属性
返回或设置延伸形状绕Y 轴的旋转，以“度”为单位。可为 - 90 到 90 之间的值。正值表示向左旋转，负值表示向右旋转。可读写。Single 类型。
说明
若要设置延伸形状绕 x 轴的旋转，请使用 ThreeDFormat对象的RotationX属性。若要设置延伸形状绕 z 轴的旋转，请使用Shape对象的Rotation属性。若要改变延伸经过路径的方向而不旋转延伸的正面，请使用SetExtrusionDirection方法。
VBA示例
本示例向myDocument 中添加三个相同的延伸椭圆，并设置分别绕 x 轴旋转 - 30、0 和 30 度。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes
    With .AddShape(msoShapeOval, 30, 30, 50, 25).ThreeD
        .Visible = True
        .RotationY = -30
    End With
    With .AddShape(msoShapeOval, 30, 70, 50, 25).ThreeD
        .Visible = True
        .RotationY = 0
    End With
    With .AddShape(msoShapeOval, 30, 110, 50, 25).ThreeD
        .Visible = True
        .RotationY = 30
    End With
End With
Rows属性
返回一个Rows集合，代表表格中的所有行。只读。
有关返回集合中单个元素的详细信息，请参阅返回集合中的对象。
VBA示例
本示例删除表格（活动演示文稿中第二张幻灯片上的第五个形状）中的第三行。
ActivePresentation.Slides(2).Shapes(5).Table.Rows(3).Delete
本示例对表格单元格中第二行的下框线应用虚线样式。
ActiveWindow.Selection.ShapeRange.Table.Rows(2) _
    .Cells.Borders(ppBorderBottom).DashStyle = msoLineDash

weiyingde

Ruler属性
返回一个Ruler对象，该对象代表指定文本的标尺。只读。
VBA示例
本示例在myDocument 中第二个形状中文本的 2 英寸（144 磅）处设置左对齐制表位。
Set myDocument = ActivePresentation.Slides(1)
myDocument.Shapes(2).TextFrame.Ruler.TabStops _
    .Add ppTabStopLeft, 144
Run属性
返回或设置演示文稿或宏名称，该演示文稿或宏在幻灯片放映过程中单击形状或鼠标指针经过形状时运行。Action属性必须设为 ppActionRunMacro 或 ppActionRunProgram，本属性才能影响幻灯片的放映动作。可读写。String 类型。
说明
如果 Action属性的值为 ppActionRunMacro，则指定的字符串值应为一个当前已加载的全局宏的名称。如果 Action属性的值为 ppActionRunProgram，则指定的字符串应为一个程序的完整路径和文件名。
可以将 Run属性设为无参数的或单个 Shape 或 Object参数的宏。幻灯片放映时被单击的形状将被作为此参数传送。
VBA示例
本示例指定在幻灯片放映过程中的任何时候，如果鼠标指针经过形状则运行宏“CalculateTotal”。
With ActivePresentation.Slides(1) _
    .Shapes(3).ActionSettings(ppMouseOver)
        .Action = ppActionRunMacro
        .Run = "CalculateTotal"
        .AnimateAction = True
End With
Saved属性
决定演示文稿自上次保存以来是否进行过更改。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse
msoTriStateMixed
msoTriStateToggle
msoTrue 演示文稿自上次保存以来没有进行过更改。
说明
如果将已修改演示文稿的 Saved属性设置为 msoTrue，则用户关闭演示文稿时不会提示保存所作的修改，且将丢失尚未保存的所有更改。
VBA示例
如果当前演示文稿已被修改而尚未存盘，本示例将其保存。
With Application.ActivePresentation
    If Not .Saved And .Path <> "" Then .Save
End With

weiyingde

SaveNewWebPagesAsWebArchives属性
属性值为 MsoTrue 时，Microsoft PowerPoint 将新的 Web 页保存为 Web 档案。可读写。MsoTriState 类型。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue 不应用于此属性。
msoFalse 将新 Web 页保存为单独的 Web 页。
msoTriStateMixed 不应用于此属性。
msoTriStateToggle 不应用于此属性。
msoTrue 将新 Web 页保存为 Web 档案。
expression.SaveNewWebPagesAsWebArchives
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
设置 SaveNewWebPagesAsWebArchives属性不会更改任何当前打开的 Web 页的格式。必须单独保存打开的 Web 页并且使用SaveAs方法明确地设置 Web 页格式。
VBA示例
本示例启用 SaveNewWebPagesAsWebArchives属性，以便在保存新的 Web 页时将其保存为 Web 档案。
Sub SetWebOption()
    Application.DefaultWebOptions _
        .SaveNewWebPagesAsWebArchives = True
End Sub
ScaleEffect属性
返回给定动画动作的ScaleEffect对象。
expression.ScaleEffect
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例对第一张幻灯片中的第一个形状进行缩放，该形状由零开始增长至其初始大小的 100%。
Sub ChangeScale()
    Dim shpFirst As Shape
    Dim effNew As Effect
    Dim aniScale As AnimationBehavior
    Set shpFirst = ActivePresentation.Slides(1).Shapes(1)
    Set effNew = ActivePresentation.Slides(1).TimeLine.MainSequence _
        .AddEffect(Shape:=shpFirst, effectId:=msoAnimEffectCustom)
    Set aniScale = effNew.Behaviors.Add(msoAnimTypeScale)
    With aniScale.ScaleEffect
        'Starting size
        .FromX = 0
        .FromY = 0
        'Size after scale effect
        .ToX = 100
        .ToY = 100
    End With
End Sub

weiyingde

SchemeColor属性
返回或设置已经应用的配色方案中的颜色，该配色方案与指定对象相关。可读写。PpColorSchemeIndex 类型。
PpColorSchemeIndex 可以是下列 PpColorSchemeIndex 类型常数之一。
ppAccent1
ppAccent2
ppAccent3
ppBackground
ppFill
ppForeground
ppNotSchemeColor
ppSchemeColorMixed
ppShadow
ppTitle
expression.SchemeColor
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例切换当前演示文稿第一张幻灯片的两种背景色，一种是显式的红-绿-蓝值所定义的颜色，另一种是配色方案的背景色。
With ActivePresentation.Slides(1)
    .FollowMasterBackground = False
    With .Background.Fill.ForeColor
        If .Type = msoColorTypeScheme Then
            .RGB = RGB(0, 128, 128)
        Else
            .SchemeColor = ppBackground
        End If
    End With
End With

weiyingde

ScreenSize属性
返回或设置理想的最小屏幕尺寸（宽度乘高度，以像素为单位），在 Web 浏览器中查看保存的演示文稿时使用该屏幕尺寸。可读写。MsoScreenSize 类型。
MsoScreenSize 可以是下列 MsoScreenSize 类型常数之一。
msoScreenSize1024x768
msoScreenSize1152x882
msoScreenSize1152x900
msoScreenSize1280x1024
msoScreenSize1600x1200
msoScreenSize1800x1440
msoScreenSize1920x1200
msoScreenSize544x376
msoScreenSize640x480
msoScreenSize720x512
msoScreenSize800x600 默认值
expression.ScreenSize
expression  必选。该表达式返回“应用于”列表中的对象之一。
VBA示例
本示例将目标屏幕大小设置为 640x480 像素。
Presentations(2).WebOptions.ScreenSize = _
    msoScreenSize640x480
ScreenTip属性
返回或设置超链接的屏幕提示文字。可读写。String 类型。
说明
将演示文稿保存为 HTML、在 Web 浏览器中查看 Web 演示文稿以及将鼠标指针停留在超链接之上时，会显示屏幕提示文字。有些浏览器可能不支持屏幕提示。
VBA示例
本示例为第一个超链接设置屏幕提示文字。
ActivePresentation.Slides(1).Hyperlinks(1) _
    .ScreenTip = "Go to the Microsoft home page"

weiyingde

Script属性
返回一个代表 Microsoft PowerPoint 幻灯片上一段脚本代码的 Script对象。在 PowerPoint 中，脚本与某个标记形状相关联。如果指定形状没有相关联的脚本，则不会返回任何值。只读。
说明
幻灯片中插入的脚本代码只能在 Web 演示文稿中运行。
默认情况下，脚本标记形状不可见。若要使其可见，请使用 PowerPoint 用户界面。不能通过 Visual Basic 代码使脚本标记形状可见。
可以使用某范围的形状 (ShapeRange.Script) 上的 Script属性，而不是指定单个的标记形状。但是，如果该范围包含多个形状，则代码不能执行，并返回表示 Script属性不可访问的消息。
VBA示例
本示例将脚本标记（第一张幻灯片上的第八个形状）的脚本语言设置为 Microsoft Visual Basic Scripting Edition (VBScript)。
With ActivePresentation.Slides(1).Shapes(8)
    .Script.Language = msoScriptLanguageVisualBasic
End With
Scripts属性
返回一个 Scripts集合，代表演示文稿中的所有 Script对象（脚本代码块）。只读。
说明
Script对象所代表的脚本代码只能在 Web 演示文稿中运行。
SegmentType属性
返回一个值，该值表示与指定结点相关联的段是直还是曲。只读。MsoSegmentType 类型。
MsoSegmentType 可以是下列 MsoSegmentType 类型常数之一。
msoSegmentCurve 如果指定结点是某曲段的控制点，则 SegmentType属性返回该值。
msoSegmentLine
expression.SegmentType
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
该属性为只读。可使用SetSegmentType方法设置该属性的值。
VBA示例
本示例将myDocument 中第三个形状的所有直段更改为曲段。第三个形状必须是任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(3).Nodes
    n = 1
    While n <= .Count
        If .Item(n).SegmentType = msoSegmentLine Then
            .SetSegmentType n, msoSegmentCurve
        End If
        n = n + 1
    Wend
End With