Word 2003 中怎么用 VBA 清空剪贴板内容？

413191246se

因为有时复制不少内容，觉得影响内存运作，喜欢清空剪贴板，我平时是用外部的看图程序 iview 来清空的，麻烦，请高人指教！3Q！

wudixin96

1. Dim objData As New DataObject
   
2. objData.SetText ""
   
3. objData.PutInClipboard

复制代码

wudixin96

Dim objData As New DataObject

之前请先引用 Microsoft  Forms 2.0 Object Library

guojianlin1985

留个记号，回头试试这招。

413191246se

    经过试验，发现似乎清除了剪贴板，已经无法再粘贴，但剪贴板及外部的 iview 小看图程序的剪贴板并未显示灰色。我又看了 VBA 帮助，说 ObjectData 和 剪贴板 是两条路，我还是喜欢操作系统共用的这个剪贴板，就是清空后，在别的程序里面剪贴板也看着已经是灰色不可粘贴这种状态，因为 iview 报错，所以，我不想采用这种方法，想找到通用的清除剪贴板的方法，但是还是非常谢谢 wudixin96，3Q！

chuhaiou

ppt用它不起作用

wudixin96

1. Private Declare Function OpenClipboard Lib "user32" (ByVal Hwnd As Long) As Long
   
2. Private Declare Function CloseClipboard Lib "user32" () As Long
   
3. Private Declare Function EmptyClipboard Lib "user32" () As Long
   
4. Sub EraseClipboard()
   
5.     If (OpenClipboard(0&)) Then
   
6.         Call EmptyClipboard
   
7.         Call CloseClipboard
   
8.     End If
   
9. End Sub

复制代码

再试下这个行不？

413191246se

谢谢！仍然报错。

wudixin96

413191246se 发表于 2011-9-25 10:20
谢谢！仍然报错。

不知你如何使用，我这没有错误

chuhaiou

由于在Office 2003版中，VBA不直接提供操作Office剪贴板的方法，因此只能借助API函数来完成。

主要思路：
①：先载入剪贴板窗口
②：然后找到剪贴板的窗口句柄
③：向剪贴板窗口发送鼠标按下和弹起的消息，模拟按下“全部清空”

这儿，以Word为例，其它Office程序（如Excel、PowerPoint）可以如法炮制。


'*************************************************************************
'作者：Joe Was
'功能：清空Office剪贴板
'整理：ExcelHome论坛
'测试环境：Word 2003
'相关链接：http://www.mrexcel.com/forum/showthread.php?t=167292
'*************************************************************************

'声明API函数
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
'定义鼠标消息
Private Const WM_LBUTTONDOWN As Long = &H201&
Private Const WM_LBUTTONUP As Long = &H202&

Sub ClearClipBoard()

    Dim hWord, hClipBoard, hWindow As Long 'Word主窗口、剪贴板、临时窗口句柄
    Dim nXY As Long '剪贴板“全部清空”按钮的坐标
    Dim strCaption As String    'Word主窗口的标题

    Application.ShowClipboard  '打开剪贴板
    CommandBars("Task Pane").Visible = False '关闭任务窗格
   
'先获取Word主窗口的标题
    If Documents.Count = 0 Then   '没有文档打开
        strCaption = "Microsoft Word"
    Else
        strCaption = ActiveWindow.Caption & " - Microsoft Word"
    End If
   
    hWord = FindWindowEx(0&, 0&, "OpusApp", strCaption)   '获取Word主窗口句柄
    hWindow = FindWindowEx(hWord, 0&, "MsoWorkPane", "MsoWorkPane") '获取任务窗格窗口句柄
    hClipBoard = FindWindowEx(hWindow, 0&, "bosa_sdm_Microsoft Office Word 11.0", "Collect and Paste 2.0") '获取剪贴板窗口句柄
   
    If hClipBoard = 0 Then  '未知原因，没有找到剪贴板的窗口句柄
        MsgBox "剪贴板清空失败!"
        Exit Sub
    End If
   
    nXY = 100 + 10 * 65536   '(x,y)=(100,10),取(92,6)~(168,27)均可
   
    Call PostMessage(hClipBoard, WM_LBUTTONDOWN, 0&, nXY) '模拟鼠标按下
    Call PostMessage(hClipBoard, WM_LBUTTONUP, 0&, nXY) '模拟鼠标弹起
   
End Sub