[开_27] 条件求和问题[已总结] ★★

wangtx218

一般公式:

J13=SUMIF(型号,"*"&J$12&"*",套数)

hWE0k0T7.rar (4.81 KB, 下载次数: 124)

2005-5-25 19:26 上传

点击文件名下载附件
[函数18] 测试题：条件求和问题 ★★

型号的名称定义=OFFSET(问题!$B$3,XX1+1,,XX2)可简化为=OFFSET(问题!$B$3,XX1+1,)就行了，sumif的第三个参数只要对应区域的第一个单元格就行了。

不用名称来还原一下你的公式

=SUMIF(OFFSET($B$3,COUNTIF($C$4:$C$100,"<="&$F13-DAY($F13))+1,,COUNTIF($C$4:$C$100,"<="&$F13)-COUNTIF($C$4:$C$100,"<="&$F13-DAY($F13))),"*"&J$12&"*",OFFSET($D$3,COUNTIF($C$4:$C$100,"<="&$F13-DAY($F13))+1,))

——apolloh

[此贴子已经被apolloh于2005-6-1 16:15:29编辑过]

apolloh

以下是引用wangtx218在2005-5-25 19:24:00的发言：

一般公式:

J13=SUMIF(型号,"*"&J$12&"*",套数)

思路靠近了！提示：用什么函数可以快速定位每个期间的数据记录段（首尾位置），而不用所有的数据参与多重的数组运算呢？

wangtx218

已用offset定位了,没有数据参与多重的数组运算![em06]

想不出

jjxcYwRH.rar (5.65 KB, 下载次数: 91)

2005-5-25 21:13 上传

点击文件名下载附件

因为你用countif这个函数，就是调用所有数据参与计算了，match则不会。前者要对照完区域中每个单元格，才出结果，因为其统计区域内的指定条件单元格的个数。后者是找到第一满足条件的单元格就停止了，所以比较快。如何避免match的第一行值找不到出错，请参见wutong9988在26楼的解法。——apolloh

[此贴子已经被apolloh于2005-6-1 17:07:33编辑过]

gdliyy

这个问题除了考虑计算公式以外（其实我在揣摩投一颗星的朋友的想法，只是单纯解题？），我们还应该着重考虑效率问题，因为象此类问题在工作中很容易遇到的！

另外：不用任何辅助列或单元格（因为工作中你可能没有这么多时间来设计辅助列），使用普通公式也是很容易解决的，我们不要忘记了楼主给我们提供了这么多的条件，关键是看大家的解题思路了！

[此贴子已经被作者于2005-5-25 23:50:24编辑过]

梧桐

按apolloh要求再改一下,投票四颗星!!支持阿波罗!!!

=SUMIF(OFFSET($B$3,start,,end-start+1,),"=*"&G$12&"*",OFFSET($D$3,start,,end-start+1,))

start=IF(ISERROR(MATCH(sheet1!$F12,日期)),1,MATCH(sheet1!$F12,日期)+1)

end=MATCH(sheet1!$F13,日期)

93oWF6Hp.rar (5.84 KB, 下载次数: 93)

2005-5-26 11:08 上传

点击文件名下载附件

公式可以简化一下

start=IF(ISNUMBER(MATCH($F12,日期)),MATCH($F12,日期))+1

end=MATCH($F13,日期)

=SUMIF(OFFSET($B$3,start,,end-start+1,),"=*"&G$12&"*",OFFSET($D$3,start,))

[此贴子已经被apolloh于2005-6-1 17:16:58编辑过]

wwwquan

用数组做到的^_^

结果正确。6楼 huangws 朋友的思路和你的基本一致的，但你是用if多层判断，huangws的是用*来表示逻辑与的关系

照你的思路，可简化为

=SUM(IF(ISNUMBER(FIND(G$12,型号)),IF(YEAR(日期)=YEAR($F13),IF(MONTH(日期)=MONTH($F13),套数))))

：）——apolloh

[此贴子已经被apolloh于2005-6-1 17:28:39编辑过]

wangtx218

H13=SUMIF(OFFSET($B$4,COUNTIF($C$4:$C$100,"<="&$G13-DAY($G13)),,MATCH($G13,$C$4:$C$100)-COUNTIF($C$4:$C$100,"<="&$G13-DAY($G13))),"*"&H$12&"*",OFFSET($D$4,COUNTIF($C$4:$C$100,"<="&$G13-DAY($G13)),))

H13=SUMIF(OFFSET($B$3,MATCH($G13-DAY($G13),$C$3:$C$100),,MATCH($G13,$C$3:$C$100)-MATCH($G13-DAY($G13),$C$3:$C$100)),"*"&H$12&"*",OFFSET($D$3,MATCH($G13-DAY($G13),$C$3:$C$100),))

pOGwMEF5.rar (5.25 KB, 下载次数: 93)

2005-5-26 14:40 上传

点击文件名下载附件

水平低，好好向大师学习！！！

第一个解法用countif虽然避免了match找不到第一日期的错误，但速度较慢。

第二个解法，很好，巧妙的运用了c3的自定义格式，实际存储了一个较小的日期值（这里可以用０），来避免match找不到第一日期的错误，比较完美！

[此贴子已经被apolloh于2005-6-3 17:35:38编辑过]

gdliyy

以下是引用wangtx218在2005-5-26 12:29:00的发言： H13=SUMIF(OFFSET($B$4,COUNTIF($C$4:$C$100,"<="&$G13-DAY($G13)),,MATCH($G13,$C$4:$C$100)-COUNTIF($C$4:$C$100,"<="&$G13-DAY($G13))),"*"&H$12&"*",OFFSET($D$4,COUNTIF($C$4:$C$100,"<="&$G13-DAY($G13)),))

这么复杂，还用了3个Countif()，如果有10000行数据，那不慢死？你还选择两颗星？

一点提示：其实只用一个Countif()就可以了。

[此贴子已经被作者于2005-5-26 13:35:31编辑过]

zwy

凑个热闹！

G13=SUMPRODUCT(NOT(ISERROR(FIND(G$12,型号)))*(TEXT(日期,"yy-mm")=TEXT($F13,"yy-mm")),套数)

S7PDMRn7.rar (4.28 KB, 下载次数: 93)

2005-5-26 14:22 上传

点击文件名下载附件
[函数18] 测试题：条件求和问题 ★★

和13楼的第一解法基本相同——apolloh

[此贴子已经被apolloh于2005-6-3 17:38:33编辑过]

zlj1101

呵呵，我只是新手看不懂的