个人认为目前最完美的人民币大写公式和自定义函数

vip968

关于人民币大写的问题，有很多帖子，也试过好多其中介绍的多种方法，总有自己感觉不太满意的地方或错误，经认真测试、查错和简化，特编写以下VBA函数，自我感觉特别好，特此分享，如有不足之处，请大家批评指正，欢迎互相讨论。谢谢！

注意：
1、函数和公式的“元”均是用“圆”字，如需用“元”，请自行修改即可。
2、负数均是在前面增加“负”字，如习惯用“-”，请自行把“负”改为“-”即可，或删除相应代码。
3、取数字时，均采取保留2位小数后再进行处理的办法。
4、VBA函数基本都有注释，应该比较容易理解吧？！

一、自定义VBA函数：

Function RMBdx(Optional Mynum As Variant)
'原创：生哥
'来源：www.vip968.com 七彩阳光
'功能：根据数值返回人民币的大写金额。
    If IsNumeric(Mynum) = False Then    'IsNumeric() 判断是否为数字
        Mynum = 0
    End If
    Mynum = Round(Mynum, 2)     '将数字保留2位小数
    If Sgn(Mynum) = 0 Then    '判断数字是否为负数，=1为正，=0为零，=-1为负
        RMBdx = ""    '数字为0，则不显示，如需显示其它信息，请自行修改，如改为  RMBdx = "零圆"
    Else
        RMBdx = IIf(Sgn(Mynum) = -1, "负", "") & Application.Text(Int(Abs(Mynum)), "[=]g;[dbnum2]") & "圆"  '若为负数，则在前加“负”字
        If Abs(Mynum) - Int(Abs(Mynum)) > 0 Then    '判断数字是否为带小数点
            RMBdx = RMBdx & Application.Text(Right(Format(Abs(Mynum) - Int(Abs(Mynum)), "0.00"), 2), "[=]g;[dbnum2]0角0分")     '转换小数点后数字
            RMBdx = Replace(Replace(RMBdx, "零分", ""), "零角", "零")       '如出现“零角”则替换为“零”,如出现“零分”则清除，如需显示“角整”则使用下边一行。
            'RMBdx = Replace(Replace(RMBdx, "零分", "整"), "零角", "零")       '如出现“零角”则替换为“零”,如出现“零分”则清除，如需显示“角整”则使用本行。
        Else
            RMBdx = RMBdx & "整"
        End If
    End If
End Function

二、直接使用公式的最简单方法：

1、显示“角整”
如“10.20元”显示为“壹拾圆贰角整”

=IF(ROUND(A1,2)=0,"",IF(A1<0,"负","")&IF(ABS(A1)>=1,TEXT(INT(ROUND(ABS(A1),2)),"[dbnum2]")&"圆","")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(A1,2),2),"[dbnum2]0角0分;;整"),"零角",IF(A1^2<1,,"零")),"零分","整"))

2、不显示“角整”
如“10.20元”显示为“壹拾圆贰角”

=IF(ROUND(A1,2)=0,"",IF(A1<0,"负","")&IF(ABS(A1)>=1,TEXT(INT(ROUND(ABS(A1),2)),"[dbnum2]")&"圆","")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(A1,2),2),"[dbnum2]0角0分;;整"),"零角",IF(A1^2<1,,"零")),"零分",""))

wshcw

5年前能写出这样的代码那当然好.可是现在不敢恭维.

wshcw

[分享]人民币大写函数TEXT终极版 1行(136字符)80楼更精彩.

[ 本帖最后由 wshcw 于 2010-4-22 01:40 编辑 ]

vip968

原帖由 wshcw 于 2010-4-22 01:26 发表
[分享]人民币大写函数TEXT终极版 1行(136字符)
84楼更精彩.

QUOTE:
Function dx(M)
    dx = Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Application.Text(Format(M, ".012034;;0"), "[=]g;[DBnum2]"), "叁肆", "分"), "壹贰", "角"), "零分", "整"), "零角", "零"), "零.零", a), "零.", a), "零整", "整"), ".", "元")
   '214字符 无缺陷 负数显示 “-”   -伍圆陆角伍分  写法A ：圆角间 无零，如需显示“负”则要增加一个replace(.....,"-","负") 的嵌套
End Function

QUOTE:
Function dx(M)
    dx = Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Application.Text(Format(M, ".012034;;0"), "[=]g;[DBnum2]"), ".", "元零"), "叁肆", "分"), "壹贰", "角"), "零分", "整"), "零角", a), "零元零", a), "零元", a), "零整", "整")
   '213字符 无缺陷 负数显示 “-”   -伍圆零陆角伍分  写法B： 圆角间 有零
End Function

经测试，用上所述84楼的2条所谓无缺陷的公式还是有缺陷：
36465.092　显示为：叁万陆仟肆佰陆拾伍元零玖叁叁玖玖玖玖
1234567890123.12　显示为：壹兆贰仟叁佰肆拾伍亿陆仟柒佰捌拾玖万零壹佰贰拾叁元壹壹

wshcw

[分享]人民币大写函数TEXT终极版 1行(136字符)80楼更精彩.
163个字符（使用EXCEL2010正常）：
Function dx(M)
     dx = Replace(Replace(Replace(Join(Application.Text(Split(Format(M, " 0. 0 0;负 0. 0 0;   ")), ["[DBnum2]"&{0,"","圆0角;;圆零","0分;;整"}]), a), "零圆零", a), "零圆", a), "零整", "整")
   '163字符A 无缺陷 负数显示 “负”   负伍圆陆角伍分  
End Function

一只鸟243

谢谢楼主!!!!很有用.

cfxyfc

谢谢楼主!!!!很有用.

fydgcn

不错哦，加上人民币标还好点

ahh0511

受教了~~~顶下LZ和BZ！

jasontay

好好学习一下：） 很实用