数据按指定品名进行合并

tmplinshi

Excel 365 可用

1. =LET(
   
2.     src, A2:B26,
   
3.     cat, H1:J11,
   
4.     a, SCAN(, INDEX(src, , 1), LAMBDA(x, y, IF(y = "", x, y))),
   
5.     b, INDEX(src, , 2),
   
6.     arr, IF(SEQUENCE(ROWS(a)) = MATCH(a & b, a & b, 0), b, ""),
   
7.     DROP(REDUCE("", arr, LAMBDA(out, x,
   
8.         IF(x = "", VSTACK(out, x), LET(
   
9.             x, TEXTBEFORE(x, "、",,,, x),
   
10.             i, MAX(IF(cat = x, SEQUENCE(, COLUMNS(cat)))),
    
11.             c, INDEX(cat, 1, i),
    
12.             py, SWITCH(c, "水果", "SG", "办公", "BG", "五金", "WJ"),
    
13.             n, COUNT(SEARCH(c & "*", out)) * 2^(py = "WJ") + 1,
    
14.             VSTACK(out, IF(i, c & py & n & IF(py = "WJ", "~" & py & n + 1, ""), ""))
    
15.         ))
    
16.     )), 1)
    
17. )

复制代码

tpb123

tmplinshi 发表于 2024-3-17 08:53
Excel 365 可用

666，太猛了，前面一个非365的？最新wps？

tpb123

tmplinshi 发表于 2024-3-17 08:53
Excel 365 可用

大神  这个要怎么处理呢？A2为原始文本，A6为检测的文本，A9:C9为存放结果的列，这题用递归公式lambda怎么写，不用名称管理器？不用reduce和scan函数

tmplinshi

1. =LET(
   
2.     srcText, A2,
   
3.     findText, A6,
   
4. 
   
5.     loop, LAMBDA(fn, [i], [outStr], [outTimes], [outPos],
   
6.         LET(
   
7.             i, i + 1,
   
8.             keyword, MID(findText, i, 1),
   
9.             foundPos, IFERROR(FIND(keyword, srcText), 0),
   
10. 
    
11.             outStr, outStr & IF(foundPos, keyword, ""),
    
12.             outTimes, outTimes + (i > 1),
    
13.             outPos, outPos & IF(foundPos, "#" & foundPos, ""),
    
14. 
    
15.             IF(
    
16.                 i < LEN(findText),
    
17.                 fn(fn, i, outStr, outTimes, outPos),
    
18.                 HSTACK(outStr, outTimes, outPos)
    
19.             )
    
20.         )
    
21.     ),
    
22.    
    
23.     loop(loop)
    
24. )

复制代码

检测的文本“&#8203;我吃完饭了”前面有一个不可见的字符（编码63），所以是6个字符，递归5次。

tpb123

牛逼牛逼，大师神乎其技，能否把小弟给收了

姜徐

谢谢大佬，学习学习