表格处理（宏）

413191246se

[code=vb]Sub 表格处理()
' 若光标在表格内则处理光标所在表格；否则将处理所有表格(仅限规则表格！)
    On Error Resume Next
    Dim i As Long
    i = ActiveDocument.Tables.Count
    If i = 0 Then MsgBox "当前文档无表格！", vbOKOnly + vbCritical, "表格处理": Exit Sub
    Dim a As Long, b As Long, c As String, h As String, s As String, t As Table, n As Long
    c = MsgBox("是：自动    否：自定义    取消：放弃", vbYesNoCancel + vbExclamation, "表格处理")
    If c = vbYes Then
        h = 0.9
        s = 12
        a = 1
        b = 1
    ElseIf c = vbNo Then
        h = InputBox("请输入表格行高值：(0.7-1.2 厘米比较美观)", "表格处理", "0.9")
        If h = "" Then Exit Sub
        s = InputBox("请输入表格内文字字号：(比正文小半号比较美观)" & vbCr & "三号/16磅，小三/15磅，四号/14磅，小四/12磅，五号/10.5磅", "表格处理", "12")
        If s = "" Then Exit Sub
        If MsgBox("根据内容调整表格吗？", vbYesNo + vbExclamation, "自动调整") = vbYes Then a = 1
        If MsgBox("所有表格表头加粗吗？", vbYesNo + vbExclamation, "表头加粗") = vbYes Then b = 1
    Else
        Exit Sub
    End If
    If Selection.Information(wdWithInTable) = True Then Selection.Tables(1).Select: n = 1
    For Each t In ActiveDocument.Tables
        If n = 1 Then Set t = Selection.Tables(1) Else t.Select
        t.Range.Font.Color = wdColorBlue
' 表格标准化
        With t
            With .Rows
                .WrapAroundText = False
                .Alignment = wdAlignRowLeft
                .HeightRule = wdRowHeightAtLeast
                .Height = CentimetersToPoints(h)
            End With
            .AutoFitBehavior (wdAutoFitWindow)
            .AutoFitBehavior (wdAutoFitWindow)
            With .Range
                With .Cells
                    .DistributeWidth
                    .VerticalAlignment = wdCellAlignVerticalCenter
                End With
                .Font.Size = s
                With .ParagraphFormat
                    .Alignment = wdAlignParagraphCenter
                    .CharacterUnitFirstLineIndent = 0
                    .FirstLineIndent = CentimetersToPoints(0)
                    .Space1
                End With
            End With
            .Shading.BackgroundPatternColor = wdColorAutomatic
' 根据内容调整表格
            If a = 1 Then
                .AutoFitBehavior (wdAutoFitContent)
                .AutoFitBehavior (wdAutoFitContent)
            End If
            .Select
            .AutoFitBehavior (wdAutoFitWindow)
            .AutoFitBehavior (wdAutoFitWindow)
' 表头加粗
            If b = 1 Then
                With .Rows(1).Range.Font
                    .Name = "黑体"
                    .Name = "Times New Roman"
                    .Bold = True
                    .Color = wdColorRed
                End With
            End If
        End With
    Next
    If n <> 1 Then Selection.MoveLeft Unit:=wdCharacter, Count:=1
End Sub[/code]

413191246se

顶以更新！

413191246se

顶以更新！

sqhsqhli

ActiveDocument.Range.Font.Color = vbRed

这是range对象的一个优点

不过我还真不太明白ActiveDocument.Range和ActiveDocument.content的区别在哪儿

413191246se

老弟，你这像 VB6 语言啊！我还是倾向于以“录制宏”后的 VBA 代码为准，再加上个人编辑，我用颜色都用 wdColorRed 这样的。只要效果一样，哪个都行啊。

守柔

sqhsqhli 发表于 2012-4-6 12:36
ActiveDocument.Range.Font.Color = vbRed

这是range对象的一个优点

这个问题很有意思。
仔细检查了一下对象浏览器中Document对象的Range，包含显示隐含成员，均未发现有Document对象的Range属性，只有Document对象的Range方法。相比如Selection对象，Paragraph对象，它们是有Range属性的。
鉴于此，Range方法作用于Document对象时，如果缺省Start参数，它值默认为0，如果缺少End参数，它的默认值为文档结束位置。
Sub Example()
    With ThisDocument
        .Range(End:=10).Select    ''''选中文档前10个字符
        '等同于
        .Range(Start:=0, End:=10).Select
        .Range(Start:=10).Select    ''''从选中第11个字符开始至文档结束区域
        ''''等同于
        .Range(Start:=10, End:=.Content.End).Select
    End With
End Sub
ActiveDocument.Range是方法，通过Range方法返回一个Range对象；ActiveDocument.content是属性，通过Content属性返回一个Range对象。两者意义不同，但都返回了Activedocument.StoryRanges(wdMainTextStory)这个Range对象，当然您也可以反向理解，都返回了Content属性所指向的Range.

东山客

{:soso_e100:}随喜……

sqhsqhli

好好想一想

413191246se

顶以更新！！！

konggs

守柔 发表于 2012-4-6 15:36
这个问题很有意思。
仔细检查了一下对象浏览器中Document对象的Range，包含显示隐含成员，均未发现有Doc ...

守兄说的对。
对于VB或者说VBA这种缺少参数，带来的方便性显而易见，大大的方便了我们。

我在学习其他语言时，发现这种缺省的参数，也有他的两面性：即太多的“不严谨”的特性，将导致结果的“不确定”性，必须靠经验来记忆变成了“必须”。
所以，有时候觉得，严谨的语法可能更有利于我们的学习。

不知老大同意否？