[53期国庆附加题] 玩转 N 进制 -----------已结

ldy · 发表于 2009-9-22 23:48

VBA只提供了 8  和16进制转换函数，Oct 和 Hex，这是两种在各个领域使用比较多的进制。
到底可以有多少进制？理论上能够找到多少不同字符，就可以有多少进制。
如果用汉字作为进制的表示字符，搞出1000 进制2000进制也不是问题。
这种特殊进制有什么用？别的作用不知道，但最起码起到了数字加密的作用。
FF 这是一个16进制数， 10进制就是255，这对经常和程序打交道的人来说没有秘密，
但对于不懂的人来说这就是天书。
如果借助汉字编写一个188进制的转换函数，对某个数字进行转换后的结果是：
中华人民共和国万岁
是不是很酷?
如果不知道是188进制，也不知道是采用的是哪188个汉字，根本不可能知道这个数字是什么。
题目  2分
编写两个函数，
1.转换Long 值（-2147483648  到 2147483647）为N进制字符串
2.转换N进制字符串为 Long值（-2147483648  到 2147483647）
要求：纯VBA代码，不得使用API，不得引用外部对象。常数 Jzs 不得修改。
为使代码简洁、易读，假定传入的参数都是正确合理的，即不会出现 N2ChrX(40000,37) 、
ChrX2N("FFFF",2) 此类参数错误。代码中不需要使用 On Error 语句。
数字0 和字母 O 看起来很像的问题不用考虑。

评分标准：结果正确、代码效率达到要求，一个函数 1 分

Function N2ChrX(ByVal L As Long, ByVal N As Integer) As String
'作用：将Long值转换为 N 进制所表示的字符串
'参数说明 L 要转换的值, N (2-36) 将要使用的进制数
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
End Function
Function ChrX2N(ByVal S As String, ByVal N As Integer) As Long
'作用：字符串值转换为 N 进制所表示的字符串
'参数说明 S 要转换的N进制字符串, N (2-36) 对S变量进制数的说明
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
S = UCase(S)
End Function
'结果正确与否请自行验证，代码效率可用下面代码测试。
Sub 效率验证N2ChrX()
Dim L As Long, i As Long, v As Long, t As Double, t2 As Double
t = Timer
v = 65535
For i = 1 To 1000000
S = Hex(v)
Next
t = Timer - t
t2 = Timer
For i = 1 To (i - 1) / 10
S = N2ChrX(v, 16)
Next
t2 = Timer - t2
Index = t2 / t * 10 '(越小越好，我的参考指数平均为 15-20 )
MsgBox "代码效率指数为 " & Index & IIf(Index < 100, " 不错！如结果正确可得分", " 太慢了不得分")
End Sub
Sub 效率验证ChrX2N()
Dim L As Long, i As Long, v As Long, t As Double, t2 As Double
t = Timer
v = 65535
For i = 1 To 1000000
S = Hex(v)
Next
t = Timer - t
t2 = Timer
For i = 1 To (i - 1) / 10
L = ChrX2N("FFFF", 16)
Next
t2 = Timer - t2
Index = t2 / t * 10 '(越小越好，我的参考指数平均为 20-25 )
MsgBox "代码效率指数为 " & Index & IIf(Index < 100, " 不错！如结果正确可得分", " 太慢了不得分")
End Sub
Sub 自检()
Dim L As Long, L2 As Long, I As Integer, Boo As Boolean, S As String, Lrr(-1000 To 1002) As Long
V = 65535
t = Timer
For L = 1 To 74000
S = Hex(V)
Next
t = Timer - t
Boo = True
For L = -1000 To 1000
Lrr(L) = L
Next
Lrr(1001) = -2147483648#
Lrr(1002) = 2147483647
t1 = Timer
For L = -1000 To 1002
For I = 2 To 36
L2 = ChrX2N(N2ChrX(Lrr(L), I), I)
Boo = (Lrr(L) = L2) And Boo
'If Boo = False Then Stop
Next
Next
For L = -1000 To 1002
L2 = ChrX2N(Hex(Lrr(L)), 16)
Boo = (Lrr(L) = L2) And Boo
'If Boo = False Then Stop
Next
For L = -1000 To 1002
L2 = ChrX2N(Oct(Lrr(L)), 8)
Boo = (Lrr(L) = L2) And Boo
'If Boo = False Then Stop
Next
t1 = Timer - t1
Index = t1 / t
Debug.Print "效率指数：" & Index; " 200之内可以结受"
If Boo Then
MsgBox "自检成功，有机会得分，具体还要看实际结果，效率指数：" & Index
Else
MsgBox "自检有错误,不得分" & " 效率指数：" & Index
End If
End Sub

