题目测试，欢迎参加，答对有奖

半半瓶醋

原帖由 piny 于 2011-3-1 09:30 发表


大俠別急 版主已經正在整理各位朋友的解 想必妙解很多 先提供小弟當時參賽的答案供釋疑
56        =MID(TEXT(WEEKDAY(A3),"AAAA周末"),1+3*(WEEKDAY(A3,2)>5),3)
50        =IF(WEEKDAY(A3,2)>5,"周末",TEXT(WEEKDAY(A3),"AA ...

题目要求不超38字，就最后一个满足要求。
MOD(A3,7)简单，忘了日期也是数字。
=TEXT(WEEKDAY(A3,2)+1,"[>6]周末;aaaa")

chenzyyysl

56        =MID(TEXT(WEEKDAY(A3),"AAAA周末"),1+3*(WEEKDAY(A3,2)>5),3)

这个思路很妙，修改一下
=MID(TEXT(A3,"AAAA周末"),1+3*(MOD(A3,7)<2),3)
43字，可惜还是略差于楼主的要求

现在看到最短的是
=TEXT(MOD(A3,7),"[>1]aaaa;周末")
=TEXT(MOD(A3,7),"[<2]周末;aaaa")
30字

[ 本帖最后由 chenzyyysl 于 2011-3-1 10:26 编辑 ]

Ericall

=NETWORKDAYS(DATE(A4,B4,1),DATE(A4,B4+1,))
=SUM(--(MOD(ROW(INDIRECT(DATE(A4,B4,1)&":"&DATE(A4,B4+1,))),7)>1))
=SUM(--(WEEKDAY(ROW(INDIRECT(DATE(A4,B4,1)&":"&DATE(A4,B4+1,))),2)<6))
=INDEX(A$3:A$7,ROW(4:4)/4)
=IF(A3="",C2,A3)
=IF(A3>0,A3,INDIRECT("C"&ROW()-1))
=TEXT(MOD(A3,7),"[>1]AAAA;周末")
=TEXT(MOD(A3,7),"[<2]周末;AAAA")
=TEXT(WEEKDAY(A3,2)+1,"[<7]AAAA;周末")
=TEXT(WEEKDAY(A3,2)+1,"[>6]周末;AAAA")
=TEXT(WEEKDAY(A3),"[=7]周末;[=1]周末;AAAA")

[ 本帖最后由 Ericall 于 2011-3-1 10:50 编辑 ]

Zaezhong

在ET有个帖子跟问题4很像，未限制长度，大家可以学习下拓展思路~~
[基础练习]计算指定日期当月有几个周六(已总结评分) http://www.exceltip.net/thread-11940-1-1-41613.html

[ 本帖最后由 Zaezhong 于 2011-3-1 11:06 编辑 ]

topyuyang

第三题
=OFFSET(A$1,MAX(ROW(A$1:A3)*(A$1:A3<>""))-1,)

[ 本帖最后由 topyuyang 于 2011-3-1 16:38 编辑 ]

安然祥和

回复PINY老师：
50        =IF(WEEKDAY(A3,2)>5,"周末",TEXT(WEEKDAY(A3),"AAAA"))此公式可简化为：
=IF(WEEKDAY(A3,2)>5,"周末",TEXT(A3,"AAAA"))
但是字数40,超过38字啊

[ 本帖最后由 安然祥和 于 2011-3-1 11:28 编辑 ]

piny

原帖由 安然祥和 于 2011-3-1 11:23 发表
回复PINYF老师：
50        =IF(WEEKDAY(A3,2)>5,"周末",TEXT(WEEKDAY(A3),"AAAA"))此公式可简化为：
=IF(WEEKDAY(A3,2)>5,"周末",TEXT(A3,"AAAA"))
但是字数40,超过38字啊

嗯 我說提供解題思維 我並沒有說這些公式都符合字元數的要求

還有 我的名字是piny 並沒有F

安然祥和

对不起，PINY老师，我太粗心了，已在楼上更正。

wangjguo44

原帖由 piny 于 2011-3-1 09:30 发表


大俠別急 版主已經正在整理各位朋友的解 想必妙解很多 先提供小弟當時參賽的答案供釋疑
56        =MID(TEXT(WEEKDAY(A3),"AAAA周末"),1+3*(WEEKDAY(A3,2)>5),3)
50        =IF(WEEKDAY(A3,2)>5,"周末",TEXT(WEEKDAY(A3),"AA ...

我的是=IF(MOD(A3,7)<2,"周末",TEXT(A3,"aaaa"))，虽只有37个字，符合要求，但比起piny的=TEXT(MOD(A3,7),"[<2]周末;AAAA")差大了。学习了。

fjrlgj

第五题:=IF(RIGHT(A3)="页","",MATCH(,-(RIGHT(A5:A26)="页"),))
第七题:=ABS(SUM(RIGHT(LARGE(FREQUENCY(ROW(3:20),(A3:A20<>A4:A21)*ROW(3:20))*100+ROW(3:21),{1,2}),2)*{1,-1}))+1