用VB6.0制作Excel2010功能区COM加载项及自定义图标

henrylam

网上用VB6.0制作Excel2010功能区COM加载项的教程不少，而用VB6.0自定义图标的资料几乎没有，所以在这方面花了不少时间，以下将这两天的心得整理出来供大家一起学习讨论。Excel2007版的制作过程类似，Excel2003版的不适合。
由于本人水平有限，错漏之处难免，欢迎网友指教。

一、创建外接程序
打开VB6.0，在新建工程对话框中选择“外接程序”。然后在“项目资源管理器”窗口中，通过右键单击“Connect”打开设计器窗口，然后选择“查看对象”。按下图所示进行填写和选择。

在VB6.0菜单栏“工程”点击“引用”，按下图勾选

二、编写代码
在“项目”窗口中，右键单击“Connect”项并选择“查看代码”，删除在设计器代码窗口中自动生成的代码，将以下代码复制进去后保存。

1. 
   
2. Option Explicit
   
3. Implements IRibbonExtensibility '添加对 IRibbonExtensibility 接口的引用
   
4. Public xlApp As Excel.Application
   
5. 
   
6. Private Sub AddinInstance_OnConnection(ByVal Application As Object, ByVal ConnectMode As AddInDesignerObjects.ext_ConnectMode, ByVal AddInInst As Object, custom() As Variant)
   
7.     Set xlApp = Application '加载时
   
8. End Sub
   
9. 
   
10. Private Sub AddinInstance_OnDisconnection(ByVal RemoveMode As AddInDesignerObjects.ext_DisconnectMode, custom() As Variant)
    
11.     Set xlApp = Nothing '卸载时
    
12. End Sub
    
13. 
    
14. '调用自定义 XML
    
15. Public Function IRibbonExtensibility_GetCustomUI(ByVal RibbonID As String) As String
    
16.     IRibbonExtensibility_GetCustomUI = GetRibbonXML()
    
17. End Function
    
18. 
    
19. '添加 XML 自定义代码
    
20. Public Function GetRibbonXML() As String
    
21.     Dim sRibbonXML As String
    
22.     sRibbonXML = "<customUI xmlns=""http://schemas.microsoft.com/office/2006/01/customui"" >" & _
    
23.                   "<ribbon startFromScratch=""false"">" & _
    
24.                    "<tabs>" & _
    
25.                     "<tab id=""henrylam"" label=""我的工具"">" & _
    
26.                      "<group id=""test"" label=""测试"">" & _
    
27.                       "<button id=""Button1"" label=""测试内置图标"" size=""large"" imageMso=""HappyFace"" onAction=""test1"" />" & _
    
28.                       "<button id=""Button2"" label=""测试自定义图标"" size=""large"" getImage=""GetImage"" onAction=""test2"" />" & _
    
29.                      "</group >" & _
    
30.                      "<group id=""ExcelHome"" label=""ExcelHome"">" & _
    
31.                       "<button id=""Button3"" label=""访问论坛"" size=""large"" getImage=""GetImage"" onAction=""test3"" />" & _
    
32.                      "</group >" & _
    
33.                     "</tab>" & _
    
34.                    "</tabs>" & _
    
35.                   "</ribbon>" & _
    
36.                  "</customUI>"
    
37.     GetRibbonXML = sRibbonXML
    
38.    End Function
    
39.    
    
40. '下面是调用资源文件(.res)中资源的函数。
    
41. 'Button1用的是系统内置图标，无需调用。Button2和Button3用的是自定义图标
    
42. 
    
43. Function GetImage(control As IRibbonControl) As IPictureDisp
    
44.     Select Case control.Id
    
45.     Case "Button2"
    
46.         Set GetImage = LoadResPicture(101, vbResBitmap) '调用资源文件中的位图作为功能区的图标
    
47.     Case "Button3"
    
48.         Set GetImage = LoadResPicture(102, vbResBitmap)
    
49.     End Select
    
50. End Function
    
51. 
    
52. '下面是测试控件回调的3个过程，对应3个按钮
    
53. 
    
54. Public Sub test1(ByVal control As IRibbonControl)
    
55.     MsgBox "测试通过，按钮用的是内置图标", vbInformation
    
56. End Sub
    
57. 
    
58. Public Sub test2(ByVal control As IRibbonControl)
    
59.     MsgBox "测试通过，按钮用的是自定义图标", vbInformation
    
60. End Sub
    
61. 
    
62. Public Sub test3(ByVal control As IRibbonControl)
    
63.     If Not xlApp.ActiveWorkbook Is Nothing Then
    
64.        xlApp.ActiveWorkbook.FollowHyperlink Address:="http://club.excelhome.net/forum.php", NewWindow:=True
    
65.     Else
    
66.        MsgBox "没有活动工作簿", vbExclamation
    
67.     End If
    
68. End Sub
    

复制代码

henrylam

三、加载自定义图标到“资源文件”。本贴重点要说的。
用VBA编辑的加载宏，可以将.png格式的自定义图片加载到.xlam文件中，但VB6.0不支持.png格式的，只能用.bmp位图了。如果需要透明效果的图标，我们可以把做好的.png图片用画图工具打开，另存为24位位图即可。

做好图标后，在VB6.0菜单栏“外接程序”中，点击“外接程序管理器”，选择“VB 6 资源编辑器”，“加载行为”前两项勾上，然后点击“确定”。

到VB6.0菜单栏“工具”中，点击“资源编辑器”，点击“新建”按钮，再点击“位图”按钮，将自定义好的位图文件加载进来。

henrylam

四、生成DLL文件
单击VB6.0菜单栏“文件”，再点击“生成Excel2010.dll ”，即可生成COM加载项文件。
新建记事本文件，填入RegSvr32.exe Excel2010.dll，保存为安装.BAT文件，关闭Excel程序，打开安装.BAT文件再打开Excel程序就可以了。效果如下：


生成的DLL文件 Excel2010dll.rar (19.16 KB, 下载次数: 1390)

2011-11-17 20:32 上传

点击文件名下载附件

自义定图标 自定义图标.rar (12.18 KB, 下载次数: 1462)

2011-11-17 20:33 上传

点击文件名下载附件

VB工程文件 Excel2010.rar (48.56 KB, 下载次数: 1967)

2011-11-17 20:33 上传

点击文件名下载附件

本贴参考了三戒的http://club.excelhome.net/thread-424834-1-1.html
及佛山小老鼠的http://club.excelhome.net/thread-729624-1-1.html
感谢！！






补充内容 (2016-3-15 17:19):
第10页91楼补充更新，解决在“Connect”项编写XML代码太多行时受“行继续标志”限制问题。
PS:因为VB6.0编写的插件支持不了64位Office，楼主已从VB6.0转VSTO，此贴也几年没留意，今天上论坛翻出来，手痒完善下。

Moneky

楼主VB能手。谢谢分享，收藏备用。

风云际会6

谢谢分享，收藏备用

najagay

很好，谢谢分享

tonychris

03的也是大同小异，不过不需要xml文件。

henrylam

tonychris 发表于 2011-11-18 19:15
03的也是大同小异，不过不需要xml文件。

03菜单与10功能区不一样，但自定义图标也是类似

mobuli

总结的很好

Kelidai

很好的学习资料，适合美化自己的小系统。