怎么样能快速统计一组数中，某一数连出最大次数的值,

chenjunyi

怎么样能快速统计一组数中，某一数连出最大次数的值,例如：0000111100001111111000110。。。。我想统计出1连出的最大次数

来生缘

做了一个自定义函数，试试是不是这个效果

lb_bn

这样子？
Sub bbb()
    Dim str1$, z%, y%, i%, v()
    str1 = "0000111100001111111000110"
    y = 1
    For i = 1 To Len(str1) - 1
        If Mid(str1, i, 1) = "1" And Mid(str1, i + 1, 1) = "1" Then
            y = y + 1
            ReDim Preserve v(z)
            v(z) = y
        End If
        If Mid(str1, i, 1) = "1" And Mid(str1, i + 1, 1) <> "1" Then
           z = z + 1
           y = 1
        End If
    Next
    MsgBox Application.Max(v)
    Erase v
End Sub

[ 本帖最后由 lb_bn 于 2009-10-20 22:52 编辑 ]

lb_bn

上面这个最后一个如果是单独1个的1或0的话，统计不出，即可能得不到最小值
下面这个全面点。

Sub bbb()
    Dim dic1 As Object, dic2 As Object
    Dim str1$, v(), z, zz, i&, y&
    str1 = "00001111000011111110001101"
    Set dic1 = CreateObject("scripting.dictionary")
    Set dic2 = CreateObject("scripting.dictionary")
    z = 0.0001
    zz = 0.0001
    For i = 1 To Len(str1)
        sv1 = Val(Mid(str1, i, 1))
        sv2 = Val(Mid(str1, i + 1, 1))
        If sv1 = 1 Then
            If sv1 = sv2 Then
                dic1(sv1 + z) = dic1(sv1 + z) + 1
            Else
                dic1(sv1 + z) = dic1(sv1 + z) + 1
                z = z + 0.0001
            End If
        Else
            If sv1 = sv2 Then
                dic2(sv1 + zz) = dic2(sv1 + zz) + 1
            Else
                dic2(sv1 + zz) = dic2(sv1 + zz) + 1
                zz = zz + 0.0001
            End If
        End If
    Next
    MsgBox Join(dic1.items, ",")
    MsgBox Join(dic2.items, ",")
    MsgBox Application.Max(dic1.items)
    MsgBox Application.Max(dic2.items)
End Sub

oobird

Sub bbb()
    Dim s$, i%, j%
    s = "0000111100001111111000110"
    For i = 1 To Len(s)
    If Mid(s, i, 1) <> 1 Then Mid(s, i, 1) = ","
    Next
    For i = 0 To UBound(Split(s, ","))
    j = IIf(Len(Split(s, ",")(i)) > j, Len(Split(s, ",")(i)), j)
    Next
    MsgBox j
    End Sub

lb_bn

学习了，谢谢版主。

pt98

Option Explicit

Sub Test()
Dim i As Long, j As Long
Dim Temp As String
Dim N As Long, Pos As Long, MaxN As Long, MaxC As String
    Temp = "0000111100001111111000110"
    For i = 1 To Len(Temp) - 1
        For j = i + 1 To Len(Temp)
            If Mid(Temp, i, 1) = Mid(Temp, j, 1) Then
                N = N + 1
                If j = Len(Temp) Then
                    If MaxN < N Then
                        MaxN = N: MaxC = Right(Temp, 1): Pos = i
                    End If
                    N = 0
                End If
            Else
                If MaxN < N Then
                    MaxN = N: MaxC = Mid(Temp, i, 1): Pos = i
                End If
                N = 0
                Exit For
            End If
        Next
    Next
    If MaxN > 0 Then MsgBox "字符：" & MaxC & vbNewLine & "开始位置：" & Pos & vbNewLine & "连续出现次数：" & MaxN + 1
End Sub

pt98

原帖由 oobird 于 2009-10-20 23:42 发表
Sub bbb()
    Dim s$, i%, j%
    s = "0000111100001111111000110"
    For i = 1 To Len(s)
    If Mid(s, i, 1)  1 Then Mid(s, i, 1) = ","
    Next
    For i = 0 To UBound(Split(s, ","))
    j = I ...

版主，当s = "1111222222"，你的答案好像有点问题哈。