HI，来吧，咱们一起来边练边学FREQUENCY！

看见星光

可以继续答题，海鲜老师的公式也是可以简的，还有另外的思路。

极地飞雪007

最近比较忙，错过上题了：
第十二题：
连胜次数：=MAX(FREQUENCY(ROW(1:16),IF(B210:Q210<>"胜了",COLUMN(A:P))))-1
积分1：=SUM(FREQUENCY(MATCH(B210:Q210,{"胜了","败了","平了"},),{1,2})*{3;0;1})
积分2：=SUM(COUNTIF(B210:Q210,{"胜了","平了"})*{3,1})
积分3：=SUM(FIND(LEFT(B210:Q210),"败平0胜")-1)
积分4：=SUM(CHOOSE(MATCH(B210:Q210,{"胜了","败了","平了"},),3,,1))

极地飞雪007

极地飞雪007 发表于 2014-10-24 15:35
最近比较忙，错过上题了：
第十二题：
连胜次数：=MAX(FREQUENCY(ROW(1:16),IF(B210:Q210"胜了",COLUMN(A ...

还是要给中国队全胜的机会：
机会1：=MAX(FREQUENCY(ROW(1:17),IF(B210:Q210<>"胜了",COLUMN(A:P))))-1
机会2：=MAX(FREQUENCY(ROW(1:16),IF(B210:R210<>"胜了",COLUMN(A:Q)-1)))
机会3：=MAX(FREQUENCY(ROW(1:16),IF(B210:Q210<>"胜了",COLUMN(A:P))))-OR(B210:Q210<>"胜了")

看见星光

更新第十三题：求连续奇偶数的个数。附件： frequency (13).rar (66.64 KB, 下载次数: 46)

2014-10-28 08:57 上传

点击文件名下载附件

13732120571

十三题
先来板砖试试，这次可别掉那个U里面了
1）偶

1. =TEXT(FREQUENCY(IF(MOD(B227:B235+1,2),ROW(1:9)),MOD(B228:B235,2)*ROW(2:9)),"0;;")

复制代码

多单元格数组公式

2）奇

1. =TEXT(FREQUENCY(IF(MOD(B227:B235,2),ROW(1:9)),MOD(B228:B235+1,2)*ROW(2:9)),"0;;")

复制代码

多单元格数组公式

cmxxccxx

13题凑个热闹：

1. =INDEX(TEXT(FREQUENCY(ROW($1:$10),MOD($B$227:$B$235+COLUMN(B1),2)*ROW($1:$9))-1,"0;;"),ROW(A2)),

复制代码

下拉右拉

看见星光

13732120571 发表于 2014-10-28 09:39
**** 该帖被屏蔽 ****

先蔽一下，哈哈，看别人怎么出招。

13732120571

看见星光 发表于 2014-10-28 09:42
先蔽一下，哈哈，看别人怎么出招。

大人~~
冤枉啊~~
我英俊的头像也屏蔽了~~

*****************************
看见星光  高手太多，题才出，就被灭了。。。。  [color=rgb(153, 153, 153) !important]发表于 2014-10-28 11:25
有竞赛答题那种
设置本人可见
的功能

极地飞雪007

偶：在D227：D235输入数组公式：=INDEX(TEXT(FREQUENCY(ROW(1:10),IF(MOD(($B$227:$B$235+(COLUMN(B227:B235)=3)),2)+($B$227:$B$235=""),ROW(1:9),0))-1,"0;;;"),ROW(2:10))
奇：D227：D235右拉，即可得奇数结果
就是公式长了点，但适合空格情况。

极地飞雪007

cmxxccxx 发表于 2014-10-28 09:41
13题凑个热闹：下拉右拉

出现空格，此法会有些问题