如果取第n大的数

donghan

学习一下frequency的用法

heiniu8952

frequency的妙用！受用

枫桥夜泊lwb

原帖由 gdliyy 于 2005-5-30 23:21 发表

谁说的：）Frequency()可以直接支持内部数组运算的。

原来是可以支持内部数组运算的,学习了

lyb200

FREQUENCY的理解深啦 。

ksaq116

frequency函数的灵活运用，又学习了

sscylh

frequency 真是个好函数
我的第一想法：=(LARGE(A1:A5*1000,COUNTIF(A1:A5,LARGE(A1:A5,1))+1))/1000
当年论坛 好似天天华山论剑，好不热闹，有点生不逢时之感，呵呵！

yuyuer

如果是查找 到的第几大的值有重复，如何能也能将重复的值也找到？？？

Wangai2212

jxksxx 发表于 2008-6-29 12:43
QUOTE:以下是引用apolloh在2005-1-25 19:28:00的发言：=LARGE(IF(FREQUENCY(A1:A5,A1:A5),A1:A5),2)老大： ...

提供一种理解方法。

先看FREQUENCY(A1:A5,A1:A5)。公式参数是两个数组，结果是一个数组。这里两个参数都是A1:A5。我们把它用表格写出来：

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1
2	2
2	2
5	5
5	5

首先找到参数2中最小的数字，也就是1。然后从参数1中，找出≤1的数字，并输出个数。结果是1个。

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1	1
2	2
2	2
5	5
5	5

然后我们把使用完的参数划掉，开始下一轮计算：

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1	1
2	2
2	2
5	5
5	5

现在开始第二轮计算：再从剩下参数2中，找到最小的数字。现在参数2中最小的数字是2，这里有两个2，那我们用上面。而参数1剩下的数字中，≤2的结果有两个，于是FREQUENCY输出2。

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1	1
2	2	2
2	2
5	5
5	5

再把用完的参数划掉。

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1	1
2	2	2
2	2
5	5
5	5

现在有意思的事情来了。参数2中剩下最小的数字是2，但是参数1剩下的数字中，还有没有≤2的数字呢？当然没有！所以公式就输出0：

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1	1
2	2	2
2	2	0
5	5
5	5

之后如法炮制，最终结果是：

参数1：数据数组	参数2：间隔点数组	{=FREQUENCY(A1:A5,A1:A5)}
1	1	1
2	2	2
2	2	0
5	5	2
5	5	0

这里提一下，FREQUENCY输出的数组要比参数2多一个结果。本例多出的那个结果永远是0，这里不做解释了。所以
{=FREQUENCY(A1:A5,A1:A5)}={1;2;0;2;0;0}

然后=IF(FREQUENCY(A1:A5,A1:A5),A1:A5)，也就是：
=IF({1;2;0;2;0;0},{1;2;2;5;5})

再写成表格：

参数1	参数2	=IF({1;2;0;2;0;0},{1;2;2;5;5})
1	1	1
2	2	2
0	2	FALSE
2	5	5
0	5	FALSE
0		FALSE

这里利用了=IF(X,Y)，若X<>0输出Y，X=0输入FALSE的特性。

也就有了
{=IF(FREQUENCY(A1:A5,A1:A5),A1:A5)}={1;2;FALSE;5;FALSE;FALSE}

最后用LARGE取第2大的数：
=LARGE(IF(FREQUENCY(A1:A5,A1:A5),A1:A5),2)
=LARGE({1;2;FALSE;5;FALSE;FALSE},2)
=2