遍历所有子文件夹枚举指定类型文件或文件夹的函数

wpxxsyzx

论坛最近要求遍历文件夹或文件夹下的文件帖子比较多，每次都要编写一样的查找的代码，把它做成函数，以后方便使用。
有的要求递归遍历所有子文件夹，正好用字典实现。

'MuLu是要查找的文件夹,如："F:\VBA\pdf\Excel2007VBA"
'LeiXing是要查找的文件类型，如：*.xls,a?*.txt等，如果省略该参数，函数实现的是查找文件夹功能
'LeiXing参数不省略时：1、Zi为true时搜索所有子文件夹下符合要求的文件。2、Zi为false时仅搜索参数MuLu下符合要求的文件
'LeiXing参数省略时：  1、Zi为true时搜索参数MuLu下所有子文件。2、Zi为false时仅搜索参数MuLu下的文件夹
'函数的返回值是一个一维数组，可视具体情况使用

Public Function ListFile(MuLu As String, Zi As Boolean, Optional LeiXing As String = "")
Dim MyFile As String, ms As String
Dim arr, brr, x
Dim i As Integer
Set d = CreateObject("Scripting.Dictionary")
If Left(MuLu, 1) <> "\" Then MuLu = MuLu & "\"
d.Add MuLu, ""
i = 0
Do While i < d.Count
    brr = d.keys
    MyFile = Dir(brr(i), vbDirectory)
    Do While MyFile <> ""
        If MyFile <> "." And MyFile <> ".." Then
            If (GetAttr(brr(i) & MyFile) And vbDirectory) = vbDirectory Then d.Add (brr(i) & MyFile & "\"), ""
        End If
        MyFile = Dir
    Loop
    If Zi = False Then Exit Do
    i = i + 1
Loop
If LeiXing = "" Then
    ListFile = Application.Transpose(d.keys)
Else
    For Each x In d.keys
        MyFile = Dir(x & LeiXing)
        Do While MyFile <> ""
            ms = ms & x & MyFile & ","
            MyFile = Dir
        Loop
        If Zi = False Then Exit For
    Next
    If ms = "" Then ms = "没有符合要求的文件,"
    ListFile = Application.Transpose(Split(ms, ","))
End If
End Function
测试函数：
Public Sub a()
Dim a
a = ListFile("F:\VBA\pdf\Excel2007VBA", True, "*.xls")
Range("a1").Resize(UBound(a), 1) = a
End Sub
枚举文件的函数.rar (12.47 KB, 下载次数: 2049)

2011-8-29 10:22 上传

点击文件名下载附件

dxy27

学习，谢谢分享。

jiminyanyan

学习，谢谢分享

HHAAMM

好！！{:soso_e179:}
这种问题以前只想用递归
这种双循环的办法比递归好

HHAAMM

财富+5怎么成了技术+5了{:soso_e110:}

kevinchengcw

可以尝试命令行中的dir或者for命令，关键语句只需要一句就可以了。

wpxxsyzx

可以尝试命令行中的dir或者for命令，关键语句只需要一句就可以了。

就是图个在平时使用时方便

joyark

呵呵……感谢楼主分享，下载学习了

wpxxsyzx

向各位版主致谢！
希望对有的朋友有帮助。

WUWANMING

谢谢分享了