如何从sheet1中引用不重复的数据（二单元格）到sheet2？

晨曦矇眬

如何用函数从sheet1中引用不重复的数据（二单元格）到sheet2且在相应的列求和？并且在sheet1后面的行添加型号与颜色时，sheet2自动计算。
表1：
A列　　　B列　　　C列    D列
日期        型号        颜色　　数量
1.1　　　7570236        黑　　　　1
        8500146        红　　　　1
        9440265        黄　　　　1
        8770432        绿　　　　1
        9640210        紫　　　　1
1.2　　　7570236        红　　　　1
        8500146        红　　　　1
        9440265        黄　　　　1
        8770432        绿　　　　1
        9640210        紫　　　　1
1.3　　　7570236        红　　　　1
        8500146        红　　　　1
        9440265        黄　　　　1
        8770432        绿　　　　1
        9640210        紫　　　　1
表2：
B列　　　C列　　D列
型号        颜色　　数量
7570236        黑　　　1
7570236        红　　　2
8500146        红　　　3
9440265        黄　　　3
8770432        绿　　　3
9640210        紫　　　3

[ 本帖最后由 晨曦矇眬 于 2009-10-15 13:38 编辑 ]

foodorwater

B2=INDEX(Sheet1!B:B,SMALL(IF(MATCH(Sheet1!$B$2:$B$16&Sheet1!$C$2:$C$16,Sheet1!$B$2:$B$16&Sheet1!$C$2:$C$16,)=ROW($1:$15),ROW($2:$16),4^8),ROW(1:1)))
數組公式，右拉，下拉

xiongkehua2008

B2=INDEX(Sheet1!B:B,SMALL(IF(MATCH(Sheet1!$B$2:$B$16&Sheet1!$C$2:$C$16,Sheet1!$B$2:$B$16&Sheet1!$C$2:$C$16,)=ROW($1:$15),ROW($2:$16),4^8),ROW(A1)))

數組公式!

公式右拉下拉進行填充即可!

foodorwater

，，，，，，，，，，，，，，，，

yfan17

从表1中引用所有不重复的货号.rar (4.08 KB, 下载次数: 36)

2009-10-14 13:25 上传

点击文件名下载附件

晨曦矇眬

谢谢楼上的！问题只解决一半。
1.不明白4^8的意思。
2.也不能删除表1中的任何一行，否则表2公式就出错。
3.如果表1有1000行，表2的公式下拉后能否在表1中输入后自动生成。
4.我把3楼的附件插入二行后整个计算就错误了（详见附件）！

[ 本帖最后由 晨曦矇眬 于 2009-10-14 21:52 编辑 ]

yfan17

B4=INDEX(Sheet1!B:B,SMALL(IF(MATCH("@"&Sheet1!$B$4:$B$1000&Sheet1!$C$4:$C$1000,"@"&Sheet1!$B$4:$B$1000&Sheet1!$C$4:$C$1000,)=ROW($4:$1000)-3,ROW($4:$1000),4^8),ROW(1:1)))&""

晨曦矇眬

型号与颜色引用已解决。能否告知表2中D列数量自动求和的公式！

[ 本帖最后由 晨曦矇眬 于 2009-10-15 13:47 编辑 ]

yfan17

B4=INDEX(Sheet1!B:B,SMALL(IF(MATCH("@"&Sheet1!$B$4:$B$1000&Sheet1!$C$4:$C$1000,"@"&Sheet1!$B$4:$B$1000&Sheet1!$C$4:$C$1000,)=ROW($4:$1000)-3,ROW($4:$1000),4^8),ROW(1:1)))
D4=SUMPRODUCT((Sheet1!B$4:B$1000=B4)*(Sheet1!C$4:C$1000=C4),Sheet1!D$4:D$1000)

晨曦矇眬

完全解决，非常感谢！~

[ 本帖最后由 晨曦矇眬 于 2009-10-15 19:48 编辑 ]