教育应用贴（分班、统计、课表等）1142楼添加运动会成绩统计表20121215

lhx120824

怎样的运算能得到数组{11;12;13}与数组{21,31;22,32;23,33}合并成{11,21,31;12,22,32;13,23,33}
先临时总结如下：（继续等待其他的方法）
原帖子参见：
[url=http://club.excelhome.net/thread-668230-1-1.html]http://club.excelhome.net/thread-668230-1-1.html[/url]


1、wcymiss 提供的先分解数组成单列再用CHOOSE({})函数并联的方法：
=CHOOSE({1,2,3},{11;12;13},INDEX({21,31;22,32;23,33},0,1),INDEX({21,31;22,32;23,33},0,2))

2、shaowu459 提供的分解讲解很细，让人一看就懂：
两个数组都扩展然后数组相加的方法：
=MMULT({11;12;13},{1,0,0})+MMULT({21,31;22,32;23,33},{0,1,0;0,0,1})

3、也可只扩展第二个数组再用if函数并联的方法：
=IF({1,0,0},{11;12;13},MMULT({21,31;22,32;23,33},{0,1,0;0,0,1}))

4、如果第二个数组只有1列，就可以用李兴德提供的方法：
数组公式：
=IF({1,1,0},A1:B3,C1:C3)

5、如果数组都是有规律的纯数值的话，也可用李兴德提供的自然数的运算方法直接得出：
=(MOD(ROW()-1,3)+1)*10+ROUNDUP((ROW()-0)/3,)

谢谢提供了很好的解题思路。值得细细研究研究。
shaowu459提供的附件中
数组扩充截图

[ 本帖最后由 lhx120824 于 2011-1-2 09:34 编辑 ]

lhx120824

两个相同行数的多列数组的并联：
见下图：
要把3列数组ABC与4列数组DEFG合并成7列的数组ABCDEFG，需要把第二个数组扩充成7列的数组，借助于函数MMULT(），需要构建一个辅助数组，见图的右上方，经过矩阵运算
=MMULT(H4:K9,N4:T7)
得到中间的7列的数组，然后借助 if({1,1,1,0,0,0,0},,)
=IF({1,1,1,0,0,0,0},D4:F9,MMULT(H4:K9,N4:T7))
即可实现。

辅助数组（区域N4:T7）可用以下数组公式替代：
=1*(ROW(1:4)+3=COLUMN(1:7))
公式直接变成：
=IF({1,1,1,0,0,0,0},D4:F9,MMULT(H4:K9,1*(ROW(1:4)+3=COLUMN(1:7))))



[ 本帖最后由 lhx120824 于 2011-1-2 12:58 编辑 ]

xylqr

高人哪，赞一个！

x924139675

恩 谢谢分享 学习了

无语问苍天

感谢给我们提供学习的机会！！！！！！！！！

lhx120824

查任课表小结，运用一个数组公式填出两列内容：
定义名称
教师=SMALL(IF(data=H$3,ROW(data)*10^3+COLUMN(data)-1),ROW(1:10))

I2:J10=IFERROR(IF({1,0},INDEX(A3:A10,LEFT(教师)),INDEX(B2:F2,,RIGHT(教师,2))),"")

查任课表_小结20110103.rar (17.23 KB, 下载次数: 223)

2011-1-3 17:13 上传

点击文件名下载附件

再补充一个公式：
=IFERROR(SMALL(IF(ISERROR(FIND(H$3,B$3:F$10)),"",A$3:A$10),ROW(A1)),"")
=IFERROR(INDEX($B$2:$F$2,MOD(SMALL(IF(ISERROR(FIND(H$3,B$3:F$10)),"",COLUMN($A:$E)+ROW($A$3:$A$10)*10),ROW(A1)),10)),"")

[ 本帖最后由 lhx120824 于 2011-2-26 20:37 编辑 ]

hongqi8

很好呀     。。。

ilyou2049

常来看看真是受教不少

fyj7601

上次求助的问题得到lhx120824 专家的解答，很是感谢。对我工作中省去很多时间，在此谢谢各位热心人。

fyj7601

如何给EXCEL分栏制作登分册，见附件。即（1）怎样给考生表分成3栏，格式见登分册。（2）登分册中的信息如何从考生表中得到。请大师指教。
登分册我是复制粘帖的，能否用函数直接从考生表中分栏得到登分册。谢谢