VB中不是控件数据,多个文本框设置,代码简化

nmcfbgttyl · 发表于 2013-1-7 22:03

Private Sub Text1_Change()
If Not IsNumeric(Text1.Text) Then Text1.Text = ""
End Sub

Private Sub Text2_Change()
If Not IsNumeric(Text2.Text) Then Text2.Text = ""
End Sub

Private Sub Text3_Change()
If Not IsNumeric(Text3.Text) Then Text3.Text = ""
End Sub

Private Sub Text4_Change()
If Not IsNumeric(Text4.Text) Then Text4.Text = ""
End Sub

Private Sub Text5_Change()
If Not IsNumeric(Text5.Text) Then Text5.Text = ""
End Sub
....
120个文本框,怎样简化代码
是VB
各位老师请指点

zhaogang1960 · 发表于 2013-1-7 23:18

本帖最后由 zhaogang1960 于 2013-1-7 23:27 编辑

短信收到，如果是VBA，可以使用类模块实现，如果是VB6，可以使用控件组
Private Sub Text1_Change(Index As Integer)
If Not IsNumeric(Text1.Item(Index).Text) Then Text1.Item(Index).Text = ""
End Sub

改进：
Private Sub Text1_Change(Index As Integer)
With CreateObject("vbscript.regexp")
      .Global = True
      .Pattern = "[^0-9.]+"
      If .test(Text1.Item(Index).Text) Then
         Text1.Item(Index).Text = .Replace(Text1.Item(Index).Text, "")
      End If
End With
End Sub

zhaogang1960 · 发表于 2013-1-7 23:21

VBA类模块clsTxt：

Public WithEvents Txtbox As MSForms.TextBox
Private Sub Txtbox_Change()
With CreateObject("vbscript.regexp")
.Global = True
.Pattern = "[^0-9.]+"
If .test(Txtbox.Text) Then
Txtbox.Text = .Replace(Txtbox.Text, "")
End If
End With
End Sub

复制代码

zhaogang1960 · 发表于 2013-1-7 23:24

你原来的是把整个Text=""，现在这个是仅删除刚刚输入的非数字字符
请看下面附件

限制多个TEXTBOX输入数字.rar (12.04 KB, 下载次数: 146)

nmcfbgttyl · 发表于 2013-1-8 19:35

谢谢赵老师，回复晚了，请谅解，因为今天有事，一天没开电脑。
VBA的代码正是我要实现的效果，可是我想在VB6里设置，且只能输入一个小数点，不能是多个小数点（如　1.2.3.4），我怎么也没弄成，请您再给改一下，谢谢老师！

求助.rar (1.59 KB, 下载次数: 15)

nmcfbgttyl · 发表于 2013-1-8 19:37

zhaogang1960 发表于 2013-1-7 23:18
短信收到，如果是VBA，可以使用类模块实现，如果是VB6，可以使用控件组
Private Sub Text1_Change(Index A ...

谢谢赵老师，可是还是有点问题，您再帮忙看一下。

zhaogang1960 · 发表于 2013-1-8 21:34

nmcfbgttyl 发表于 2013-1-8 19:35
谢谢赵老师，回复晚了，请谅解，因为今天有事，一天没开电脑。
VBA的代码正是我要实现的效果，可是我想在V ...

你把哑巴逼得说了话，如果合乎要求，要多多加鲜花啊！
类模块clsTxt：

Public WithEvents Txtbox As TextBox
Private Sub Txtbox_Change()
Dim s As String, t As String, a, i As Integer
s = Txtbox.Text
If InStr(s, ".") Then
If Left(s, 1) = "." Then
Txtbox.Text = Mid(s, 2)
Else
a = Split(s, ".")
If UBound(a) > 1 Then
t = a(0) & "."
For i = 1 To UBound(a)
t = t & a(i)
Next
Txtbox.Text = t
End If
End If
End If
With CreateObject("vbscript.regexp")
.Global = True
.Pattern = "[^0-9.]+"
If .test(s) Then
Txtbox.Text = .Replace(s, "")
End If
End With
Txtbox.SelStart = Len(s)
End Sub

复制代码

zhaogang1960 · 发表于 2013-1-8 21:35

窗体：

Dim Txt() As New clsTxt
Private Sub Form_Load()
Dim ctl As Control, m As Integer
For Each ctl In Me.Controls
If TypeName(ctl) = "TextBox" Then
m = m + 1
ReDim Preserve Txt(1 To m)
Set Txt(m).Txtbox = ctl
End If
Next
End Sub

复制代码

zhaogang1960 · 发表于 2013-1-8 21:37

请看附件

求助.rar (2.43 KB, 下载次数: 120)

nmcfbgttyl · 发表于 2013-1-9 18:57

zhaogang1960 发表于 2013-1-8 21:37
请看附件

完全符合我的想法，谢谢赵老师！
只所以这么晚才回复，是因为前段时间出了车祸，白天在法院打官司了，已经有几天了，所以才这么晚来回复！
打官司比写代码难多了！！！！！！1

		自动登录	找回密码
密码			免费注册

[求助] VB中不是控件数据,多个文本框设置,代码简化

评分