TEXT函数基础测试26小小题

lwwcom

=TEXT(88.3333333333333,"0天0/24")
="88天8/24"
88天我能理解
8/24是怎么来的，一头雾水！请老师给来块毛巾

yilaikong1231

请问您这里答案中，隐藏零值的这条答案我不是很明白，能否详解？

半半瓶醋

不是“使用道具”，是“评分”

duwei9981

今天的花送完了，部分还没送到 ，重在学习吧！
出的题目都是基础题，新手比较好吸收 ，意在全面的接触一下TEXT。
整理一下比较简洁的答案供参考：
1        3位显示         =TEXT(B2,"000")
2        取2位小数位数 =TEXT(B3,"0.00")
3        判断><=0         =TEXT(B4,">;<;=")&0
4        隐藏0值         =TEXT(B7,"[=0] ")
5        隐藏负值         =TEXT(B10,"[<0] ")
6        隐藏正值         =TEXT(B10,"[>0] ")
7        隐藏0、正值，负值显示正值         =TEXT(B16,"[<0];")
8        转换百分比，保留2位小数         =TEXT(B19,"0.00%")
9        英文百分比转成小数         =TEXT(LEFT(B20,LEN(B20)-7),""!0!.00"") 、=SUBSTITUTE(B20,""percent"",)%
10        加美元符号、千分符、保留2位小数 =TEXT(B21,"$#,##0.00")
11        转换星期         =TEXT(B22,""aaaa"") 、英文版=TEXT(B22,""[$-804]aaaa"")
12        转换星期(英文)        =TEXT(B23,"dddd")
13        改变时间显示格式        ="现在时间："&TEXT(B24,"mm/dd h:mm AM/PM")
14        汉字时间        =TEXT(B25,""[dbnum1]yyyy年m月d日"") 、英文版=TEXT(B25,""[dbnum1][$-804]yyyy年m月d日"")
15        时间转换成多少秒          =TEXT(B26,"")
16        自动显示几月份产值          =TEXT(B27,"m月份产量")
17        此日期距现在几年了？=TEXT(DATEDIF(B28,NOW(),"Y"),"0年;;")
18        判断上半年、下半年？=TEXT(MONTH(B29),"[>6]下半年;上半年")
19        加字符显示（20层30栏）=TEXT(B30,"0层00栏")
20        加字符显示（本月我的工资x元）=TEXT(B31,"本月我的工资0元")
21        重复4次         =TEXT(B32,"@@@@")
22        重复10次并用；号分开=TEXT(B33,REPT("@\;",9)&"@")
23        "判断分数" =TEXT(TEXT(B34,"[>=90]优;[<60]不及格;0"),"[>=80]良;及格")
                                   =TEXT(0&B34-60,"[>=30]优；[>=20]良;及格;差"")
24        显示多少K+零头、保留3位小数   =TEXT(B38,"0K+000.000")
25        正数显示存入、负数支出、0平衡  =TEXT(B39,"收入;支出;平衡")
26        转换成X天Y小时 =SUBSTITUTE(TEXT(LEFT(B42,LEN(B42)-2)/24,"#天#小时/24"),"/24",)
                                             =TEXT(LEFT(B42,LEN(B42)-2)/24,"0天")&TEXT(LEFT(B42,LEN(B42)-2)/24,"h小时")

[ 本帖最后由 duwei9981 于 2011-6-8 07:56 编辑 ]

山桑弓

原帖由 yilaikong1231 于 2011-5-24 15:56 发表
请问您这里答案中，隐藏零值的这条答案我不是很明白，能否详解？

是
=TEXT(B7,"G/通用格式；-G/通用格式；")
吧，TEXT函数第二参数中，全写的话可以有四段格式，分别是正数格式、负数格式、零值格式、文本格式，中间用“；”隔开，各段格式可以不写齐全（具体内容很多，我也只知一点点），如果分隔号写了，而具体格式不写，就代表这段格式返回空值，你可以把第二个“；”删除，公式改为
=TEXT(B7,"G/通用格式；-G/通用格式")
这样就不会有隐藏零值的作用了，如果四段的分隔符都写，而中间什么都没有，则代表隐藏输入的所有值，正数、负数、零、文本都不显示。
=TEXT(B7,";;;")
在这个题目中，我这个答案算很啰嗦的，可以不写的格式占用了很多字符，看了人家的回答，感觉到差距很大，你偏偏叫我解释这个公式，真是哪壶不开提哪壶，一剑老师的
=TEXT(B7,"[<>];")
至柔楼主的
=TEXT(B7,"[=0] ")
才是好答案，只把需要隐藏的0值进行设置。

[ 本帖最后由 山桑弓 于 2011-5-24 16:29 编辑 ]

duwei9981

原帖由 lwwcom 于 2011-5-24 15:55 发表
=TEXT(88.3333333333333,"0天0/24")
="88天8/24"
88天我能理解
8/24是怎么来的，一头雾水！请老师给来块毛巾

8/24=0.333333333333

一嘟噜钥匙

做了半天真累啊！

lwwcom

谢谢 duwei9981 老师的毛巾
是不是这样的运算模式
0.232312         =TEXT(0.232312,"0+0/24")        0+6/24
1         =TEXT(1,"0+0/24")        1+0/24
1.232312         =TEXT(1.232312,"0+0/24")        1+6/24
3.232312         =TEXT(3.232312,"0+0/24")        3+6/24
4.832312         =TEXT(4.832312,"0+0/24")        4+20/24
如：1.232312是不是就分解成1+0.232312 而0.232312由6/24求得

[ 本帖最后由 lwwcom 于 2011-5-24 17:47 编辑 ]

uefj2

先下载，再学习，

一嘟噜钥匙

原帖由 lwwcom 于 2011-5-24 15:55 发表
=TEXT(88.3333333333333,"0天0/24")
="88天8/24"
88天我能理解
8/24是怎么来的，一头雾水！请老师给来块毛巾

"0天0/24"的意思就是用“几又24分之几”的格式显示