如何删除段落中的空格而保留表格中的空格

szqhb · 发表于 2010-1-13 21:07

试了一下，可以运行啊，还很快的
雨雪霏霏老师，能注释一下吗？
能否变通一下，比如对表格外的文字进行字体、字号、段落设置等操作？
只对表格进行设置，又该怎样写？

[ 本帖最后由 szqhb 于 2010-1-13 21:16 编辑 ]

雨雪霏霏 · 发表于 2010-1-14 11:03

原帖由 我爱myvba 于 2010-1-13 12:40 发表
谢谢雨雪霏霏朋友，这段代码从理论上是可行的，但实际运行就不行了，每个字符都要检查，实在是太慢了。

　　是的，以上代码对付短文还行。如果在长文档中运行，就近似死机了。

原帖由 szqhb 于 2010-1-13 21:07 发表
试了一下，可以运行啊，还很快的
雨雪霏霏老师，能注释一下吗？
能否变通一下，比如对表格外的文字进行字体、字号、段落设置等操作？
只对表格进行设置，又该怎样写？

　　称“老师”不敢当！家园里，神仙排班列队，我给孙大圣提蟠桃篮子都不够格！呵呵。
　　注释刚才补上了，请见前页。

　　以下是新的两段代码，请我爱myvba 兄、szqhb兄试试：

Sub 删除全文表格外的空格__隐藏和解隐藏文字法()
'2010.01.14 雨雪霏霏试写。
'此宏通过“全文的文字设为隐藏”等一系列关于“隐藏文字”的操作进行迂回空格替换，
'如果您的文档不方便进行“隐藏文字”的一系列操作，请改以其他文字格式进行。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False '关闭屏幕更新

ActiveDocument.Range.Font.Hidden = True '隐藏文档中所有文字
For Each myTable In ActiveDocument.Tables '逐个在所有表格中循环
      myTable.Range.Font.Hidden = False '显示表格中的所有文字
Next '继续此一循环

Set myRange = ActiveDocument.Range '为下一步的“替换”定义一个作用范围，新范围为全文档
With myRange.Find '在此范围内“查找”
      .ClearFormatting '清除“查找”时的所有格式
      .Font.Hidden = True '重新定义“查找”时的格式为隐藏文字，只查找隐藏文字，亦即对表格外的全文进行查找
      .Execute FindText:="[ 　]", replacewith:="", Wrap:=wdFindContinue, MatchWildcards:=True, Replace:=wdReplaceAll
      '执行查找。
      '查找文本为半角空格或全角空格。
      '替换文本为空。
      '“继续查找”而不显示“是否继续查找”的对话框，
      '查找时使用“通配符”。
      '全文档替换。
End With
myRange.Font.Hidden = False '显示全文档的文字

Application.ScreenUpdating = True '恢复屏幕更新
End Sub

Sub 删除全文表格中的空格()
'2010.01.14 雨雪霏霏试写。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False '关闭屏幕更新

For Each myTable In ActiveDocument.Tables '逐个在所有表格中循环
      Set myRange = myTable.Range '为下一步的“替换”定义一个作用范围，新范围为表格之一
      With myRange.Find
         .ClearFormatting '清除“查找”时的所有格式
         .Execute FindText:="[ 　]", replacewith:="", Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
         '执行查找。
         '查找文本为半角空格或全角空格。
         '替换文本为空。
         '“不再继续查找全文”而不显示“是否继续查找”的对话框，
         '查找时使用“通配符”。
         '某一表格内全部替换。
      End With
Next

Application.ScreenUpdating = True '恢复屏幕更新
End Sub

[ 本帖最后由雨雪霏霏于 2010-1-14 11:05 编辑 ]

szqhb · 发表于 2010-1-14 14:34

有注释很好，收藏研究，据实应用

我爱myvba · 发表于 2010-1-14 23:01

雨雪霏霏老师的上面两段代码真是不错，非常好，解决了我的大问题。谢谢。
想再请教一下，如果文档中有英文，能不能保留英文之间的半角空格，如果都删除的话，英文字母就都连在一起了。

