如何自动打开“欢迎屏幕”

heike2004

在access中有一个著名的“罗斯文示例数据库”，每次打开罗斯文数据库，都是首先自动打开“启动屏幕”，这一设计非常人性化。
小弟照猫画虎制作了一个员工管理数据库，也想仿照罗斯文数据库的样子制作一个自动打开的“欢迎屏幕”，但不知罗斯文数据库的启动屏幕是如何制作的，如何才能实现每次打开数据库首先自动打开“欢迎屏幕”。
请高手不吝赐教，谢谢

好像是自定义菜单如何如何，想不起来了。。。。。

咱家是猫

在罗斯文的"欢迎界面"窗体里有一个"下次不再显示"复选框,如果勾选了,下次启动就不会再显示.其实原理很简单,注意看在此窗体的关闭事件触发了一个过程

Function HideStartupForm()
On Error GoTo HideStartupForm_Err
' 使用"隐藏启动窗体"检查框的值决定数据库的 StartupForm 属性的设置。
' （设置情况在启动对话框上的显示窗体框中显示）。
' 用于“启动”窗体的 OnClose 属性。
        If Forms!启动!隐藏启动窗体 Then
        ' "隐藏启动窗体"检查框已标记，所以设置 StartupForm 属性为＂主切换面板＂
            CurrentDb().Properties("StartupForm") = "主切换面板"
        Else
            ' "隐藏启动窗体"检查框被清除，所以设置 StartupForm 属性为“启动”。
            CurrentDb().Properties("StartupForm") = "启动"
        End If
   
        Exit Function
        
HideStartupForm_Err:
    Const conPropertyNotFound = 3270
    If Err = conPropertyNotFound Then
        Dim db As DAO.Database
        Dim prop As DAO.Property
        Set db = CurrentDb()
        Set prop = db.CreateProperty("StartupForm", dbText, "启动")
        db.Properties.Append prop
        Resume Next
    End If
   
End Function

在这个过程中,判断是否勾选了那个复选框,如果勾选了,就会更换"启动对话框"里的那个"显示窗体/页"属性.就会换成"主切换面板",这里的代码是采用了更改CurrentDB的Properties,在HideStartupForm_Err标签中,意图是如果更改此启动属性失败的话(如果未设置过此属性,那此属性就不存在,当设置过后.它就会存在),就自动为程序库添加此属性.

heike2004

谢谢，学习了

qangsheng

选择下次启动窗体，记下了。