请问,为什么我写 a=7008*12 系统会提示溢出? 那我该如何来写?

ladapt

请问,为什么我写  


sub abc()
a=7008*12
end sub

系统会提示溢出?  那我该如何来写?

香川群子

溢出（错误 6）


当赋值超出目标的限制时，就会发生溢出。此错误有以下的原因和解决方法：

赋值、计算或数据类型的结果的转换太大，以致于不能在变量类型所允许的范围内表示出来。
赋值给足够表示值的范围的类型的变量上。

给属性的赋值超过属性能接受的最大值。
确保赋值适合属性的范围。

试图在计算中使用一个数字，并且该数字被强制为一个整数，但是结果超过了整数的范围，例如：
    Dim x As Long
    x = 2000 * 365   ' 错误: 溢出
要解决这个问题，请按如下方式键入该数字：

    Dim x As Long
    x = CLng(2000) * 365
详细信息，可选取有问题的项目，并按下 F1 （在Windows中）或HELP（在Macintosh中）键。

香川群子

举例，下面代码不会产生溢出错误：

Sub test1()
    c = CLng(7008) * 12 '直接用CLng()函数把7008转换为长整数类型数据，然后计算结果a也会是长整型
End Sub

Sub test2()
    a = 7008# * 12 '直接用#符号把7008转换为双精度类型数据，然后计算结果a也是双精度数值。
End Sub

Sub test3()
    t1 = 7008 '把7008存入变量，由VBA自动判断数据类型为整型数据。
    a = t1 * 12  '然后计算结果a会自定转换为长整型数据。
End Sub

呵呵。

接下来，关于数据类型，还有：
Sub test4()
    Dim t1 '定义变量为任意可变类型
    t1 = 7008 'VBA自动把t1变量认识为整型
    a = t1 * 12 'VBA自动把计算结果转为长整型
End Sub

Sub test5()
    Dim t1% '直接定义t1为整型时
    t1 = 7008
    a = t1 * 12 '计算结果超过整型值最大范围，于是产生溢出错误→这个实际上就是楼主顶楼溢出问题的原因。
End Sub

Sub test6()
    Dim t1& '直接定义t1为长整型时
    t1 = 7008
    a = t1 * 12 '计算结果也是长整型
End Sub

Sub test7()
    Dim t1! '直接定义t1为单精度数值
    t1 = 7008
    a = t1 * 12 '计算结果也是单精度的。
End Sub

Sub test8()
    Dim t1# '直接定义t1为双精度数值
    t1 = 7008
    a = t1 * 12 '计算结果也是双精度的。
End Sub


这样楼主应该明白了吧。

ladapt

谢谢楼上大哥,真的是太详细了,原来直接算数字就相当于是 整型阿，这个问题让我加深了数据类型的印象，谢谢 侠圣-香川群子 。