fanxp · 发表于 2010-1-14 23:59

这个题目就有挑战性，不过，一般遇不到的

我爱myvba · 发表于 2010-1-15 22:25

　　以下是 ... [/quote]
以下是新的两段代码，请我爱myvba 兄、szqhb兄试试：

Sub 删除全文表格外的空格__隐藏和解隐藏文字法()
'2010.01.14 雨雪霏霏试写。
'此宏通过“全文的文字设为隐藏”等一系列关于“隐藏文字”的操作进行迂回空格替换，
'如果您的文档不方便进行“隐藏文字”的一系列操作，请改以其他文字格式进行。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False '关闭屏幕更新

ActiveDocument.Range.Font.Hidden = True '隐藏文档中所有文字
For Each myTable In ActiveDocument.Tables '逐个在所有表格中循环
      myTable.Range.Font.Hidden = False '显示表格中的所有文字
Next '继续此一循环

Set myRange = ActiveDocument.Range '为下一步的“替换”定义一个作用范围，新范围为全文档
With myRange.Find '在此范围内“查找”
      .ClearFormatting '清除“查找”时的所有格式
      .Font.Hidden = True '重新定义“查找”时的格式为隐藏文字，只查找隐藏文字，亦即对表格外的全文进行查找
      .Execute FindText:="[ 　]", replacewith:="", Wrap:=wdFindContinue, MatchWildcards:=True, Replace:=wdReplaceAll
      '执行查找。
      '查找文本为半角空格或全角空格。
      '替换文本为空。
      '“继续查找”而不显示“是否继续查找”的对话框，
      '查找时使用“通配符”。
      '全文档替换。
End With
myRange.Font.Hidden = False '显示全文档的文字

Application.ScreenUpdating = True '恢复屏幕更新
End Sub

Sub 删除全文表格中的空格()
'2010.01.14 雨雪霏霏试写。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False '关闭屏幕更新

For Each myTable In ActiveDocument.Tables '逐个在所有表格中循环
      Set myRange = myTable.Range '为下一步的“替换”定义一个作用范围，新范围为表格之一
      With myRange.Find
         .ClearFormatting '清除“查找”时的所有格式
         .Execute FindText:="[ 　]", replacewith:="", Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
         '执行查找。
         '查找文本为半角空格或全角空格。
         '替换文本为空。
         '“不再继续查找全文”而不显示“是否继续查找”的对话框，
         '查找时使用“通配符”。
         '某一表格内全部替换。
      End With
Next

Application.ScreenUpdating = True '恢复屏幕更新
End Sub

雨雪霏霏老师的上面两段代码真是不错，非常好，解决了我的大问题。谢谢。
想再请教一下，如果文档中有英文，能不能保留英文之间的半角空格，如果都删除的话，英文字母就都连在一起了。

[ 本帖最后由我爱myvba 于 2010-1-15 22:28 编辑 ]

雨雪霏霏 · 发表于 2010-1-16 08:57

原帖由 我爱myvba 于 2010-1-15 22:25 发表
　　……
　　雨雪霏霏老师的上面两段代码真是不错，非常好，解决了我的大问题。谢谢。
　　想再请教一下，如果文档中有英文，能不能保留英文之间的半角空格，如果都删除的话，英文字母就都连在一起了。...

　　请我爱myvba 兄试试以下代码：

Sub 删除全文表格中的空格__保留英文间空格()
'2010.01.16 雨雪霏霏试写。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False '关闭屏幕更新

