【老婆布置的任务，跪求】如何把WORD每2页，分割成一个单独的word文件

fig000

厉害！收藏学习！

right1406

学习，收藏

diqi1234

雨雪霏霏 发表于 2010-1-30 10:37
请 秋日的枫叶 兄试试以下代码：

Sub 每两页分割为一个新文档__保存到同目录下()

但是这个分页后，原本文档中的页眉和页脚也没了。 有办法改进为连同页眉页脚全部保留

cycyaya

先收藏，慢慢学习。谢谢！

songm025

雨雪霏霏大神靠谱

chendeyan126

diqi1234 发表于 2016-11-22 19:37
但是这个分页后，原本文档中的页眉和页脚也没了。 有办法改进为连同页眉页脚全部保留

同问。我想到一个，如果不需要编辑了，可以转换为成pdf，再拆分，acrobat有现在的拆分功能，这样可以保留页眉页脚。但如果还要编辑的话，……

chendeyan126

如果需要每10页、20页等任意页数拆分，可以修改如下两处代码。
以10页为例。
       For i = 1 To PageCount / 10 + (PageCount Mod 2)    '设置循环次数
           
             for j = 1 to 10  '增加声明一个j变量，移动10页。
                  Selection.GoToNext (wdGoToPage)
             next j
           

suihuas

为什么代码拷贝不下来？

suihuas

4楼的代码无法拷贝

wdpfox

拷贝没有问题
请 秋日的枫叶 兄试试以下代码：

Sub 每两页分割为一个新文档__保存到同目录下()
'2010.01.30 雨雪霏霏改编自守柔版主代码。
'守柔版主代码见：《请教：如何将一个word文档按页保存为多个word文档？？？》5楼
'链接为：http://club.excelhome.net/viewthread.php?tid=52690


    Dim MyPath As String, PageCount As Integer
    Dim StartRange As Long, EndRange As Long, MyRange As Range
    Dim Fn As String, MyDoc As Document, i As Integer


    On Error Resume Next
    Application.ScreenUpdating = False

    MyPath = ActiveDocument.Path    '取得文档路径
    PageCount = Selection.Information(wdNumberOfPagesInDocument)    '取得文档总页数


    Selection.HomeKey unit:=wdStory    '将光标移至文档起点
    For i = 1 To PageCount / 2 + (PageCount Mod 2)    '设置循环次数
        StartRange = Selection.start    '取得该页的第一个字符位置
        Selection.EndKey unit:=wdLine    '将光标移动到该页首行的最后位置
        Fn = i & ActiveDocument.Name    '-1的目的是防止该页首行含有段落标记,导致出错.
        If i * 2 >= PageCount Then    '如果循环到达最后一页
            EndRange = ActiveDocument.Content.End    '将文档最后位置赋值于EndRange
        Else
       '否则,将下两页的起始位置赋值于EndRange(等同于下一页的最后位置)
            Selection.GoToNext (wdGoToPage)
            Selection.GoToNext (wdGoToPage)
            EndRange = Selection.start
        End If
        Set MyRange = ActiveDocument.Range(StartRange, EndRange)  '将两页中的内容进行复制
        MyRange.Copy


        Set MyDoc = Documents.Add    '新建一空白文档
        With MyDoc
             .Content.Paste    '在新文档中粘贴
             .Content.Paragraphs.Last.Range.Delete '删除新文档末尾多出来的一个段落标记
             .SaveAs FileName:=MyPath & "/" & Fn
             '保存新文档到原文档所在目录。如果删除“MyPath & "/" & ”，。则保存到“我的文档”中。
             .Close    '关闭新文档
        End With
    Next


    Application.ScreenUpdating = True
End Sub

[ 本帖最后由 雨雪霏霏 于 2010-1-30 11:14 编辑 ]