复制代码

答题后请运行自检程序

答题者请跟帖占位，跟帖中不要出现与题目相关的内容，否则不予评分。
截止日期 2009-10-20 以发邮件时间为准。
答案请按如下格式发送到邮箱 26258103@163.com （不需要附件，纯文字即可）
邮件主题： VBA53期国庆附加题答案
邮件内容：

'ID : xxxxxxxxxxxxxxxx
Function N2ChrX(ByVal L As Long, ByVal N As Integer) As String
'作用：将Long值转换为 N 进制所表示的字符串
'参数说明 L 要转换的值, N (2-36) 将要使用的进制数
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
End Function
Function ChrX2N(ByVal S As String, ByVal N As Integer) As Long
'作用：字符串值转换为 N 进制所表示的字符串
'参数说明 S 要转换的N进制字符串, N (2-36) 对S变量进制数的说明
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
S = UCase(S)
End Function

复制代码

参考答案：

'ID ： LDY
Function N2ChrX(ByVal L As Long, N As Integer) As String
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
Dim v As Double, x As Double, y As Long
If N = 10 Then N2ChrX = L: Exit Function' 10进制转10进制没必要处理，直接赋值
v = L - (L < 0) * 4294967296# '把负数转为正数赋值给 Double
Do
N2ChrX = Mid(Jzs, v - Int(v / N) * N + 1, 1) & N2ChrX
v = Int(v / N)
Loop While v > 0
End Function
Function ChrX2N(ByVal S As String, N As Integer) As Long
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
Dim i%, v As Double
S = UCase(S)
If N = 10 Then ChrX2N = S: Exit Function
For i = 1 To Len(S)
v = v + (InStr(Jzs, Mid$(S, i, 1)) - 1) * N ^ (Len(S) - i)
Next
ChrX2N = v + (v > 2147483647) * 4294967296#
End Function

复制代码

结贴 http://club.excelhome.net/viewthread.php?tid=484032&page=4#pid3244334

[ 本帖最后由 ldy 于 2009-10-22 15:13 编辑 ]

HHAAMM · 发表于 2009-9-23 01:10

邮件已发送，请查收，多谢！！

俺用的方法不好

'论坛ID：HHAAMM OK + 2
Function N2ChrX(ByVal L As Long, ByVal N As Integer) As String
'作用：将Long值转换为 N 进制所表示的字符串
'参数说明 L 要转换的值, N (2-36) 将要使用的进制数
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
Dim m As Double, i%, j%, p$, b As Double, LL As Double
Dim a(100) As Double
LL = L
If LL < 0 Then
Dim x1 As Double, i1 As Integer, t%
Dim bb(31) As Integer
x1 = Abs(LL / 2)
dInt = Abs(Int(x1))
t1 = 31
If InStr(x1, ".") Then bb(t1) = 1 Else bb(t1) = 0
Do While dInt > 0
t1 = t1 - 1
x1 = dInt / 2
dInt = Int(x1)
If InStr(x1, ".") Then bb(t1) = 1 Else bb(t1) = 0
Loop
bb(0) = 1
For i1 = 1 To 31
If bb(i1) = 1 Then bb(i1) = 0 Else bb(i1) = 1
Next
For i1 = 31 To 1 Step -1
If bb(i1) = 1 Then bb(i1) = 0 Else bb(i1) = 1: Exit For
Next
x1 = 0
For i1 = 31 To 0 Step -1
x1 = x1 + bb(i1) * 2 ^ (31 - i1)
Next
LL = x1
End If
i = 100
Do
b = Int(LL / (N - 0.00000000001))
If LL >= N Then
a(i) = (LL - b * N)
Else
a(i) = LL
Exit Do
End If
LL = b
i = i - 1
Loop
For i = 0 To 100
If a(i) > 0 Then Exit For
Next
For j = i To 100
p = Mid(Jzs, a(j) + 1, 1)
N2ChrX = N2ChrX & p
Next
End Function
Function ChrX2N(ByVal S As String, ByVal N As Integer) As Long
'作用：字符串值转换为 N 进制所表示的字符串
'参数说明 S 要转换的N进制字符串, N (2-36) 对S变量进制数的说明
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
S = UCase(S)
Dim a() As Byte, m As Double, i%, j%, t%
a = S
j = UBound(a)
t = (UBound(a) + 1) / 2 - 1
For i = 0 To j Step 2
If a(i) < 64 Then
m = m + (a(i) - 48) * N ^ t
t = t - 1
Else
m = m + (a(i) - 55) * N ^ t
t = t - 1
End If
Next
If m > 2147483647 Then ChrX2N = m - 4294967296# Else ChrX2N = m
End Function

