如何进行数据拆分放入到Excel的工作簿中

homewin

老师们好，我想把文件中的数据（test）读入到result的几个工作表中的A列，如何用VBA来实现；                                                                                
PS:因为数据的行数超过每个工作表的行数，所有要读入到几个工作表中（工作表的数目要根据数据大小来确定）                                                                                
最后，谢谢老师们的帮忙！        

蓝桥玄霜

1. Sub lqxs()
   
2.     Dim a() As String, b() As String, i&, m&, r&, Arr(), rr&
   
3.     Open ThisWorkbook.Path & "\test" For Input As #1
   
4.     a = Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbCrLf)
   
5.     Do
   
6.         m = m + 1
   
7.         ReDim Preserve Arr(1 To m)
   
8.         Arr(m) = a(i)
   
9.         i = i + 1
   
10.         If m = 65000 Then
    
11.             rr = rr + 1
    
12.             Sheets(rr).[a1].Resize(m, 1) = Application.Transpose(Arr)
    
13.             m = 0
    
14.         End If
    
15.     Loop While i < UBound(a)
    
16.     If m > 0 Then
    
17.         rr = rr + 1
    
18.         Sheets(rr).[a1].Resize(m, 1) = Application.Transpose(Arr)
    
19.         m = 0
    
20.     End If
    
21.     Close #1
    
22. End Sub
    

复制代码

yangyangzhifeng

1. Sub RowCnt()
   
2.     Dim Arr, k&, x&, i&
   
3.     ReDim br(1 To 65536, 1 To 1)
   
4.     Application.ScreenUpdating = False
   
5.     Open ThisWorkbook.Path & "\test" For Input As #1
   
6.     Arr = Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbCrLf)
   
7.     Close #1
   
8.     k = UBound(Arr)
   
9.     x = k \ 65536 + 1
   
10.     Do Until Sheets.Count >= x
    
11.         Sheets.Add
    
12.     Loop
    
13.     x = 0
    
14.     For i = 1 To k + 1
    
15.         x = x + 1
    
16.         br(x, 1) = Arr(i - 1)
    
17.         If x = 65536 Then
    
18.             x = 0
    
19.             Sheets(i \ 65536).Range("a1").Resize(65536) = br
    
20.         End If
    
21.     Next
    
22.     If x > 0 Then
    
23.         Sheets(i \ 65536 + 1).Range("a:a").ClearContents
    
24.         Sheets(i \ 65536 + 1).Range("a1").Resize(x) = br
    
25.     End If
    
26.     Application.ScreenUpdating = True
    
27. End Sub
    

复制代码

蓝桥玄霜

请见附件。

homewin

蓝桥玄霜 发表于 2012-8-30 16:12
请见附件。

蓝版可以解释一下么，不是很明白，例如：
（1）Dim a() As String, b() As String, i&, m&, r&, Arr(), rr&中的变量分别有什么作用，由于水平有限，我看得有点乱；
（2）这句：Arr = Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbCrLf)用来干什么的？
（3）还有，ReDim Preserve Arr(1 To m)有什么作用？
盼解析，多谢多谢！

蓝桥玄霜

（1）Dim a() As String, b() As String, i&, m&, r&, Arr(), rr&
声明变量
a() As String   字符串数据类型的数组变量
m&     长整数数据类型变量     相当于m As Long
（3）还有，ReDim Preserve Arr(1 To m)
声明动态数组变量，随着m的增加，前面声明的数组值仍然保留
（2）这句：Arr = Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbCrLf)
LOF(1)    LOF函数，括号中的1表示文件号#1     #1文件的末尾
InputB(LOF(1), 1)  InputB函数   返回#1文本文件所有的字节
StrConv(InputB(LOF(1), 1), vbUnicode)   StrConv函数返回按Unicode格式的字符串
Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbCrLf)   Split函数把以上的字符串按照回车换行符分离，形成一个一维数组
整句是把以上的一维数组赋给变量Arr

以上解释对于没有基础的可能没什么用处吧。

homewin

蓝桥玄霜 发表于 2012-8-30 19:25
（1）Dim a() As String, b() As String, i&, m&, r&, Arr(), rr&
声明变量
a() As String   字符串数据类 ...

谢谢篮版的耐心解析，的确明白了许多。

homewin

蓝版你好，不好意思，我还有一个问题要问，求指点：
If m = 65000 Then......Loop While i < UBound(a)和If m > 0 Then.....的分别要达到什么目的？
谢谢！

蓝桥玄霜

If m = 65000 Then......Loop While i < UBound(a)
前者是为了不超过一列的总行数而作的判断，如果m达到65000，即给单元格赋值，同时m复原=0，rr+1
使下一个工作表可继续赋值
后者是Do   Loop循环，当i<Ubound(a)的时候执行循环。

wsk0722

蓝桥玄霜 发表于 2012-8-31 11:05
If m = 65000 Then......Loop While i < UBound(a)
前者是为了不超过一列的总行数而作的判断，如果m达到65 ...

寻找蓝版的足迹中