在这里为什么IF函数实现不了

piny

原帖由 laowuwyx 于 2010-12-3 14:44 发表
呵呵，本来以为版主会给一点技术分的，又泡汤了。

不要氣餒 您也很有料 人又熱心 多多分享excel經驗 ^^

wangg913

老公式。
=LOOKUP(,-FIND({"","裤"},A2),{"上装","下装"})

wshcw

原帖由 piny 于 2010-12-3 14:58 发表
感謝加分鼓勵 加入8樓laowuwyx 老師 總整理如下 再加幾個

32        =IF(COUNTIF(A2,"*裤*"),"下装","上装")
33        =TEXT(COUNTIF(A2,"*裤*"),"下装;;上装")
34        =IF(COUNT(FIND("裤",A2)),"下装","上装")
34        =IF(ISERR(F ...

赞，优秀作品！

Violet_Universe

大头啥时当版主了啊，恭喜啊

ZHXF894

贺一个，大版

wshcw

原帖由 piny 于 2010-12-3 14:58 发表
感謝加分鼓勵 加入8樓laowuwyx 老師 總整理如下 再加幾個

32        =IF(COUNTIF(A2,"*裤*"),"下装","上装")
33        =TEXT(COUNTIF(A2,"*裤*"),"下装;;上装")
34        =IF(COUNT(FIND("裤",A2)),"下装","上装")
34        =IF(ISERR(F ...

还不彻底,再加油,努力,深挖.

wshcw

还不彻底,请大家再加油,努力."深挖洞,广积函"
=MID("上下",COUNT(,MATCH("*裤*",A2,)),1)&"装"
=MID("上装下装",2*COUNT(,MATCH("*裤*",A2,))-1,2)
=TEXT(COUNT(MATCH("*裤*",A2,))-1,"下装;上装")
=IF(COUNT(1/(MID(A2,COLUMN(1:1),1)="裤")),"下装","上装")
=IF(SUM(N(MID(A2,COLUMN(1:1),1)="裤")),"下装","上装")
=TEXT(-(LEN(SUBSTITUTE(A2,"裤",))<LEN(A2)),"上装;下装")
=IF(LEN(SUBSTITUTE(A2,"裤",))<LEN(A2),"下装","上装")
=IF(SUBSTITUTE(A2,"裤",)=A2,"上装","下装")
=TEXT(-(LEN(A2)>=FIND("裤",A2&"裤")),"上装;下装")
=TEXT(-ISNUMBER(FIND("裤",A2)),"上装;下装")
=TEXT(-ISERR(FIND("裤",$A2)),"下装;上装")
=TEXT(-ISNUMBER(MATCH("*裤*",A2,)),"上装;下装")
=TEXT(-ISNA(MATCH("*裤*",A2,0)),"下装;上装")
=TEXT(LEN(A2)-LEN(SUBSTITUTE(A2,"裤",)),"下装;;上装")
=TEXT(-COUNT(SEARCH("裤",A2)),"上装;下装")
=TEXT(-COUNT(MATCH("*裤*",A2,)),"上装;下装")
=TEXT(-COUNTIF(A2,"*裤*"),"上装;下装")
将TEXT函数换成IF会更短些.

[ 本帖最后由 wshcw 于 2010-12-3 22:56 编辑 ]

duwei9981

=MID("上下",COUNTIF(A2,"*裤*")+1,1)&"装"

gj98122

其实没那么复杂,直接筛选包含裤的,填上下装就好了

lzqmsy

很好,方法太多了,学习了