用ExcelVBA将多个列数不完全相同的文本文件或csv数据导入到Access数据库中的三种方法

commander777

请问版主，如果想将不同内容的CSV（有不相同的列）写入到ACCESS的同一个表中，采用第3种方法该如何操作？谢谢！

commander777

原帖由 tangel 于 2011-7-27 03:37 发表
附上第四写法：其它写法相同
4.先合并txt文件为temp.txt
dim cmdstr as string
cmdstr ="cmd.exe/c  dir "& mypath &"*.txt/s >"&mypath&"temp.txt" '运用cmd命令合并所有txt文件为一个temp.txt文件
shell cmdst ...

如果文本文件的列不完全一致时能实现吗？

zhaogang1960

原帖由 commander777 于 2011-8-3 12:58 发表
请问版主，如果想将不同内容的CSV（有不相同的列）写入到ACCESS的同一个表中，采用第3种方法该如何操作？谢谢！

Sub 联合查询后导入() '引用Microsoft ActiveX Data Objects 2.x Library
    Dim cnn As New ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim myPath$, MyFile$, SQL$, a(), b(), arr(), s$, t$, i%, n%
    cnn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & ThisWorkbook.Path & "\学生成绩.mdb" '连接数据库
    Set rs = cnn.Execute("成绩单")
    n = rs.Fields.Count
    ReDim a(1 To n)
    ReDim b(1 To n)
    For i = 1 To n
        a(i) = rs.Fields(i - 1).Name
        If rs.Fields(i - 1).Type <= 5 Then b(i) = 0 Else b(i) = "''"
    Next
    myPath = ThisWorkbook.Path & "\"
    MyFile = Dir(myPath & "*.txt")'csv文本修改为MyFile = Dir(myPath & "*.csv")
    Do While MyFile <> "" '创建多个文本文件的联合查询
        Set rs = cnn.Execute("[Text;FMT=Delimited;HDR=Yes;DATABASE=" & myPath & ";].[" & MyFile & "]")
        ReDim arr(1 To rs.Fields.Count)
        For i = 1 To rs.Fields.Count
            arr(i) = rs.Fields(i - 1).Name
            
        Next
        s = "," & Join(arr, ",") & ","
        t = ""
        For i = 1 To n
            If InStr(s, "," & a(i) & ",") Then '该文本文件存在该字段
                t = t & "," & a(i)
            Else
                t = t & "," & b(i) & " as " & a(i) '该文本文件不存在该字段要添加 '' as 字段或 0 as 字段
            End If
        Next
        t = Mid(t, 2)
        If Len(SQL) Then
            SQL = SQL & " union all select " & t & " from [Text;FMT=Delimited;HDR=Yes;DATABASE=" & myPath & ";].[" & MyFile & "]"
        Else
            SQL = "select " & t & " from [Text;FMT=Delimited;HDR=Yes;DATABASE=" & myPath & ";].[" & MyFile & "]"
        End If
        MyFile = Dir()
    Loop
    SQL = "insert into 成绩单 select * from (" & SQL & ")" '向access数据表中添加数据语句
    cnn.Execute SQL
    MsgBox "已经成功将文本文件数据保存为数据库！", vbInformation
    cnn.Close
    Set cnn = Nothing
End Sub

[ 本帖最后由 zhaogang1960 于 2011-8-4 02:01 编辑 ]

commander777

原帖由 zhaogang1960 于 2011-8-3 18:02 发表

Sub 联合查询后导入() '引用Microsoft ActiveX Data Objects 2.x Library
    Dim cnn As New ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim myPath$, MyFile$, SQL$, a(), b(), arr(), s$, t$, i%, ...

感谢版主的帮助与启发，我去试验一下！
另外有个问题想请教一下，如果我需要从其他数据库（例如SQL、SYBASE）中通过ODBC导出数据到ACCESS里面，需要将数据库中不同表（列数也是不一致）的数据组合后导入，我该怎样操作？
以前看到过个例子，是通过DOCMD来实现的，但是找不到了，麻烦版主指点一二！

zhaogang1960

原帖由 commander777 于 2011-8-4 11:40 发表

感谢版主的帮助与启发，我去试验一下！
另外有个问题想请教一下，如果我需要从其他数据库（例如SQL、SYBASE）中通过ODBC导出数据到ACCESS里面，需要将数据库中不同表（列数也是不一致）的数据组合后导入，我该怎样 ...

你所提到的这些数据库我没有用过，不知道它们是否和access兼容，记得ldy版主有过论述，可惜我们没有记住在那里了，建议发信息向ldy版主求助

jjhome

commander777

原帖由 zhaogang1960 于 2011-8-4 12:41 发表

你所提到的这些数据库我没有用过，不知道它们是否和access兼容，记得ldy版主有过论述，可惜我们没有记住在那里了，建议发信息向ldy版主求助

谢谢版主，已用你的方法实现了程序。
另外问一下在第2种方法中，在打开了2个Recordset之后，能用SQL直接在这2个Recordset之间传递数据吗？就是不采用工作表过渡

如果不行，那原因是什么呢？

zhaogang1960

原帖由 commander777 于 2011-8-8 23:08 发表


谢谢版主，已用你的方法实现了程序。
另外问一下在第2种方法中，在打开了2个Recordset之后，能用SQL直接在这2个Recordset之间传递数据吗？就是不采用工作表过渡

如果不行，那原因是什么呢？

这不就是第一种方法吗？
就是因为这种方法需要用循环的方式交换两个查询记录集的信息，我才想到了用工作表过度，一次性写入工作表，再一次性写入数据库

commander777

原帖由 zhaogang1960 于 2011-8-8 23:28 发表

这不就是第一种方法吗？
就是因为这种方法需要用循环的方式交换两个查询记录集的信息，我才想到了用工作表过度，一次性写入工作表，再一次性写入数据库

谢谢版主，我想的太多了，呵呵

clietj37

感謝版主的分享,讓我獲益良多