[第81期]Piny系列-小中大判定

piny

說明
0, 1, 2, 3為小；4, 5, 6為中；7, 8, 9為大
請在F2找出該列未出現之群組，
若小中大皆出現，請返回「无」
若小中大有兩項未出現，請返回「小中」、「小大」、「中大」（請注意順序）

評分標準
公式字元數(含等號)小於80字元，技術分1分
公式字元數(含等號)小於70字元，技術分2分

期限
2011/8/22 下午6:00

限制
不限Excel版本
公式需由F2可下拉，且全部答案與E列完全一致(即G1返回TRUE)
B, C, D列只會出現0~9之數字
不需考慮B, C, D為空或不為數字之情況(即全部情況就這1000種而已)
無VBA，無自定義函數
F2公式只得引用B2:D2，不得引用B至D列中如D2:D11等包含其他行之寫法
無輔助列，E列為參考解(不得引用)
公式由F1001上拉完成者，視為不符題意(即非由F2填寫公式視為不符要求)
一人限占一樓層，無答案勿先占位

chunlin1wang

先凑一个67字符，慢慢再研究。

1. =TRIM(MID("中大小大 小中 小 无",SUM((FREQUENCY(B2:D2,{3,6})>0)*{1;3;6}),2))

复制代码

oyzhjr

=TRIM(MID(" 中大小大大 小中中 小 无",2*SUM(IF((FREQUENCY(B2:D2,{3;6})),{1;2;4})),2))
或
=TRIM(MID(" 中大小大大 小中中 小 无",2*SUM(SIGN(FREQUENCY(B3:D3,{3;6}))*{1;2;4}),2))
74个字符，没办法了，等高手答案。

wkbu

70字符
=TRIM(MID(" 中大小大大 小中中 小 无",SUM((FREQUENCY(B2:D2,{3,6})>0)*{2;4;8}),2))


64字符（这个答案可以实现，不知道算不算~~~）
=MID(" 中大小大大 小中中 小 无",SUM((FREQUENCY(B2:D2,{3,6})>0)*{2;4;8}),2)

涅磐86970

=TRIM(MID(" 中大小大大 小中中 小 无",2*OR(B2:D2<4)+OR(B2:D2={4;5;6})*4+OR(B2:D2>6)*8,2))
带等号77

羽希

春林哥 真服你了
出手总是这样快 还能非常漂亮
我先搬个板凳


貌似PINY版主是开棋牌馆的^^
第1次是扑克牌(三带和四炸弹),第2次是斗兽棋(十二生肖),第3次是推牌九(天地五行)+象棋(将帅),想要得分,呵呵,先会玩才行啊..
这一次是摇色子(猜大小),终于碰上个不用学就会的了.

=LOOKUP(BIN2DEC(SUM(IF(FREQUENCY(B2:D2,{3,6}),{100;10;1}))),ROW($1:$7),{"小中";"小大";"小";"中大";"中";"大";"无"})

=TRIM(MID("小中小大小 中大中 大 无",BIN2DEC(SUM(IF(FREQUENCY(B2:D2,{3,6}),{100;10;1})))*2-1,2))

=TRIM(MID("小中小大小 中大中 大 无",SUM(IF(FREQUENCY(B2:D2,{3,6}),{4;2;1}))*2-1,2))

=TRIM(MID(" 小中小大小 中大中 大 无",SUM(IF(FREQUENCY(B2:D2,{3,6}),{8;4;2})),2))

wcymiss

怎么这么短的时间？凑个69的公式：

1. =TRIM(MID("小中小 小 小大中 无 大   中 大     中大",SUM((B2:D2<{4;7})*{6;2})+1,2))

复制代码

ringdove

唉，字数不符合要求，不过也参与一下，最短也就只能是80个字符

改来改去还有137个字符，晕啊

1. =IF(PRODUCT(FREQUENCY(B2:D2,{3;6})), "无",IF(FREQUENCY(B2:D2,3),"","小")&IF(SUM(N(B2:D2={4;5;6})),"","中")&IF(SUM(N(B2:D2={7;8;9})),"","大"))

复制代码

再改了一下还是要128个字符，我晕

1. =IF(PRODUCT(FREQUENCY(B2:D2,{3;6})), "无",IF(SUM(N(B2:D2<4)),"","小")&IF(SUM(N(B2:D2={4;5;6})),"","中")&IF(SUM(N(B2:D2>6)),"","大"))
   

复制代码

继续改，唉，还是要113个字符，不过也是有进步的

1. =LOOKUP(SUM(IF(FREQUENCY(B2:D2,{3;6}),1,)*{100;10;1}),{1;10;11;100;101;110;111},{"小中";"小大";"小";"中大";"中";"大";"无"})

复制代码

继续改，80个字符了，不过觉得答案虽然正确，但是逻辑性还没有字数多的强，简直是凑出来的

1. =INDEX({"中大";"小大";"大";"小中";"中";"小";"无"},SUM(IF(FREQUENCY(B3:D3,{3;6}),{1;2;4},)))

复制代码

鬼狐

刚刚好79个字符~~
=TRIM(MID("中大    大 中   大 无 中 小大小 小 小中",SUM(LOOKUP(B2:D2,{0,4,7;0,3,4}))*2+1,2))

cpayang

如能使用名称,则长度可短一些.