通过VBA自动加入引用

ngcg

自动加入引用的另一个指令：
dim FullPath as string
FullPath="C:\windows\System32\wmp.dll"
ThisDocument.VBProject.References.AddFromFile(FullPath)

dsd999

不错，谢谢分享，这个应该能应用到office所有的产品中

守柔

一般而言，直接使用后期绑定对象即可，否则的话，实际上是编译无法通过的，除非定义对象时仍为Object。

类似问题的常规做法：
使用CreateOjbect方法创建一个后期绑定的对象。为了使用该对象库的对象浏览器，可以在本机中先期引用该对象库，定义为明确的对象类型，编译通过以及测试没有问题后，去除前期引用，将所有该对库库的相关对象声明为Object类型，常量改为常数。

ngcg

请版主提供明确的实例以供参考。谢谢。

守柔

原帖由 ngcg 于 2010-8-28 18:11 发表
请版主提供明确的实例以供参考。谢谢。

论坛上比比皆是。
我示例一下，仅供理解。

Option Explicit

Sub Example_AddReference()
'''VBE 引用Microsoft Excel 11.0 Object  Library
    Dim xlApp As New Excel.Application
    Dim xlWBK As Excel.Workbook
    Dim xlSht As Excel.Worksheet
    Dim xlRng As Excel.Range
    Dim C As Excel.Range
    Set xlWBK = xlApp.Workbooks.Open("D:\Temp\sample.xls")
    Set xlSht = xlWBK.Worksheets(1)
    With xlSht
        Set xlRng = .Range(.Cells(1, 1), .Cells(65536, 1).End(xlUp))
    End With
    For Each C In xlRng
        Debug.Print C.Value
    Next
    xlWBK.Close False
    Set xlWBK = Nothing
    xlApp.Quit
    Set xlApp = Nothing
End Sub

Sub Example_CreateObject()
    Dim xlApp As Object
    Dim xlWBK As Object
    Dim xlSht As Object
    Dim xlRng As Object
    Dim C As Object
    Set xlApp = CreateObject("Excel.Application")
    Set xlWBK = xlApp.Workbooks.Open("D:\Temp\sample.xls")
    Set xlSht = xlWBK.Worksheets(1)
    With xlSht
        Set xlRng = .Range(.Cells(1, 1), .Cells(65536, 1).End(-4162))
    End With
    For Each C In xlRng
        Debug.Print C.Value
    Next
    xlWBK.Close False
    Set xlWBK = Nothing
    xlApp.Quit
    Set xlApp = Nothing
End Sub

''''前者为前期绑定，即在VBE中勾选对于MS EXCEL 库的引用；后期为后期绑定，使用CreateObject创建一个已注册的库的类的实例。
'''前者如果开发机上引用为高版本时(如12.0)，在低端用户机上（如11.0）时将发生引用丢失现象，反之则不会出现。但后期绑定时则不存在此问题，CreateObject时总是创建一个当前环境下已注册的类的实例。

ngcg

'谢谢版主的示例。
我的构思是不要通过VBE人工引用Microsoft Excel 11.0 Object  Library，而是借助编码引用
Microsoft Excel 11.0 Object  Library
''VBE 引用Microsoft Excel 11.0 Object  Library

chuhaiou

在PPT中如何借助编码引用？

ngcg

ActivePresentation.vbproject.references.addfromfile("c:\windows\system32\wmp.dll")
执行前，必须勾选Tools->Macro->Security->->TrustedSources->TrustaccesstoVisualBasicProject

chuhaiou

谢谢，学会了在PPT中引用！
Sub 引用msdxm.ocx()
ActivePresentation.VBProject.references.addfromfile ("c:\windows\system32\msdxm.ocx")
End Sub

[ 本帖最后由 chuhaiou 于 2010-11-18 21:15 编辑 ]

yb010

收藏了！我要学习！