请教各位老师，如何用VBA找出两列中不同的值？

anijoe123

请教各位老师，如何用VBA找出两列中不同的值？如：
序号    A列        B列
1           张         郭
2           黄         李  
3           郭         张
4           王         黄
5           李         王  
6           孙         曹
7           曹         吴
8           汪         周
9           周         孙
10         吴   

我要在C列显示A列不同与B列的值，即“汪”，请问如何写代码？
谢谢各位老师。。。

gufengaoyue

Sub 查找()
Dim arr, brr, crr(1 To 1000), b As Boolean
b = False
Dim x%: x = 1
arr = Range("a1:a" & [a65536].End(xlUp).Row)
brr = Range("b1:b" & [b65536].End(xlUp).Row)
For i = 1 To UBound(arr, 1)
    For j = 1 To UBound(brr, 1)
        If arr(i, 1) = brr(j, 1) Then b = True: Exit For
    Next
    If b = False Then crr(x) = arr(i, 1): x = x + 1
    b = False
Next
[c1].Resize(x - 1, 1) = Application.Transpose(crr)
End Sub

anijoe123

太感谢了。谢谢老师。。好强大。。

zhaogang1960

原帖由 anijoe123 于 2011-2-26 14:03 发表
请教各位老师，如何用VBA找出两列中不同的值？如：
序号    A列        B列
1           张         郭
2           黄         李  
3           郭         张
4           王         黄
5            ...

Sub Macro1()
    Dim arr, brr(), d As Object, i&
    Set d = CreateObject("scripting.dictionary")
    arr = [a1].CurrentRegion
    ReDim brr(1 To UBound(arr), 0)
    For i = 1 To UBound(arr)
        d(arr(i, 2)) = ""
    Next
    For i = 1 To UBound(arr)
        If Not d.Exists(arr(i, 1)) Then brr(i, 0) = arr(i, 1)
    Next
    [c1].Resize(i - 1) = brr
End Sub

yaojil

Sub chf()
Dim arr, brr, d
Set d = CreateObject("Scripting.Dictionary")
arr = Range("b2:b" & [b65536].End(3).Row)
brr = Range("c2:c" & [c65536].End(3).Row)
For i = 1 To UBound(arr)
    d(arr(i, 1)) = ""
Next
For i = 1 To UBound(brr)
   If d.exists(brr(i, 1)) Then
      d.Remove (brr(i, 1))
   End If
Next
[d2].Resize(d.Count, 1) = Application.Transpose(d.keys)
End Sub

可爱天使

好，来学习一下

yutianlian

试了各老师的,5楼的报错.2楼和4楼的可以实现,但A列有B列没有的会显示在C列;B列有A列没有的不会显示.
要怎么才能实现A列或B列都没有的,都显示出来:A列有B列没有的会显示在C列;
B列有A列没有的显示在D列

莫悠悠

zhaogang1960 发表于 2011-2-26 14:38
Sub Macro1()
    Dim arr, brr(), d As Object, i&
    Set d = CreateObject("scripting.dictionary" ...

请教：如果两列分属不同的两个表，改如何改造脚本？

zhaogang1960

莫悠悠 发表于 2014-5-19 10:55
请教：如果两列分属不同的两个表，改如何改造脚本？

上面方法好像不完整，两列都有可能存在独有的值
请上传附件说明具体要求

莫悠悠

zhaogang1960 发表于 2014-5-19 11:36
上面方法好像不完整，两列都有可能存在独有的值
请上传附件说明具体要求

表1的名字可能与表2的名字不一致，如何找到不一致的名单，并标出来源。
表1的名字是掌握在报账部门的基础资料；
表2的名字是掌握在基层部门的资料；
基层部门的资料经常会有变动，是由于管理部门经常会对基层的人员进行调整，这种调整没有在报账部门进行更新和备案。因此发生报账部门的资料无法及时更新。
因此，我的目的是拿到基层部门的姓名信息与报账部门的信息进行匹配，看名字是否完全相同，如果有不同的，想知道这个不同是报账部门的名单多了还是基层部门上报的名单多了，同样，如果名单少了，也想知道这个是谁少的资料。
也就是：两个表的名单有差异的，列出差异的来源。
如附件：表1比表2多了邹蜀琅；表1比表2少了邬国耿
判断基准设定为：表1