复制代码

[ 本帖最后由 ldy 于 2009-10-21 17:28 编辑 ]

alzeng · 发表于 2009-9-23 07:00

是否在这里只需做到36进制之内即可？

biaotiger1 · 发表于 2009-9-23 08:01

个人理解哦

lz表示的N进制规定用常量中的字母哦
比如如果我要求将10进制转换为10进制，而这10进制用中文表示（一以已亿意易依伊亦咦）

这是不也是一种方式捏
-----------------------------------------------------------------------------------------------------------------------
按照lz斑竹所表示的常量范围，应该仅限于36进制内的了。如果出现37，打他PP

-----------------------------------------------------------------------------------------------------------------------
个人理解，不知当否。还请lz斑竹明示，以利答题

[ 本帖最后由 biaotiger1 于 2009-9-23 08:04 编辑 ]

zhoukick · 发表于 2009-9-23 10:22

占位

biaotiger1 · 发表于 2009-9-23 10:24

原帖由 泓() 于 2009-9-23 08:06 发表
题还没做，先站位！！
与2楼同感十六进制按你的常量（常量作什么用的?）换算后如32=1G 而Hex（32）=20 两值不相同
你的2-36进制是否改变了原来进制如Hex等应该有的值

还是给出你的验证答案比较适当
比如 65 ...

正数相对简单些，负数我不会

一堆的数，看着就迷糊

ldy · 发表于 2009-9-23 12:25

dim L as long,N As Integer
L = -1
N = 19 ' 限 2 到36
msgbox  N2ChrX(L,8)  = Oct(L)
msgbox  N2ChrX(L,16)  = Hex(L)
msgbox  N2ChrX(L,10)  = Cstr(L)
msgbox  ChrX2N(Hex(L),16)  = L
msgbox  ChrX2N(Oct(L),8)  = L
msgbox  ChrX2N(Cstr(L),10)  = L
msgbox  ChrX2N(N2ChrX(L,N),N) =L

不管 L = 什么长整数，上面7 个消息框都应该显示 TRUE
8 和 16进制可以用VBA自带函数检验,至于其他进制，给几个边界值参考下。

HEX 和 OCT 是如何处理负数的，你的代码也要按照此规律编写。
只要你编写的函数中不使用 Hex  和 Oct 函数，而
msgbox  N2ChrX(L,8)  = Oct(L)
msgbox  N2ChrX(L,16)  = Hex(L)
上面这两个等式成立，其他的进制转换自然迎刃而解。

0          = 17进制字符串 "0"
1          = 17进制字符串 "1"
10          = 17进制字符串 "A"
-1          = 17进制字符串 "A7FFDA90"
2147483647 = 17进制字符串 "53G7F548"
-2147483648 = 17进制字符串 "53G7F549"

0          = 18进制字符串 "0"
1          = 18进制字符串 "1"
10          = 18进制字符串 "A"
-1          = 18进制字符串 "704HE7G3"
2147483647 = 18进制字符串 "3928G3H1"
-2147483648 = 18进制字符串 "3928G3H2"

0          = 11进制字符串 "0"
1          = 11进制字符串 "1"
10          = 11进制字符串 "A"
-1          = 11进制字符串 "1904440553"
2147483647 = 11进制字符串 "A02220281"
-2147483648 = 11进制字符串 "A02220282"

