如何在邮件中插入附件资讯

vane42

在网上找到如下VBA码可在邮件内文插入附件资讯，可是插入点却是在邮件尾，如何修改可以将资讯于游标停留点插入？谢谢！
[code=vb]Option Explicit
Sub Names()

Dim Atmt As attachment
Dim Mensaje As Outlook.MailItem
Dim Adjuntos As String
Dim Body As String
Dim i As Integer

Set Mensaje = Application.ActiveInspector.currentItem
Mensaje.BodyFormat = olFormatHTML

Body = Mensaje.HTMLBody

i = 0
Adjuntos = ""

For Each Atmt In Mensaje.Attachments
    'If Atmt.Size > 5 Then
    Adjuntos = Adjuntos & "** Attached file: <u>" & Atmt.FileName & "</u><br>"
    i = i + 1
    'End If
Next Atmt

Adjuntos = "<font face='calibri'><u><b>Total number of attached files: " & i & "</u></b><br>" & Adjuntos & "</font>"

Mensaje.HTMLBody = Left(Body, InStr(Body, "</body>") - 1) & Adjuntos & Right(Body, Len(Body) - InStr(Body, "</body>") + 1)

Set Mensaje = Nothing

End Sub
[/code]

vane42

你说的这个方式我有想过，可我希望能自订字型颜色等，所以要嘛将格式化的内容先复制至剪贴板再贴上，要嘛直接将内容插入游标点（这得修改第27行的码）。
可惜VBA我不会撰写，只能到网上找范本，所以上述问题还望高手指导。谢谢！

dsd999

你可以先把增加的内容放到剪贴板中，然后粘贴。

dsd999

http://www.dimastr.com/redemption/safeinspector.htm

用第三方的库吧。

vane42

虽然没用到你提供的资料，还是谢谢你的回复。已自行改写达到需求。

dsd999

vane42 发表于 2013-4-3 15:37
虽然没用到你提供的资料，还是谢谢你的回复。已自行改写达到需求。

希望能分享出来。

vane42

dsd999 发表于 2013-4-9 14:06
希望能分享出来。

OK!
[code=vb]'须设定引用项目[Microsoft Word 14.0 Object Library]
Option Explicit
Sub InsrtAttachmentsInfo()
    Dim Atmt As attachment
    Dim Mensaje As Outlook.MailItem
    Dim Adjuntos As String
    Dim i As Integer
    Dim objOL As Outlook.Application
    Dim objDoc As Word.Document
    Dim objSel As Word.Selection

    Set Mensaje = Application.ActiveInspector.currentItem
    i = 0
    Adjuntos = ""

    For Each Atmt In Mensaje.Attachments
        Adjuntos = Adjuntos & "** Attached file: " & Atmt.FileName & vbCrLf
        i = i + 1
    Next Atmt

    Set objOL = Application
    Set objDoc = objOL.ActiveInspector.WordEditor
    Set objSel = objDoc.Windows(1).Selection
    With objSel
        .collapse wdCollapseStart
        .InsertAfter "Total number of attached files: " & vbCrLf & Adjuntos
        .Font.Name = "Calibri"
        .Font.Size = "12"
        .Font.Bold = True
        .Font.Color = wdColorGreen
    End With
    Set Mensaje = Nothing
End Sub
[/code]



补充内容 (2013-5-28 17:09):
第26行程式码修正为：
.InsertAfter "Total number of attached files: " & i & vbCrLf & Adjuntos