统计多个文档的总页数

花甲翁

工作需要，对一些文档进行整理，需要批量印刷，但在交稿前需要对多个文档进行合计一下总共多少页。参照着版主的代码就自己略加修改了一下，拿出来与大家分享，或许对资料整理等岗的人有些帮助。
Option Explicit

Sub Example()    '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名

    Dim myDialog As FileDialog, oDoc As Document, oSec As Section

    Dim oFile As Variant, myRange As Range

    Dim PagesNumber, NumSum

    On Error Resume Next
    Application.ScreenUpdating = False

    '定义一个文件夹选取对话框
    PagesNumber = 0
    NumSum = 0
    Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
    With myDialog
        .Filters.Clear    '清除所有文件筛选器中的项目
        .Filters.Add "所有 WORD 文件", "*.doc", 1    '增加筛选器的项目为所有WORD文件
        .AllowMultiSelect = True    '允许多项选择
        If .Show = -1 Then    '确定
            For Each oFile In .SelectedItems    '在所有选取项目中循环
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                For Each oSec In oDoc.Sections    '文档的节中循环
                    PagesNumber = oDoc.Content.Information(wdNumberOfPagesInDocument)
                    NumSum = PagesNumber + NumSum
                Next
                oDoc.Close True
            Next
        End If
    End With
    Application.ScreenUpdating = True
    MsgBox "你所选择文档共有" & NumSum & "页", vbOKOnly + vbInformation, "MS WORD提示"

End Sub

守柔

谢谢楼主的分享。
以下代码值得商榷。
For Each oSec In oDoc.Sections    '文档的节中循环
                    PagesNumber = oDoc.Content.Information(wdNumberOfPagesInDocument)
                    NumSum = PagesNumber + NumSum
                Next
                oDoc.Close True
代码只是取得文档总页数，与节无关。况且在你节中循环，又未与节联系起来，这样如果是多节的文档，其总页数将倍翻。
无须保存文档。odoc.close false即可。

花甲翁

谢谢版主指点，请教一下能否帮忙写个与节无关的，适用多节的页码统计，另外再求教一下2007版本如何选择全部中文，谢谢！

kqbt

oDoc.Content.Information(wdNumberOfPagesInDocument) 取得的应该就是总页数吧？

花甲翁

更新了小部分代码，请各位网友指正。
Option Explicit
Sub Example()    '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
    Dim myDialog As FileDialog, oDoc As Document, oSec As Section
    Dim oFile As Variant, myRange As Range
    Dim PagesNumber, NumSum

    On Error Resume Next
    Application.ScreenUpdating = False
    '定义一个文件夹选取对话框
    PagesNumber = 0
    NumSum = 0
    Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
    With myDialog
        .Filters.Clear    '清除所有文件筛选器中的项目
        .Filters.Add "所有 WORD 文件", "*.doc", 1    '增加筛选器的项目为所有WORD文件
        .AllowMultiSelect = True    '允许多项选择
        If .Show = -1 Then    '确定
            For Each oFile In .SelectedItems    '在所有选取项目中循环
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                PagesNumber = oDoc.Content.Information(wdNumberOfPagesInDocument)
                NumSum = PagesNumber + NumSum
                oDoc.Close False
            Next
        End If
    End With
    Application.ScreenUpdating = True
    MsgBox "你所选择文档共有 " & NumSum & " 页", vbOKOnly + vbInformation, "MS WORD提示"

End Sub

youliqi

看看，学习学习

tangqingfu

学习ing……
谢谢分享！

lhx120824

我来学习，看的代码很难懂的，可直接搬来用。谢谢楼主和版主提供。

守柔

相关链接：
http://club.excelhome.net/thread-608481-1-2.html

欣语

很需要这样的技术，我需要统计的文件夹中有多种类的文档，有word,还有excel 如何编代码，实现不打开文档，调出各文档的页呢