0          = 9进制字符串 "0"
1          = 9进制字符串 "1"
10          = 9进制字符串 "11"
-1          = 9进制字符串 "12068657453"
2147483647 = 9进制字符串 "5478773671"
-2147483648 = 9进制字符串 "5478773672"

0          = 4进制字符串 "0"
1          = 4进制字符串 "1"
10          = 4进制字符串 "22"
-1          = 4进制字符串 "3333333333333333"
2147483647 = 4进制字符串 "1333333333333333"
-2147483648 = 4进制字符串 "2000000000000000"

0          = 16进制字符串 "0"
1          = 16进制字符串 "1"
10          = 16进制字符串 "A"
-1          = 16进制字符串 "FFFFFFFF"
2147483647 = 16进制字符串 "7FFFFFFF"
-2147483648 = 16进制字符串 "80000000"

0          = 36进制字符串 "0"
1          = 36进制字符串 "1"
10          = 36进制字符串 "A"
-1          = 36进制字符串 "1Z141Z3"
2147483647 = 36进制字符串 "ZIK0ZJ"
-2147483648 = 36进制字符串 "ZIK0ZK"

ldy · 发表于 2009-9-23 12:29

[quote]原帖由 biaotiger1 于 2009-9-23 08:01 发表
个人理解哦

lz表示的N进制规定用常量中的字母哦
比如如果我要求将10进制转换为10进制，而这10进制用中文表示（一以已亿意易依伊亦咦）

这是不也是一种方式捏
--------------------------------------------- ... [/quote]

10 进制转换 10进制，无变化，不用转换，直接函数内赋值就行了。
其他理解正确。
本来想加一些中文在常量中，弄个500进制的，考虑到繁体简体的问题不便验证，就只用36个数字和英文字母了。
其实道理是一样的，这道题如果作对了，只要增加常量的字符数，2000进制也没问题。

jmouse · 发表于 2009-9-23 13:35

16进制没有1G，因为用的字符只能到F。
负数的表示跟总位数有关，这里应该是不考虑的吧。
其实还有个小数的问题，比负数复杂一些。

邮件已发，请查收。

[ 本帖最后由 jmouse 于 2009-9-23 13:46 编辑 ]

收到，负数也要考虑的。在 8楼有说明——ldy

jmouse · 发表于 2009-9-23 16:01

呃，没有注意到8楼有关负数的说明。
已经重发邮件，请查收。

收到 -ldy

'论坛ID: jmouse OK +2
Function N2ChrX(ByVal L As Long, ByVal N As Integer) As String
'作用：将Long值转换为 N 进制所表示的字符串
'参数说明 L 要转换的值, N (2-36) 将要使用的进制数
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
If N = 10 Then
N2ChrX = L
Else
If L < 0 Then
x = Int((2 ^ 32 + L) / N)
m = 2 ^ 32 + L - x * N
N2ChrX = Mid(Jzs, m + 1, 1) + N2ChrX
L = x
End If
While L >= N
m = L - Int((L / N)) * N
N2ChrX = Mid(Jzs, m + 1, 1) + N2ChrX
L = Int((L / N))
Wend
N2ChrX = Mid(Jzs, L + 1, 1) + N2ChrX
End If
End Function
Function ChrX2N(ByVal s As String, ByVal N As Integer) As Long
'作用：字符串值转换为 N 进制所表示的字符串
'参数说明 S 要转换的N进制字符串, N (2-36) 对S变量进制数的说明
Const Jzs As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
s = UCase(s)
If N = 10 Then
ChrX2N = s
Else
i = 1
Dim tmp As Double
While s <> ""
tmp = (InStr(1, Jzs, Right(s, 1)) - 1) * i + tmp
s = Left(s, Len(s) - 1)
i = i * N
Wend
If tmp > 2147483647 Then
ChrX2N = tmp - 2 ^ 32
Else
ChrX2N = tmp
End If
End If
End Function

复制代码

[ 本帖最后由 ldy 于 2009-10-21 17:27 编辑 ]

		自动登录	找回密码
密码			免费注册

[Excel 程序开发] [53期国庆附加题] 玩转 N 进制 -----------已结

评分

本帖子中包含更多资源

评分

评分