word中类似单位批量转换的问题（已解决）

neaby

请您不吝指教~~~

sylun

可试试如下代码：
Sub test()
    '没有选定内容则全文档对进行处理
    Dim myRange As Range, c As String
    Set myRange = IIf(Selection.Type = wdSelectionIP, ActiveDocument.Content, Selection.Range)
    Application.ScreenUpdating = False
    With myRange.Find
        .Parent.Select
        .Text = "[0-9.]@公顷"
        .MatchWildcards = True
        Do While .Execute
            With .Parent
                If .Start > Selection.End Then Exit Do
                c = Format(Val(.Text) * 15 / 10000, "0.00") & "万亩"
                If .Next(wdCharacter) = "（" Then
                    .Start = .End + 1
                    .MoveEndUntil "）"
                    If .Text Like "[0-9]*万亩" Then
                       If .Text <> c Then .Text = c
                    Else
                        .Start = .Start - 1
                        .InsertBefore "（" & c & "）"
                    End If
                Else
                    .InsertAfter "（" & c & "）"
                End If
                .Collapse wdCollapseEnd
            End With
        Loop
    End With
    Application.ScreenUpdating = True
End Sub

neaby

非常感谢您的指点，完美的解决了我遇到的问题，节约了工作中很多不必要的时间。
如果大家还有什么问题，请参照：
sylun兄的
如何修改VBA代码把"亩"换算为"公顷"？
http://club.excelhome.net/thread-561712-1-1.html
这个代码写得同样精彩！

我的电子表1516

好资料，受益不少，只可惜时间太久远了，不知高手们是否还在网上巡视，俺也有将亩转换为公顷的小问题，不同之处就是：word表格中，第一行或第二行中有“亩”的字符，要将有亩所在的一整列数据（数字），均按这个方式转换为公顷的查找替换，及换算。。。不论如何，都先谢谢了！