求助求助，有关多行合并求和

excelinfo

有一份几十万行的数据。
现在有一个情况就是，我想用VBA的方法把同一时间同一规格的产品进行数量统计

例如：
库位             代码             时间           数量
A1               1001           2010.1         1
A1               1001           2010.1         2
A1               1002           2010.1         1
A2               1001           2010.2         1
B3               1001           2010.2         1
现在我有什么样的办法可以把同样是A1的代码为1001，同时又是2010.1生产的产品的数量进行加总，并把加总过的那一行删除？

在这里就是把数据变成：
库位             代码             时间           数量
A1               1001           2010.1         3
A1               1002           2010.1         1
A2               1001           2010.2         1
B3               1001           2010.2         1

另：这个文件有几十万行数据。我怎么样通过VBA把它们该合并的进行合并呢？

我也试过数据透视表。但是，它就是加总，就会变成一张统计的表格了。
目前我只是想把原表进行瘦身，就是减少一些行数而已。怎么能做到呢？
谢谢各位大侠了！

zhaogang1960

请参考:
Sub Macro1()
    Dim arr, brr(), d As Object, i&, j&, m&, temp$
    arr = Range("A1").CurrentRegion
    Set d = CreateObject("scripting.dictionary")
    ReDim brr(1 To UBound(arr), 1 To 4)
    For i = 2 To UBound(arr)
        temp = arr(i, 1) & arr(i, 2) & arr(i, 3)
        If Not d.Exists(temp) Then
            m = m + 1
            d(temp) = m
            For j = 1 To 4
                brr(m, j) = arr(i, j)
            Next
        Else
            brr(d(temp), 4) = brr(d(temp), 4) + arr(i, 4)
        End If
    Next
    Range("A1").CurrentRegion.Offset(1, 0).ClearContents
    Range("A2").Resize(m, 4) = brr
End Sub

lrlxxqxa

几十万行的数据?excel装不下了,要用access

lb_bn

这样??

Sub bbb()
    Dim icn As Object
    Dim sql$
   
    sql = "select 库位,代码,时间,sum(数量) from [sheet1$] group by 库位,代码,时间"
    Set icn = CreateObject("adodb.connection")
    icn.Open "provider=microsoft.ace.oledb.12.0;extended properties=excel 12.0;data source=" & ThisWorkbook.FullName
    Sheets("sheet2").[a2].CopyFromRecordset icn.Execute(sql)
    Set icn = Nothing
   
End Sub

excelinfo

这论坛里的大侠们真是热心啊！
我去试试。因为那个文件奇大，里面的字段很多的。我还要调整一下格式

PS：几十万行在2003不行，但是在2007以后都可以显示100万行了。哦，我用的是2010

excelinfo

哦，我还有个问题，就是我把EXCEL导入ACCESS的时候，他说我“针对该架构的规范XML验证失败”

lb_bn

这个倒是没遇到过...

cqtyy

zhaogang1960 发表于 2010-4-4 17:24
请参考:
Sub Macro1()
    Dim arr, brr(), d As Object, i&, j&, m&, temp$

我也在找此问题的答案，谢谢你，但我试过了，还是有部分相同的行没有合并，不知道问题出在那儿？

zhaogang1960

cqtyy 发表于 2011-11-8 11:49
我也在找此问题的答案，谢谢你，但我试过了，还是有部分相同的行没有合并，不知道问题出在那儿？

本题目是个简单汇总问题，如有疑问请上传附件

yqdaqinqin

zhaogang1960 发表于 2011-11-8 12:33
本题目是个简单汇总问题，如有疑问请上传附件

有个问题想请您分析一下，vba可以处理吗？非常感谢