如何實現office outlook 中沒有主旨郵件的提醒功能

adim999

各位高人，
        我在寫郵件是經常忘記填寫郵件的主旨，為這事經常挨批。請問有沒有在發送郵件時，如果沒有主旨，會自動提醒功能？

zealot30

在outlook的ThisOutlookSession中添加如下代码即可：
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
On Error Resume Next
    Dim message As Outlook.MailItem
    Set message = Item
   
    If Not CheckAttachment(message) Then
        Cancel = True
        Exit Sub
    End If
   
    If Not CheckSubject(message) Then
        Cancel = True
        Exit Sub
    End If
End Sub

Private Function CheckAttachment(message As Outlook.MailItem) As Boolean
    CheckAttachment = True
    If (message.Attachments.Count = 0 And _
            (InStr(message, "附件") > 0 Or InStr(message.Body, "附件") > 0)) Then
        Dim answer As VbMsgBoxResult
        answer = MsgBox("没有附件, 是否继续发送?", vbYesNo + vbQuestion, "Microsoft Office Outlook")
        If answer = vbNo Then
            CheckAttachment = False
        Else
            CheckAttachment = True
        End If
    End If
End Function

Private Function CheckSubject(message As Outlook.MailItem) As Boolean
    CheckSubject = True
    If message.Subject = "" Then
        Dim answer As VbMsgBoxResult
        answer = MsgBox("没有主题, 是否继续发送?", vbYesNo + vbQuestion, "Microsoft Office Outlook")
        If answer = vbNo Then
            CheckSubject = False
        Else
            CheckSubject = True
        End If
    End If
End Function

[ 本帖最后由 zealot30 于 2009-11-6 21:20 编辑 ]

zealot30

在某些特殊情况下，打开outlook后，不能响应这些事件。我遇到的是如果以最小化的方式打开，会不响应所有的事件处理代码，也不知道是什么原因。
所以我加了这么一段，只要是弹出提示窗口了，我就可以放心使用outlook了，不怕忘了写主体或者忘了挂附件之类的了。
Private Sub Application_Startup()

    MsgBox "Welcome, " & Application.GetNamespace("MAPI").CurrentUser

End Sub