For Each myTable In ActiveDocument.Tables '逐个在所有表格中循环
      Set myRange = myTable.Range '为下一步的“替换”定义一个作用范围，新范围为表格之一
      With myRange.Find
         .ClearFormatting '清除“查找”时的所有格式
         '以下两个替换（必须是两次）将表格内所有英文间的一个或多个空格替换为“刀牛试小”
         .Execute FindText:="([a-zA-Z.,])[ 　]{1,}([a-zA-Z])", replaceWith:="\1刀牛试小\2", _
                              Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
         .Execute FindText:="([a-zA-Z.,])[ 　]{1,}([a-zA-Z])", replaceWith:="\1刀牛试小\2", _
                              Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
          '以下将表格内所有空格去除
         .Execute FindText:="[ 　]{1,}", replaceWith:="", _
                              Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
         '以下将所有“刀牛小试”替换为一个半角空格
         .Execute FindText:="刀牛试小", replaceWith:=" ", _
                              Wrap:=wdFindStop, MatchWildcards:=False, Replace:=wdReplaceAll
      End With
Next

Application.ScreenUpdating = True '恢复屏幕更新
End Sub

Sub 删除全文表格外的空格__隐藏和解隐藏文字法__保留英文间空格()
'2010.01.16 雨雪霏霏试写。
'此宏通过“全文的文字设为隐藏”等一系列关于“隐藏文字”的操作进行迂回空格替换，
'如果您的文档不方便进行“隐藏文字”的一系列操作，请改以其他文字格式进行。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False '关闭屏幕更新

ActiveDocument.Range.Font.Hidden = True '隐藏文档中所有文字
For Each myTable In ActiveDocument.Tables '逐个在所有表格中循环
      myTable.Range.Font.Hidden = False '显示表格中的所有文字
Next '继续此一循环

Set myRange = ActiveDocument.Range '为以下“替换”定义一个作用范围，新范围为全文档
With myRange.Find '在此范围内“查找”
      .ClearFormatting '清除“查找”时的所有格式
      .Font.Hidden = True '重新定义“查找”时的格式为隐藏文字，只查找隐藏文字，亦即对表格外的全文进行查找
      '以下两次替换（必须是两次）将表格外所有英文间的一个或多个空格替换为“刀牛试小”
      .Execute FindText:="([a-zA-Z.,])[ 　]{1,}([a-zA-Z])", replaceWith:="\1刀牛试小\2", _
                        Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
      .Execute FindText:="([a-zA-Z.,])[ 　]{1,}([a-zA-Z])", replaceWith:="\1刀牛试小\2", _
                        Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
      '以下将表格外所有空格去除
      .Execute FindText:="[ 　]{1,}", replaceWith:="", _
                        Wrap:=wdFindStop, MatchWildcards:=True, Replace:=wdReplaceAll
      '以下将所有“刀牛小试”替换为一个半角空格
      .Execute FindText:="刀牛试小", replaceWith:=" ", _
                        Wrap:=wdFindStop, MatchWildcards:=False, Replace:=wdReplaceAll
End With

myRange.Font.Hidden = False '显示全文档的文字

Application.ScreenUpdating = True '恢复屏幕更新
End Sub

我爱myvba · 发表于 2010-1-16 13:07

原帖由 雨雪霏霏 于 2010-1-16 08:57 发表

　　请我爱myvba 兄试试以下代码：

Sub 删除全文表格中的空格__保留英文间空格()
'2010.01.16 雨雪霏霏试写。

Dim myRange As Range, myTable As Table
Application.ScreenUpdating = False ...

非常漂亮的代码，谢谢雨雪霏霏老师。
遇到这样技术好、人又好的老师是我的荣幸，再次谢谢雨雪霏霏老师！

nuation · 发表于 2012-3-8 17:25

雨雪霏霏发表于 2010-1-16 08:57
　　请我爱myvba 兄试试以下代码：

myTable As Table 怎么不能运行呀？

adp666 · 发表于 2014-4-3 20:53

手艺啊的的

		自动登录	找回密码
密码			免费注册

[求助] 如何删除段落中的空格而保留表格中的空格

回复 10楼我爱myvba 的帖子

VBA：删除表格外的空格、删除表格内的空格

VBA：删除表内或表外的空格__保留英文间空格

[求助] 如何删除段落中的空格而保留表格中的空格

回复 10楼 我爱myvba 的帖子

VBA：删除表格外的空格、删除表格内的空格

VBA：删除表内或表外的空格__保留英文间空格

回复 10楼我爱myvba 的帖子